list - 2 つのリスト関数を 1 つに結合しますか?

Question

次の 2 つの機能をどのように組み合わせますか。

replaceNth n newVal (x:xs)
 | n == 0 = newVal:xs
 | otherwise = x:replaceNth (n-1) newVal xs

replaceMthNth m n v arg = replaceNth m (replaceNth n v (arg !! m)) arg

単一の機能に？

出来ますか？

Answer 1

これはかなり恐ろしいですが、それは仕事をします：

replacemn 0 0 z ((x : xs) : xss) = (z : xs) : xss
replacemn 0 n z ((x : xs) : xss) =
  let (ys : yss) = replacemn 0 (n-1) z (xs : xss)
  in ((x : ys) : yss)
replacemn m n z (xs:xss) = xs : replacemn (m-1) n z xss

Answer 2

OK、ここでは、グローバル名前空間に他の名前付き関数がないか、whereorlet句またはその他のグローバル関数を使用しています。

{-# LANGUAGE ScopedTypeVariables,RankNTypes #-}
module Temp where
newtype Mu a = Mu (Mu a -> a)

replaceMthNth :: Int -> Int -> a -> [[a]] -> [[a]]
replaceMthNth = (\h (f :: Int -> forall b . b -> [b] -> [b]) -> h f f)
                  ( \replaceNth replaceNth' ->
                    -- definition of replaceMthNth in terms of some replaceNth and replaceNth'
                    \m n v arg -> replaceNth m (replaceNth' n v (arg !! m)) arg
                  )
                  $
                    -- y combinator
                    ((\f -> (\h -> h $ Mu h) $ \x -> f $ (\(Mu g) -> g) x $ x) :: (a -> a) -> a) $
                    (\replaceNth ->
                      -- definition of replaceNth given a recursive definition 
                      (\(n::Int) newVal xs -> case xs of
                          [] -> []
                          (x:xs) -> if n == 0 then newVal:xs else x:replaceNth (n-1) newVal xs
                      )
                    )

Answer 3

機能構成

Haskell の関数は無料で作成できます。たとえば、2 つの関数fとが与えられた場合、gそれらを新しい関数 に構成できます。f . gこれはg、引数に適用さfれ、結果に適用されます。ここでも同じようにコンポジションを使用できるはずです。

Answer 4

質問の意味がまったくわかりません:)、しかし、これを実装する方法は次のとおりです。

modifyNth :: Int -> (a -> a) -> [a] -> [a]
modifyNth n f (x:xs)
  | n == 0 = f x : xs
  | otherwise = x : modifyNth (n-1) f xs

replaceNthMth :: Int -> Int -> a -> [[a]] -> [[a]]
replaceNthMth m n v = modifyNth m (modifyNth n (const v))

この方法では、リストを 2 回トラバースする必要はありません (1 回目は で!!、2 回目は でreplaceNth) 。

Answer 5

以下は、無限リストを持つ zip でネストされたリスト内包表記を使用して 2 次元リスト構造を再構築するグロテスクな実装です。

replaceMthNth :: Int -> Int -> a -> [[a]] -> [[a]]
replaceMthNth m n v ass = [[if (x,y) == (m,n) then v else a
                            | (y, a) <- zip [0..] as]
                           | (x, as) <- zip [0..] ass]