2

Androidスタジオでビルドの問題があり、beewareでAndroidアプリを作成しましたが、ビルドしようとするとエラーが発生します。

Androidスタジオからビルドしようとしましたが、このエラー以外のすべてのバージョンの問題とその他すべてを修正しました

Could not find method leftShift() for arguments [build_m0k5smvps1e1hvx1einev6dw$_run_closure1@34e45104] on task ':buildPythonDebug' of type org.gradle.api.DefaultTask.

答えを探しましたが、役立つものが見つかりませんでした

これはbuild.gradleです

    buildscript {
repositories {
    jcenter()
    google()
}

dependencies {
    classpath 'com.android.tools.build:gradle:3.4.0'
}
}

task buildPythonDebug << {
exec {
    commandLine "voc -v -p app -o build/intermediates/classes/debug   app".split()
}
exec {
    commandLine "voc -v -p app_packages -o build/intermediates/classes/debug app_packages".split()
}
}

task buildPythonRelease << {
exec {
    commandLine "voc -v -p app -o build/intermediates/classes/release app".split()
}
exec {
    commandLine "voc -v -p app_packages -o build/intermediates/classes/release app_packages".split()
}
}
task run << {
exec {
    commandLine "adb shell am start -n com.example.HelloWorld/android.AppName".split()
}
}

apply plugin: 'com.android.application'

android {
compileSdkVersion 25
buildToolsVersion "25.0.2"

defaultConfig {
    minSdkVersion 15
    targetSdkVersion 25
    versionCode 1
    versionName "1.0"
}
sourceSets {
    main {
        manifest.srcFile 'AndroidManifest.xml'
        java.srcDirs = ['src']
        res.srcDirs = ['res']
    }
}
}

project.afterEvaluate {
packageDebug.dependsOn buildPythonDebug
packageRelease.dependsOn buildPythonRelease
run.dependsOn installDebug
}

dependencies {
implementation 'com.android.support:appcompat-v7:25.3.1'
implementation 'com.android.support:recyclerview-v7:25.3.1'
}
4

1 に答える 1

4

task変更するたびに

から：

task abc << {
    .
    .
}

に：

task abc {
     doLast {
        .
        .
     }
}
于 2019-05-06T01:53:32.070 に答える