2

Oracle Objectsを初めて使用しますが、問題があります。参照のVARRAYからアイテムを逆参照する方法がわかりません。以下は私が抱えている問題を再現するソースコードです。エラーは次のとおりです。PLS-00306：'DEREF'の呼び出しで引数の数またはタイプが間違っています


DROP TYPE LOC FORCE
/
DROP TYPE LIST_LOC FORCE
/
DROP TYPE PIZ FORCE
/

CREATE OR REPLACE TYPE LOC AS OBJECT(
  NAME      VARCHAR2(30),
  MEMBER FUNCTION GET_NAME RETURN VARCHAR2 
)
/

CREATE OR REPLACE TYPE BODY LOC AS
  MEMBER FUNCTION GET_NAME RETURN VARCHAR2 IS
  BEGIN
    RETURN SELF.NAME;
  END;
END;
/

CREATE OR REPLACE TYPE LIST_LOC AS VARRAY(10) OF REF LOC
/

CREATE OR REPLACE TYPE PIZ AS OBJECT(
  LOCS      LIST_LOC,
  MEMBER PROCEDURE DISPLAY_LOCS
)
/

CREATE OR REPLACE TYPE BODY PIZ AS
  MEMBER PROCEDURE DISPLAY_LOCS IS
  BEGIN
    FOR IDX IN SELF.LOCS.FIRST..SELF.LOCS.LAST LOOP
      DBMS_OUTPUT.PUT_LINE(DEREF(SELF.LOCS(IDX)).GET_NAME()); --this is the line that generates the error
    END LOOP;
  END;
END;
/

LOCS varrayからIDXの位置にあるREFを取得し、それをDEREFして名前を取得しようとすると、DISPLAY_LOCSプロシージャにエラーが表示されます。

4

1 に答える 1

4

DEREFはSQLステートメントに含まれている必要があります：http： //download.oracle.com/docs/cd/B28359_01/appdev.111/b28371/adobjbas.htm#i463707

PL / SQLでは、VALUE、REF、およびDEREF関数はSQL文にのみ表示できます。

これは動作します

CREATE OR REPLACE TYPE BODY PIZ AS
  MEMBER PROCEDURE DISPLAY_LOCS IS
  x varchar2(30) ;
  BEGIN
    FOR IDX IN SELF.LOCS.FIRST..SELF.LOCS.LAST LOOP
        select DEREF(SELF.LOCS(IDX)).GET_NAME() into x from dual ;
      DBMS_OUTPUT.PUT_LINE(x); --this is the line that generates the error
    END LOOP;
  END;
END;
/

再現するための素晴らしいテストケース！

于 2011-05-02T19:29:04.920 に答える