common-lisp - Common Lispでバイト配列を文字列に変換する方法は?

Question

バイト配列を返す面白い API を呼び出していますが、テキストストリームが必要です。バイト配列からテキストストリームを取得する簡単な方法はありますか? 今のところ、私は一緒に投げました：

(defun bytearray-to-string (bytes)
  (let ((str (make-string (length bytes))))
    (loop for byte across bytes
       for i from 0
       do (setf (aref str i) (code-char byte)))
    str))

結果をwith-input-from-stringでラップしますが、それは最善の方法ではありません。（さらに、それは恐ろしく非効率的です。）

この場合、常に ASCII であることはわかっているので、ASCII または UTF-8 として解釈しても問題ありません。私は Unicode 対応の SBCL を使用していますが、SBCL Unicode 固有のソリューションよりも移植可能な (たとえ ASCII のみの) ソリューションを好むでしょう。

score 32 · Accepted Answer

FLEXI-STREAMS ( http://weitz.de/flexi-streams/ ) にはポータブルな変換機能があります

(flexi-streams:octets-to-string #(72 101 108 108 111) :external-format :utf-8)

=>

"Hello"

または、ストリームが必要な場合:

(flexi-streams:make-flexi-stream
   (flexi-streams:make-in-memory-input-stream
      #(72 101 108 108 111))
   :external-format :utf-8)

バイトベクトルからテキストを読み取るストリームを返します

score 25 · Accepted Answer

この変換には、次の 2 つのポータブルライブラリがあります。

すでに別の回答で言及されているflexi-streams。

このライブラリは古く、より多くの機能、特に拡張可能なストリームを備えています。
Babel、特に文字のエンコードとデコードに特化したライブラリ

Flexi-Stream に対する Babel の主な利点は速度です。

最高のパフォーマンスを得るには、必要な機能がある場合は Babel を使用し、それ以外の場合はフレキシストリームにフォールバックします。速度の違いを示す (やや非科学的な) マイクロベンチマークの下。

このテストケースでは、Babel は337 倍高速で、必要なメモリは 200 分の 1 です。

(asdf:operate 'asdf:load-op :flexi-streams)
(asdf:operate 'asdf:load-op :babel)

(defun flexi-streams-test (bytes n)
  (loop
     repeat n
     collect (flexi-streams:octets-to-string bytes :external-format :utf-8)))

(defun babel-test (bytes n)
  (loop
     repeat n
     collect (babel:octets-to-string bytes :encoding :utf-8)))

(defun test (&optional (data #(72 101 108 108 111))
                       (n 10000))
  (let* ((ub8-vector (coerce data '(simple-array (unsigned-byte 8) (*))))
         (result1 (time (flexi-streams-test ub8-vector n)))
         (result2 (time (babel-test ub8-vector n))))
    (assert (equal result1 result2))))

#|
CL-USER> (test)
Evaluation took:
  1.348 seconds of real time
  1.328083 seconds of user run time
  0.020002 seconds of system run time
  [Run times include 0.12 seconds GC run time.]
  0 calls to %EVAL
  0 page faults and
  126,402,160 bytes consed.
Evaluation took:
  0.004 seconds of real time
  0.004 seconds of user run time
  0.0 seconds of system run time
  0 calls to %EVAL
  0 page faults and
  635,232 bytes consed.
|#

score 15 · Accepted Answer

UTF-8 エンコーディングについて心配する必要がない場合 (つまり、基本的には「単なる ASCII」を意味します)、MAP を使用できる可能性があります。

(map 'string #'code-char #(72 101 108 108 111))

score 7 · Accepted Answer

提案されたflexistreamまたはbabelソリューションを使用すると言います。

しかし、完全性と、このページに到達する将来の Google 社員の利益のために、sbcl 独自の sb-ext:octets-to-string について言及したいと思います。

   SB-EXT:OCTETS-TO-STRING is an external symbol in #<PACKAGE "SB-EXT">.
   Function: #<FUNCTION SB-EXT:OCTETS-TO-STRING>
   Its associated name (as in FUNCTION-LAMBDA-EXPRESSION) is
     SB-EXT:OCTETS-TO-STRING.
   The function's arguments are:  (VECTOR &KEY (EXTERNAL-FORMAT DEFAULT) (START 0)
                                          END)
   Its defined argument types are:
     ((VECTOR (UNSIGNED-BYTE 8)) &KEY (:EXTERNAL-FORMAT T) (:START T) (:END T))
   Its result type is:
     *

score 4 · Accepted Answer

SBCLは、いわゆるグレイストリームをサポートしています。これらは、CLOSクラスとジェネリック関数に基づく拡張可能なストリームです。バイト配列から文字を取得するテキストストリームサブクラスを作成できます。

score 0 · Accepted Answer

0

機能をお試しくださいFORMAT。 (FORMAT NIL ...)結果を文字列として返します。

于 2009-03-01T16:50:23.063 に答える

common-lisp - Common Lispでバイト配列を文字列に変換する方法は?

6 に答える 6

Related

Reference