0

次のコードがあります。問題は、参照ダイアログでファイルを選択した後、SELECT イベントも CANCEL イベントも発生しないことです。

MacOS 10.6 と FlashPlayer 10 を使用しています。

私は何を間違っていますか？

package
{

  import flash.display.Sprite;
  import flash.display.StageAlign;
  import flash.display.StageScaleMode;
  import flash.events.Event;
  import flash.events.MouseEvent;
  import flash.net.FileReference;
  import flash.net.FileFilter;
  import flash.net.URLRequest;

    public class loader2 extends Sprite
    {
      private var placeholder:Sprite;
      private var fileReference:FileReference;
      private var fileFilter:FileFilter;

      public function loader2()
      {
        super();
        this.stage.align = StageAlign.TOP_LEFT;
        this.stage.scaleMode = StageScaleMode.NO_SCALE;
        this.stage.addEventListener(MouseEvent.CLICK, clickHandler);
        this.init();
      }

      protected function init():void
      {
        this.placeholder = new Sprite();
        this.placeholder.graphics.beginFill(0x999999);
        this.placeholder.graphics.drawRect(0,0,stage.stageWidth,stage.stageHeight);
        this.placeholder.graphics.endFill();

        this.placeholder.useHandCursor = true;
        this.placeholder.buttonMode = true;

        this.addChild(placeholder);
      }

      protected function getHostName():String
      {
        var url:String = this.loaderInfo.loaderURL;
        var protocolIndex:Number = url.indexOf("://");

        var index:Number = url.indexOf("/", protocolIndex + 3);

        return url.substr(0, index);
      }

      protected function getUploadUrl():String
      {
        var host:String = this.getHostName();
        var action:String = this.loaderInfo.parameters["uploadurl"];

        if (action.length == 0)
          return host;

        return host.concat(action);
      }

      protected function clickHandler(e:MouseEvent):void
      {
        this.fileFilter = new FileFilter( "Any file", "*.*" );
        this.fileReference = new FileReference();

        this.fileReference.addEventListener(Event.SELECT, selectHandler);
        this.fileReference.addEventListener(Event.COMPLETE, completeHandler);

        this.fileReference.browse([this.fileFilter]);
      }

      protected function selectHandler(e:MouseEvent):void
      {
      }

      protected function completeHandler(e:MouseEvent):void
      {
      }
    }
}
4

2 に答える 2

2

selectおよびcompleteイベントは通常のイベントであり、EventではありませんMouseEvent。ハンドラーはを期待しているMouseEventため、Flashがハンドラーを実行しようとするとエラーが発生します。ハンドラーのイベントパラメーターのタイプを次のように変更しますEvent。

protected function selectHandler(e:Event):void
// ...
protected function completeHandler(e:Event):void
于 2011-04-04T07:47:12.127 に答える
1

ハンドラーのシグネチャで間違ったイベントタイプを選択するのと同じくらい簡単でしょうか。イベントの代わりにMouseEvent？

次のリスナーを追加することもできます

this.fileReference.addEventListener(Event.CANCEL, cancelHandler);
于 2011-04-04T07:47:58.950 に答える