4

このライブラリ libmyproject.a を構築しています。他のいくつかの静的ライブラリ (libone.a および libtwo.a) を含めて、libmyproject とリンクするアプリケーションが libone および libtwo とリンクする必要がないようにします。

私はGCCチェーンが初めてです。Visual C++ では、すべての依存関係を追加するだけで、必要な他のすべてのライブラリも含むライブラリが作成されます。

GCC でこれを達成するにはどうすればよいですか?

おまけの質問: 私はビルドに scons を使用しています。これを行うように scons に指示する方法はありますか? 現在、私が提供するすべての追加ライブラリを無視し、.cpp ファイルのみをライブラリにコンパイルします。

4

1 に答える 1

2

アーカイブ ファイルの操作にはar ( binutils )を使用する必要があります。マージを行うために単純な Perl スクリプトを使用しています。

#!/usr/bin/perl

use warnings;
use strict;
use File::Temp qw(tempdir);
use File::Basename;
use Getopt::Long;

my %opt;
if (!GetOptions(\%opt,
                "dest=s",
               )) {
  die "Invalid option!";
}


my $tempdir = tempdir( CLEANUP => 1 );

if (!chdir($tempdir)) {
    die "Couldn't change directories to `$tempdir': $!";
}

foreach my $lib (@ARGV) {
    my $subdir = $tempdir . '/' . basename($lib);
    mkdir($subdir) or die "Unable to make $subdir: $!";
    chdir($subdir) or die "Unable to cd $subdir: $!";
    system("ar x $lib");
}
chdir($tempdir) or die "Unable to cd $tempdir: $!";
system("ar cr $opt{dest} */*.o") == 0 or die "'ar cr' failed: $?";
system("ranlib $opt{dest}") == 0 or die "'ranlib' failed: $?";

exit 0;

SCons でスクリプトを呼び出すには:

# this can be put to site_scons/site_init.py
def MergeLibs(env, target, sources):
    """Rapack multiple archive files into one."""
    merge_libs_tool = os.path.join('$TOOLS_DIR', 'merge_libraries.pl')
    lib = env.Command('${LIBPREFIX}' + target + '${LIBSUFFIX}', [merge_libs_tool] + sources,
            '$SOURCE -dest ${TARGET.abspath} ${SOURCES[1:].abspath}')
    return lib

# lib_one = env.StaticLibrary(...)
# lib_two = env.StaticLibrary(...)
# merged_lib = env.MergeLibs('myproject', [libone, libtwo])

もちろん、SCons 内の Python 関数を使用してライブラリをマージできます。他のビルド ツールと同じようにコマンド ラインから実行できるように、別のスクリプトを使用することを好みます。

于 2011-05-20T17:33:39.883 に答える