Verity は主に基準の発生回数に基づいて関連性を判断するため、結果を「優先順位付けする」方法の 1 つは、コレクションのインデックス作成時に SKU を人為的に「本体」に複数回追加することです。
これは、元の SQL クエリで行うか、ColdFusion を使用して結果セットをマッサージし、Verity に渡す前に SKU を埋め込むことができます。後者のオプションの例を次に示します。
<!--- Get the product data--->
<cfquery name="qProducts" datasource="blog">
SELECT
ID
,SKU
,title
,description
FROM
products
</cfquery>
<!--- Massage the data to prioritise the SKU by creating a new query from the original --->
<cfset qProductsForIndex = QueryNew( "ID,title,body","Integer,VarChar,VarChar" )>
<cfloop query="qProducts">
<cfset QueryAddRow( qProductsForIndex )>
<cfset QuerySetCell( qProductsForIndex,"ID",qProducts.ID )>
<cfset QuerySetCell( qProductsForIndex,"title",qProducts.title )>
<!--- Add the SKU 5 times, separated by a semi-colon --->
<cfset QuerySetCell( qProductsForIndex,"body",qProducts.description & ";" & RepeatString( qProducts.SKU & ";",5 ) )>
</cfloop>
<!--- Pass the massaged query to Verity --->
<cfindex action="REFRESH"
collection="products"
type="CUSTOM"
query="qProductsForIndex"
key="ID"
title="title"
body="body">
追加の SKU はセミコロンで区切られていることに注意してください。これにより、Verity はそれらを個別のオカレンスとして照合します。
数値の例として 5 を使用しましたが、2 から始めて、必要な結果が得られるまで上方に調整することもできます。