1

クラスオブジェクトのクローンを作成したい。ここからフォローしてみました：

package
{
    import flash.net.registerClassAlias;
    import flash.utils.ByteArray;

    public class MyClass
    {
        public var property1:String;
        public var property2:Array;

        public function clone():MyClass
        {
            registerClassAlias("MyClass", MyClass);

            var bytes:ByteArray = new ByteArray();
            bytes.writeObject(this);
            bytes.position = 0;

            return bytes.readObject() as MyClass;
        }
    }
}

ただし、これは、クラスにデフォルトのコンストラクターがある場合にのみ機能し、パラメーター化されたコンストラクターがある場合には機能しません。

クラスにパラメーター化されたコンストラクターがある場合に、クラスオブジェクトのクローンを作成する方法について何か考えはありますか？

よろしく

4

3 に答える 3

2

これは私があなたのためにできる最善のことです：

package
{

    import flash.display.Sprite;


    public class Thing extends Sprite
    {

        // Cloneable properties.
        private var _cloneable:Array = ["x","y","val1","val2"];


        // Properties.
        public var val1:uint = 10;
        public var val2:String = "ten";


        /**
         * Returns a new Thing with the same properties.
         */
        public function clone():Thing
        {
            var t:Thing = new Thing();

            for each(var i:String in _cloneable)
            {
                t[i] = this[i];
            }

            return t;
        }

    }

}

必要なのは、複製可能にしたいプロパティを追加することだけです_cloneable

使用例:

var thing:Thing = new Thing();

thing.x = 15;
thing.y = 10;
thing.val1 = 25;
thing.val2 = "twentyfive";

// Clone initial Thing.
var thing2:Thing = thing.clone();

trace(thing2.x, thing2.y, thing2.val1, thing2.val2); // 15 10 25 twentyfive
于 2011-05-09T06:27:13.383 に答える
0

オプションのパラメーターを持つコンストラクターを使用してクラスを作成できます。これは、テスト駆動型開発とパフォーマンスの観点から優れたプラクティスです。

于 2012-06-25T11:11:32.197 に答える
0

私の提案は、複雑にしすぎたり、考えすぎたりしないことです。これ以上複雑なことをする必要はありません。

 public function clone():Thing {
     var t:Thing = new Thing();

     t.x = this.x;
     t.y = this.y;
     t.val1 = this.val1;
     t.val2 = this.val2;

     return t;
 }

コンストラクターにパラメーターがある場合。

public function Thing(x:int,y:int) {
    this.x = x;
    this.y = y;
}

public function clone():Thing {
    var t:Thing = new Thing(this.x, this.y);

    t.val1 = this.val1;
    t.val2 = this.val2;

    return t;
}

私は他の答えが好きです。それは賢いですが、いくつかのプロパティを設定するだけで多くのチャーンが発生します。問題を考えすぎないでください。

于 2011-06-28T14:48:49.293 に答える