2

私は最近、XS を使用して Perl (v5.8.8) 拡張機能を書き始めました。私が書いているメソッドの 1 つは、大量のデータを収集し、それをクライアントにスプラットします。出力に対してアサーションを行う単体テストを書きたいのですが、問題が発生しています。PerlIO メソッドがprint、Perl の呼び出しと同じチャネルを介してデータを渡しているようには見えません。通常、STDOUT ファイル ハンドラーに接続して結果をインターセプトできますが、PerlIO メソッドはこれを完全にバイパスしているようです。

以下に例を貼り付けましたが、私のテストの基本的な要点は次のとおりTieです。これを行うと、ステートメントをキャプチャできますが、モジュールからの呼び出しはキャプチャできません。、、などを使ってみました。サイコロはありません。STDOUTuntieprintPerlIO_*PerlIO_writePerlIO_putsPerlIO_printf

最初から、ここに私がやっていることの最小限の再現があります:

h2xs -A -n IOTest
cd IOTest

これを に入れますIOTest.xs:

#include "EXTERN.h"
#include "perl.h"
#include "XSUB.h"
#include "ppport.h"

MODULE = IOTest PACKAGE = IOTest

void
oink ()
    CODE:
        PerlIO_puts(PerlIO_stdout(), "oink!\n");

そして、これは次のファイルに入りますtest.pl(興味深い部分は一番下にあり、それ以外はすべて stdout をキャプチャするためのものです):

# Set up the include path to match the build directories
BEGIN {
    push @INC, './blib/lib/';
    push @INC, './blib/arch/auto/IOTest';
}

use IOTest;

# This package is just a set of hooks for tieing in to stdout
{
    # Lifted from the Test::Output module found here:
    # http://search.cpan.org/~bdfoy/Test-Output-1.01/lib/Test/Output.pm
    package OutputTie;

    sub TIEHANDLE {
      my $class = shift;
      my $scalar = '';
      my $obj = shift || \$scalar;
      bless( $obj, $class);
    }

    sub PRINT {
        my $self = shift;
        $$self .= join(defined $, ? $, : '', @_);
        $$self .= defined $\ ? $\ : '';
    }

    sub PRINTF {
        my $self = shift;
        my $fmt  = shift;
        $$self .= sprintf $fmt, @_;
    }

    sub read {
        my $self = shift;
        my $data = $$self;
        $$self = '';
        return $data;
    }
}

# Runs a sub, intercepts stdout and returns it as a string
sub getStdOut (&) {
    my $callback = shift;

    select( ( select(STDOUT), $| = 1 )[0] );
    my $out = tie *STDOUT, 'OutputTie';

    $callback->();
    my $stdout = $out->read;

    undef $out;
    untie *STDOUT;

    return $stdout;
}

# This is the interesting part, the actual test:
print "Pre-capture\n";
my $output = getStdOut(sub {
    print "before";
    IOTest::oink();
    print "after";
});
print "Captured StdOut:\n" . $output . "\nend\n";

ビルドとテストは、次の問題だけです。

perl Makefile.PL
make
perl test.pl

私が見ている出力は次のとおりです。

Pre-capture
oink!
Captured StdOut:
beforeafter
end

明らかに、私は「ブー！」と期待しています。「前」と「後」の間に挟まれているが、それは起こっていないようだ.

何か案は？

4

1 に答える 1

2

キャプチャーがおかしいと思います。比較：

use IOTest;
use Capture::Tiny qw(capture);

print "Pre-capture\n";
my $output = capture {
    print "before";
    IOTest::oink();
    print "after";
};
print "Captured StdOut:\n" . $output . "\nend\n";

Pre-capture
Captured StdOut:
beforeoink!
after
end
于 2011-05-24T19:18:17.737 に答える