1

おはよう！

辞書TDictionary<String, TStringlist>（delphi-collections-unit）に値として文字列を入力し、値としていくつかの文字列を入力します。何かのようなもの：

  • 名前=ジョン、リサ、スタン
  • スキル=読む、書く、話す
  • 年齢=12、14、16

（もちろん「、」なし）。私が必要としているのは、この辞書を繰り返し、値にキーを掛けることです。出力は次のようになります

  • 名前=ジョンスキル=読み取り年齢=12
  • 名前=ジョンスキル=読み取り年齢=14
  • 名前=ジョンスキル=読み取り年齢=16
  • 名前=ジョンスキル=書き込み年齢=12
  • 名前=ジョンスキル=書き込み年齢=14
  • 名前=ジョンスキル=書き込み年齢=16
  • ..。
  • 名前=リサスキル=読み取り年齢=12
  • ..。
  • 名前=スタンスキル=話す年齢=16

だからすべての組み合わせ。どうすればいいですか？キーの数は動的であり、tstringlistのサイズも動的です。ありがとう！今までに解決...

今スコープの問題。以下は、口述を満たす手順です。サブスプリットとスプリットストリングはストリングリストであり、プロシージャの最後に解放されます。dictはprocedures-block（主に？どのように呼び出されますか？）の後に作成され、fill-methodが呼び出され、コード例のように再帰を実行したいのですが、dictに値がありません... 。

while not Eof(testfile) do
  begin
    ReadLn(testfile, text);
    if AnsiContainsStr(text, '=') then
    begin
      Split('=', text, splitarray);
      splitarray[0] := trim(splitarray[0]);
      splitarray[1] := DeleteSpaces(splitarray[1]);
      if AnsiStartsStr('data', splitarray[0]) then
      begin
        split(' ', splitarray[0], subsplit1);
        splitarray[0]:=subsplit1[1];
        split(',', splitarray[1], subsplit2);
        dict.Add(splitarray[0], subsplit2);
        for ValueName in dict.Values do
        begin
          for i := 0 to Valuename.Count - 1 do
          write('Values are : '+ Valuename[i]);
        writeln;
        end;//
      end;//
    end;//
  end;//
4

1 に答える 1

6

TDictionary<string, TStringList>キーの数が可変であることを意味するため、を使用すると、必要なものが少し複雑になります。可変数のキーがなければ、辞書は必要なく、3つのTStringListを繰り返すだけで済みます。

そうは言っても、古典的な「すべての順列を生成する」問題があります。これは、再帰またはバックトラックを使用して解決できます。再帰は実装が簡単で、バックトラックはより少ないスタックスペースを使用します。選択はあなた次第です。これは、辞書の初期化から辞書への入力、再帰関数を使用したすべての順列の生成まで、すべてを実行する完全なコンソールアプリケーションです。

program Project23;

{$APPTYPE CONSOLE}

uses
  SysUtils, Classes, Generics.Collections;

var
  Dict:TDictionary<string, TStringList>;
  L: TStringList;
  KeyName: string;
  KeysList: TStringList;

// Help procedure, adds a bunch of values to a "Key" in the dictionary
procedure QuickAddToDict(KeyName:string; values: array of string);
var L: TStringList;
    s: string;
begin
  // Try to get the TStringList from the dictionary. If we can't get it
  // we'll create a new one and add it to the dictionary
  if not Dict.TryGetValue(KeyName, L) then
  begin
    L := TStringList.Create;
    Dict.Add(KeyName, L);
  end;
  // Iterate over the values array and add stuff to the TStringList
  for s in values do
    L.Add(s);
end;

// Recursive routine to handle one KEY in the dictionary
procedure HandleOneKey(KeyIndex:Integer; PrevKeys:string);
var L:TStringList;
    i:Integer;
    Part: string;
    KeyName: string;
begin
  KeyName := KeysList[KeyIndex];
  L := Dict[KeyName];
  for i:=0 to L.Count-1 do
  begin
    Part := KeyName + '=' + L[i];
    if KeyIndex = (KeysList.Count-1) then
      WriteLn(PrevKeys + ' ' + Part) // This is a solution, we're at the last key
    else
      HandleOneKey(KeyIndex+1, PrevKeys + ' ' + Part); // Not at the last key, recursive call for the next key
  end;
end;

begin
  try
    Dict := TDictionary<string, TStringList>.Create;
    try

      // Add whatever you want to the Dict.
      // Using the helper routine to set up the dictionary faster.
      QuickAddToDict('names', ['john', 'lisa', 'stan']);
      QuickAddToDict('skills', ['read', 'write', 'speak']);
      QuickAddToDict('ages', ['12', '14', '16']);

      // Extract all the keys to a string list. Unfortunately the dictionary
      // doesn't offer a way to get a key name by index, so we have to use the
      // keys iterator to extract all keys first.
      KeysList := TStringList.Create;
      try
        for KeyName in Dict.Keys do
          KeysList.Add(KeyName);
        if KeysList.Count > 0 then
        begin
          // We got at least one key, we can start the recursive process.
          HandleOneKey(0, '');
        end;
      finally KeysList.Free;
      end;

      WriteLn;
      WriteLn('Press ENTER to make the window go away');
      ReadLn;

    finally
      // TDictionary doesn't own the keys or the values. Strings are managed types in
      // delphi, we don't need to worry about them, but we do need to free the TStringList's
      // We use the Values iterator for that!
      for L in Dict.Values do
        L.Free;
      Dict.Free;
    end;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.
于 2011-04-07T08:21:01.757 に答える