3

私は一種のトリッキーなオラクルの問題を抱えています。1 つのデータ セットを選択しようとしています。アイテムと呼びます。アイテムごとに別のプロシージャを呼び出して、インベントリ アイテムを返します。実行方法がわからない操作が 2 つあります。

  1. ネストされたプロシージャから値を取得するにはどうすればよいですか?

  2. 取得した値を SYS_REFCURSOR の形式で返すにはどうすればよいですか?

ここでの試みは、spSelect_Inv_Search からの結果を、ITEMS_TABLE というネストされたテーブルに入れることでした。これは機能していません。

以下のコード

PROCEDURE SPSELECT_ITEM (IO_CURSOR OUT SYS_REFCURSOR) 
AS   
  MY_CURSOR SYS_REFCURSOR;
  TYPE ITEM_TYPE IS TABLE OF ITEMS.ITEM_NO%TYPE;
  ITEM_TABLE ITEM_TYPE := ITEM_TYPE();

  CURSOR ITEMS_CURSOR IS
      SELECT ITEM_NO 
      FROM ITEMS;

  V_COUNTER INTEGER := 0;
BEGIN
  FOR ITEM_REC IN ITEM_CURSOR LOOP
    V_COUNTER := V_COUNTER + 1;
    ITEM_TABLE.EXTEND;
    ITEM_TABLE(V_COUNTER) := spSelect_Inv_Search(ITEM_REC.ITEM_NO, MY_CURSOR);
  END LOOP;
END SPSELECT_ITEMS;

どんな助けでも大歓迎です、ありがとう。

4

2 に答える 2

0

SYS_REFCURSOR不明な数の結果セットを 1 つの大きな結果セットにマージしたいと考えているようです。返されたカーソルの構造がわかっている場合は、spSelect_Inv_Searchパイプライン化された中間関数を使用してこれを行うことができます。

create package p as
    type tmp_rec_type is record (owner all_objects.owner%type,
        object_type all_objects.object_type%type,
        objects number);
    type tmp_rec_table is table of tmp_rec_type;

    procedure proc1(p_owner in varchar2, p_cursor out sys_refcursor);
    function func2 return tmp_rec_table pipelined;
    procedure proc3(p_cursor out sys_refcursor);
end;
/

タイプはここで定義できます。パッケージの外部で参照する必要がないため、SQL レベルである必要はありません。

create package body p as
    procedure proc1(p_owner in varchar2, p_cursor out sys_refcursor) as
    begin
        open p_cursor for select owner, object_type, count(*)
            from all_objects
            where owner = p_owner
            group by owner, object_type;
    end;

    function func2 return tmp_rec_table pipelined as
        cursor c1 is select distinct owner
            from all_tables where owner in ('SYS','SYSTEM');
        tmp_cursor sys_refcursor;
        tmp_rec tmp_rec_type;
    begin
        for r1 in c1 loop
            proc1(r1.owner, tmp_cursor);
            loop
                fetch tmp_cursor into tmp_rec;
                exit when tmp_cursor%notfound;
                pipe row(tmp_rec);
            end loop;
        end loop;
    end;

    procedure proc3(p_cursor out sys_refcursor) as
    begin
        open p_cursor for select * from table(func2);
    end;
end p;
/

次に、中間段階で使用される型に関係なく、パッケージの外部で実行できます。これを実行して、SQL*Plus または SQL Developer でテストできます。

var rc refcursor;
exec p.proc3(:rc);
print rc;

私のデータベースでは、次のようになります。

OWNER                          OBJECT_TYPE         OBJECTS                
------------------------------ ------------------- ---------------------- 
SYSTEM                         VIEW                1                      
SYSTEM                         TABLE               5                      
SYS                            VIEW                1056                   
SYS                            CONSUMER GROUP      2                      
SYS                            PROCEDURE           11                     
SYS                            FUNCTION            56                     
SYS                            SEQUENCE            1                      
SYS                            OPERATOR            6                      
SYS                            EVALUATION CONTEXT  1                      
SYS                            TABLE               13                     
SYS                            WINDOW GROUP        1                      
SYS                            PACKAGE             162                    
SYS                            WINDOW              2                      
SYS                            TYPE                529                    
SYS                            JOB CLASS           1                      
SYS                            SCHEDULE            1

これは明らかに非常に不自然ですが、これは単一のクエリとして実行するためですが、内部の手順でもっと複雑なことを行う必要があると想定しています。

于 2011-05-18T17:55:42.417 に答える
0

を呼び出す方法についての質問に答えるにspSelect_Inv_Searchは、そのサブプログラムの署名を知る必要があります。プロシージャとして説明しましたが、関数として呼び出そうとしています。それはどれですか？どのような戻り値および/または OUT モード パラメータがありますか?

CREATE TYPE上記のプロシージャからオープン REF CURSOR を返すには、最初にネストした表の型をPL/SQLコードではなくスキーマ・レベルで(文を使用して)宣言する必要があります。次に、ネストされたテーブルにデータを入力した後、そのようにカーソルを開くことができます。

OPEN io_cursor FOR SELECT * FROM TABLE(CAST(item_table AS item_type));

(ちなみに、型の名前を自分で から に変更しITEM_TYPEますITEM_TABLE_TYPE。)

于 2011-05-18T16:36:50.073 に答える