1

私はこのコードの何が問題なのかを理解しようとしていましたが、4時間後にあきらめました！私はここでstackoverflowでさまざまなソリューションを試しましたが、Web全体から見て、ボットはどれも機能しませんでした。

私がやろうとしているのは、「gml：coordinates」値を「point」属性に設定することだけです。名前空間と関係があると思います。または、他の何か...

XMLファイル：

<?xml version="1.0" encoding="ISO-8859-1"?>
<gml:LineString>
    <gml:coordinates>-7 -7 0 7 -7 0 7 7 0 -7 7 0</gml:coordinates>
</gml:LineString>

XSLファイル：

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:gml="http://www.opengis.net/gml">

<xsl:template match="/gml:LineString">
    <Transform>
        <Shape>
            <IndexedFaceSet>
                <xsl:attribute name="coordIndex">
                    <xsl:text>0 1 2 3 -1</xsl:text>
                </xsl:attribute>

                <Coordinate>
                    <xsl:attribute name="point">
                        <xsl:text>
                            <xsl:value-of select="/gml:coordinates" />
                        </xsl:text>
                    </xsl:attribute>
                </Coordinate>
            </IndexedFaceSet>
        </Shape>
    </Transform>
</xsl:template>
</xsl:stylesheet>

そして、Ajaxスクリプト（属性が「/ gml：coordinates」の代わりに「-7-7 0 7 -7 0 7 7 0 -7 7 0」に設定されている場合、正しい結果を返します）：

var xml = document.implementation.createDocument("", "", null);
var xsl = document.implementation.createDocument("", "", null);
xml.async = false;
xsl.async = false;
xml.load("xsl/ajax.xml");
xsl.load("xsl/ajax.xsl");
var processor = new XSLTProcessor();
processor.importStylesheet(xsl);
var output = processor.transformToFragment(xml, document);
document.getElementById("scene").appendChild(output);

前もって感謝します。

4

1 に答える 1

3

交換するだけです：

<Coordinate>
  <xsl:attribute name="point">
    <xsl:text>
      <xsl:value-of select="/gml:coordinates" />
    </xsl:text>
  </xsl:attribute>
</Coordinate>

と：

<Coordinate>
  <xsl:attribute name="point">
      <xsl:value-of select="gml:coordinates" />
  </xsl:attribute>
</Coordinate>

説明：ここには少なくとも2つの問題があります。

  1. <xsl:text>それ自体の中に他のxsl要素を含めることはできません-テキストのみ。

  2. ソースXMLドキュメントに最上位の要素/gml:coordinatesがないため、XPath式は何も選択しません。/gml:coordinates

さらにリファクタリング：* AVT * s（属性値テンプレート）を使用すると、コードをさらに簡略化できます。

置換：

<Coordinate>
  <xsl:attribute name="point">
      <xsl:value-of select="gml:coordinates" />
  </xsl:attribute>
</Coordinate>

と：

<Coordinate point="{gml:coordinates}"/>

置換：

<IndexedFaceSet>
  <xsl:attribute name="coordIndex">
    <xsl:text>0 1 2 3 -1</xsl:text>
  </xsl:attribute>

と：

<IndexedFaceSet coordIndex="0 1 2 3 -1">

修正とリファクタリング後の完全なコード：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:gml="http://www.opengis.net/gml">
    <xsl:template match="/gml:LineString">
        <Transform>
            <Shape>
                <IndexedFaceSet coordIndex="0 1 2 3 -1">
                    <Coordinate point="{gml:coordinates}"/>
                </IndexedFaceSet>
            </Shape>
        </Transform>
    </xsl:template>
</xsl:stylesheet>

結果は次のとおりです。

<Transform xmlns:gml="http://www.opengis.net/gml">
    <Shape>
        <IndexedFaceSet coordIndex="0 1 2 3 -1">
            <Coordinate point="-7 -7 0 7 -7 0 7 7 0 -7 7 0"/>
        </IndexedFaceSet>
    </Shape>
</Transform>
于 2011-04-03T14:40:36.880 に答える