haskell - hsc2hsを使用して定数、関数、およびデータ構造にバインドするにはどうすればよいですか？

Question

hsc2hsの使用方法の例が必要です。次のようなヘッダーファイルを作成すると、次のようになります。

// foo.h
#define PI 3.14159

typedef struct {
    int i1;
    int i2;
} foo;

struct foo2 {
    int i1;
    int i2;
};

int fooFkt(foo f);

次に、次のようなhscファイルを作成します。

import Foreign
import Foreign.C

#include "foo.h"

使用hsc2hs：

{-# INCLUDE "foo.h" #-}
{-# LINE 1 "test.hsc" #-}
import Foreign
{-# LINE 2 "test.hsc" #-}
import Foreign.C


{-# LINE 5 "test.hsc" #-}

私はそれを理解していません、私は帽子hsc2hsが私のために必要なすべてのものをインポートすると思いましたPI

誰が私にもっと良い例を与えることができますか？

Answer 1

RWH ch 17PIに続いて、C値をHaskellのシンボルにバインドする何かを導入する必要があります。

例えば：

{-# LANGUAGE ForeignFunctionInterface #-}
{-# LANGUAGE CPP                      #-}

import Foreign
import Foreign.C

-- helpers
import Control.Applicative
import Control.Monad

#include "foo.h"

-- binding a symbol

-- Note that hsc2hs can't marshal floating point CPP values, so this will be "3"
-- c_pi :: CInt
-- c_pi = #const PI

-- Instead, bind to a function that returns a CFloat
pi' :: Float
pi' = realToFrac c_pi

foreign import ccall unsafe "my_pi" c_pi :: CFloat

そして、私たちがここにいる間、Haskellとの間で構造体をマーシャリングすることもできます：

-- Marshalling for the struct foo

data Foo = Foo { i1, i2 :: Int }
    deriving Show

-- Define how to marshal foo structs

instance Storable Foo where
    sizeOf    _ = #{size foo}

    alignment _ = alignment (undefined :: CInt)

    poke p foo  = do
        #{poke foo, i1} p $ i1 foo
        #{poke foo, i2} p $ i2 foo

    peek p = return Foo
              `ap` (#{peek foo, i1} p)
              `ap` (#{peek foo, i2} p)

そして関数にバインドしfooFktます：

-- Import the function too

foreign import ccall "foo.h fooFkt"
    c_fooFkt :: Ptr Foo -> IO CInt

-- Marshal data to and from C

fooFkt :: Foo -> IO Int
fooFkt f = fromIntegral <$> with f c_fooFkt

終わり。

Answer 2

あなたが実際にからのいくつかの定義を使用する場合、それは機能しますfoo.h：

import Foreign
import Foreign.C

#include "foo.h"

pi = #const PI

与える

{-# INCLUDE "foo.h" #-}
{-# LINE 1 "test.hsc" #-}
import Foreign
{-# LINE 2 "test.hsc" #-}
import Foreign.C


{-# LINE 5 "test.hsc" #-}

pi = 3
{-# LINE 7 "test.hsc" #-}

ネットワークパッケージの実際の使用例を次に示します。https ：//github.com/haskell/network/blob/master/Network/Socket/ByteString/MsgHdr.hsc