4

いくつかの不適切な日付を持つ生データを読み込んでいます。具体的には、誰かが閏年ではない「2 月 29 日」をキー入力しました。例えば：

data _null_;
input test :yymmdd8.;
format test date9.;
cards;
20270229
run;

顧客はこれを 2 月 28 日に戻すことを望んでいます。これを行うための迅速で効率的な方法はありますか? 例：

IF iserror(date) then date=date-1; ?

どんな提案もありがたく受け取った！

4

4 に答える 4

4

日付の修正にはもう少し注意が必要です。ここに1つの方法があります。h番目。

%put sysvlong=&sysvlong sysscpl=&sysscpl;           
/* sysvlong=9.02.01M0P020508 sysscpl=W32_VSPRO */

/* read a date both as character(temp) and numeric(date).
   if the numeric date is missing then check if the
   character date ends with "0229," if so, then change it
   to "0228" and see if it is a valid date. 
   If OK, then that is it. otherwise, keep it missing. */
%let FEB29 = 0229; 
%let FEB28 = 0228;
data one;
  drop temp;
  input temp $char8. @1 date ?? yymmdd8.;
  if missing(date) then link fix;
  format date b8601da.;
  put (_all_) (=);
  return;
fix:
  if length(strip(temp))^=8 then return;
  if substr(temp,5) ^= "&FEB29" then return;
  date = input(cat(substr(temp,1,4), "&FEB28"), ?? yymmdd8.);
return;
cards;
20080229  ok
20090229  should be changed to 28th
201XX229  this should be missing
20110229  -> 28
20120229  ok 
20130229  -> 28
20270229  -> 28
;
run;

/* on log
temp=20080229 date=20080229
temp=20090229 date=20090228
temp=201XX229 date=.
temp=20110229 date=20110228
temp=20120229 date=20120229
temp=20130229 date=20130228
temp=20270229 date=20270228
NOTE: The data set WORK.ONE has 7 observations and 1 variables.
*/
于 2009-02-21T16:43:44.003 に答える
3

ここに SCONSIG からの素晴らしいヒントがあります。リンク

/******************************************************************/
 /***TIP00039.SAS                                                ***/
 /***   Leap Year Problem                                        ***/
 /***                                                            ***/
 /***   Most of us know that if the year is divisible by 4 then  ***/
 /***   that year is a Leap Year.  However, if the year is a     ***/
 /***   century year and is NOT divisible by 400 then that       ***/
 /***   century year is NOT A LEAP YEAR.                         ***/
 /***   (ie, 1700, 1800, 1900, 2100, 2200, 2300 are not LEAP     ***/
 /***        YEARS)                                              ***/
 /***                                                            ***/
 /******************************************************************/

 data leapyear;
   do year = 1600 to 2400 by 100;
    date = mdy(02,29,year);        /*** Leap Date                       ***/
    if date = . then do;           /*** If FEB 29th but not a Leap Year ***/
       date = mdy(03,01,year) - 1; /*** Make date March 1st and then    ***/
    end;                           /***   subtract 1 day                ***/
    output;
   end;
   format date mmddyy10.;
 run;

 proc print; run;

 /*** end of sas program - TIP00039 ***/

これを何らかの方法で負荷に組み込むことができます。

于 2009-02-18T16:53:59.197 に答える
1

上記の回答を少し修正したバージョン（と思います）。「??」を使用してもエラーメッセージは回避されます。入力機能で。

data testit;
   format indate yymmdd10.;
   input x $8.;

   indate = input(x, ?? yymmdd8.);
   if indate=. then indate= input(put(x - 1, 8.), ?? yymmdd8.);


    put indate=;

cards;
20080229
20090229
20100229
20110229
20120229
20130229
20270229
run;
于 2009-02-20T13:55:23.700 に答える
0

これはきれいではなく、変換に関する注意事項がありますが、機能し、エラーは発生しません。

data testit;
   format test2 yymmdd10.;
   input x $8.;
   mod4 = mod(mod((substr(x,1,4)/4),4) * 10,10);   
   if mod4 NE 0 then x = x - 1;
   test2=input(x,yymmdd8.);
   put x= test2=;

cards;
20080229
20090229
20100229
20110229
20120229
20130229
20270229
run;

出力：

x=20080229 test2=2008-02-29
x=20090228 test2=2009-02-28
x=20100228 test2=2010-02-28
x=20110228 test2=2011-02-28
x=20120229 test2=2012-02-29
x=20130228 test2=2013-02-28
x=20270228 test2=2027-02-28
于 2009-02-19T21:38:25.853 に答える