2

私はEmail::SenderとEmail::MIMEの例に従いましたが、PDF を開こうとするまでは良さそうです。それから、元のサイズよりもサイズが小さく、何らかの形で破損していることは明らかです。私のスクリプトは多かれ少なかれ、テスト目的で与えられた例のテンプレート コピーですが、ここでは MIME が実際には機能しないのではないかと心配しています。

use strict;
use warnings;

use Data::Dumper;
use IO::All ;

use Email::Simple;
use Email::Simple::Creator;

use Email::MIME;

use Email::Sender::Simple qw(sendmail);
use Email::Sender::Transport::SMTP;

# assemble the parts
my @parts = (
    Email::MIME->create(
        attributes => {
            filename     => "report.pdf",
            content_type => "application/pdf",
            encoding     => "quoted-printable",
            name         => "report.pdf",
        },
        body => io("report.pdf")->all
    ),
    Email::MIME->create(
        attributes => {
            content_type => "text/plain",
            disposition  => "attachment",
            charset      => "US-ASCII",
        },
        body => "Hello there!",
    ),
);

# assemble parts into email
my $email = Email::MIME->create(
    header => [
        To      => 'me@you.com',
        From    => 'me@you..com',
        Subject => "Thanks for all the fish ...",
    ],
    parts => [@parts],
);

# standard modifications
$email->header_set( 'X-PoweredBy' => 'RT v3.0' );

# more advanced
# $_->encoding_set('base64') for $email->parts;

# send the email
my $transport = Email::Sender::Transport::SMTP->new({
    host => 'mail.whatever.com',
    # port => 2525,
    sasl_username => 'webuser',
    sasl_password => 's3cr3t',
    timeout       => 20,
});
sendmail( $email, { transport => $transport } );

Windows と Perl 5.12.1.0 を使用しています。IO::Allモジュールではないようですが、問題はここのどこかにあると思います。誰かが私がそれを修正するのを助けるためにこのことについて十分に知っていますか?

バイナリ モード、さまざまな SMTP サーバー、さまざまな PDF ファイルを試しましたが、まったく機能しません。

4

1 に答える 1

4

電子メールを送信する前に、バイナリ添付ファイルをエンコードする必要があります。

$_->encoding_set( 'base64' ) for $email->parts;

私はEmail::MIMEを知りません。私はMIME::Liteを使用していますが、エンコードは自動的に行われるため問題はありませんでした。

### Start with a simple text message:
$msg = MIME::Lite->new(
     From    =>'me@myhost.com',
     To      =>'you@yourhost.com',
     Cc      =>'some@other.com, some@more.com',
     Subject =>'A message with 2 parts...',
     Type    =>'TEXT',
     Data    =>"Here's the GIF file you wanted"
);

### Attach a part... the make the message a multipart automatically:
$msg->attach(Type     =>'image/gif',
     Path     =>'aaa000123.gif',
     Filename =>'logo.gif'
);

MIME::Lite->send('smtp', "smtp.myisp.net", AuthUser=>"YourName", AuthPass=>"YourPass");
$msg->send;
于 2011-04-05T10:46:44.487 に答える