1

XML ファイルを暗号化して別の場所に送信し、そこで復号化する必要があります。以下のコードからわかるように、同じキーを使用していますが、機能しません (今のところ、単純に 2 つのローカル ファイルを使用しています)。

私が得るエラーは次のとおりです。

パディングが無効であり、削除できません。

Decrypt.aspx のこの行: Dim xReader As XmlTextReader

実際の暗号化の段階で、ファイルが正しく保存されないなどのエラーが発生している可能性があると考えています。

暗号化.aspx

 Dim rijnAlg As RijndaelManaged
 rijnAlg = RijndaelManaged.Create()

 rijnAlg.Key = {118, 123, 23, 17, 161, 152, 35, 68, 126, 213, 16, 115, 68, 217, 58, 108, 56, 218, 5, 78, 28, 128, 113, 208, 61, 56, 10, 87, 187, 162, 233, 38}
 rijnAlg.IV = {33, 241, 14, 16, 103, 18, 14, 248, 4, 54, 18, 5, 60, 76, 16, 191}
 Dim encryptor As ICryptoTransform
 encryptor = rijnAlg.CreateEncryptor(rijnAlg.Key, rijnAlg.IV)

 Dim wStream As FileStream
 wStream = File.Open("C:\test.xml", FileMode.Create)

 Dim cStream As CryptoStream
 cStream = New CryptoStream(wStream, encryptor, CryptoStreamMode.Write)

 Dim sWriter As StreamWriter
 sWriter = New StreamWriter(cStream)

 XMLDoc.Save(sWriter)

 'Clear memory'
 wStream.Flush()
 wStream.Close()

復号化.aspx

 Dim rijnAlg As RijndaelManaged
 rijnAlg = RijndaelManaged.Create()

 rijnAlg.Key = {118, 123, 23, 17, 161, 152, 35, 68, 126, 213, 16, 115, 68, 217, 58, 108, 56, 218, 5, 78, 28, 128, 113, 208, 61, 56, 10, 87, 187, 162, 233, 38}
 rijnAlg.IV = {33, 241, 14, 16, 103, 18, 14, 248, 4, 54, 18, 5, 60, 76, 16, 191}
 Dim decryptor As ICryptoTransform
 decryptor = rijnAlg.CreateDecryptor(rijnAlg.Key, rijnAlg.IV)

 Response.Write(rijnAlg.Key)
 Response.Write(rijnAlg.IV)

 Dim rStream As FileStream
 rStream = File.OpenRead("C:\test.xml")

 Dim cStream As CryptoStream
 cStream = New CryptoStream(rStream, decryptor, CryptoStreamMode.Read)

 Dim xReader As XmlTextReader
 xReader = New XmlTextReader(cStream)

 Dim xDoc As XDocument
 xDoc = XDocument.Load(xReader)

 xDoc.Save("C:\test.xml")

興味を引くために、私が使用している XML 作成コードを次に示します。

Dim XMLDoc As XDocument
    XMLDoc = New XDocument(
        New XDeclaration("1.0", "utf-8", "yes"),
        New XElement("user",
            New XElement("details",
                New XElement("firstname", Firstname.Text),
                New XElement("surname", Lastname.Text)
            )
        )
    )

 XMLDoc.Save("C:\test.xml")
4

2 に答える 2

2

またはFileStreamではなく、を閉じる/フラッシュするだけです。これでは、最後のブロックをフラッシュする機会がありません。CryptoStreamStreamWriterCryptoStream

個人的にはUsing、それらすべてに対してステートメントを使用します。その時点で、すべてが自動的に閉じられます。問題なく動作することがわかると思います。これは、例外が発生した場合にリソースが解放されることも意味します。たとえば、現時点では、書き込みが失敗した場合は何も閉じていません。

私も気にしません-代わりにStreamWriter直接保存してください。CryptoStreamそれ以外の場合は、XMLと、StreamWriter使用されるエンコーディングを制御しようとする試みの両方が発生します。

于 2011-04-27T06:27:13.777 に答える
0

私の問題に対する最良の結論を指摘してくれたJonSkeetに大いに感謝します。最終的なコード（および改善点）：

Encrypt.aspx

Using ra As RijnDaelManaged = RijndaelManaged.Create()

    ra.Key = {118, 123, 23, 17, 161, 152, 35, 68, 126, 213, 16, 115, 68, 217, 58, 108, 56, 218, 5, 78, 28, 128, 113, 208, 61, 56, 10, 87, 187, 162, 233, 38}
    ra.IV = {33, 241, 14, 16, 103, 18, 14, 248, 4, 54, 18, 5, 60, 76, 16, 191}

    encrypt = ra.CreateEncryptor(ra.Key, ra.IV)

    Using ws As FileStream = File.Open("C:\test1.xml", FileMode.Create)

        Using cs As CryptoStream = New CryptoStream(ws, encrypt, CryptoStreamMode.Write)

            XMLDoc.Save(cs)

        End Using

    End Using

End Using

Decrypt.aspx

Using ra As RijndaelManaged = RijndaelManaged.Create()

    ra.Key = {118, 123, 23, 17, 161, 152, 35, 68, 126, 213, 16, 115, 68, 217, 58, 108, 56, 218, 5, 78, 28, 128, 113, 208, 61, 56, 10, 87, 187, 162, 233, 38}
    ra.IV = {33, 241, 14, 16, 103, 18, 14, 248, 4, 54, 18, 5, 60, 76, 16, 191}

    decrypt = ra.CreateDecryptor(ra.Key, ra.IV)

    Using rs As FileStream = File.OpenRead("C:\test1.xml")

        Using cs As CryptoStream = New CryptoStream(rs, decrypt, CryptoStreamMode.Read)

            Using xr As XmlTextReader = New XmlTextReader(cs)

                xDoc = XDocument.Load(xr)
                xDoc.Save("C:\test2.xml")

            End Using

        End Using

    End Using

End Using
于 2011-04-28T03:28:57.463 に答える