1

現在、RESTWebサービスを使用しているVB.NETを使用してアプリケーションを開発しています。私はRESTで基本的なことを行うことができましたが、添付ファイルを追加することができませんでした（より具体的には、添付されたRESTを使用してファイルをアップロードします）。私はオンラインで広範囲にわたる調査を行いましたが、これまでのところ、VB.NETで実用的な例を見つけることができませんでした。実際にデータをアップロードするには、System.Net.WebClientを使用します。次のVB.NETコードは、重要な作業を実行します。

Dim Client As New System.Net.WebClient
Dim postBytes As Byte() = System.Text.Encoding.ASCII.GetBytes(postString)
Client.UploadData(URL, "POST", postBytes)

私のURLの簡略版は次のとおりです。 "../REST/1.0/ticket/" + ticketNumber + "/comment?user=" + userName + "&pass=" + password

最後に、私が投稿するコンテンツの例は次のとおりです。

postString = "content=Text: RT Test" + vbLf + "Action: Comment" + vbLf + "Attachment: examplefile.jpg" + vbLf + "attachment_1="

ご覧のとおり、postStringはバイトに変換されてから、サーバーにアップロードされます。ただし、生の添付ファイル自体をどこに、どのように投稿する必要があるのか​​わかりません。特に状態を使用してpostString変数に追加した変数「attachment_1」を使用しているサービスのドキュメントですが、次のステップがどうあるべきかわかりません。ファイルをバイトに変換してpostBytes変数に追加する必要がありますか？このようなことを試みましたが、examplefile.jpgの添付ファイルが見つからないというエラーが表示されました。

ご協力いただきありがとうございます！

4

1 に答える 1

2

Client.UploadData（...）を使用できず、投稿全体をバイトに変換する必要がありました。添付ファイルの前のPOSTフィールドから始まり、添付ファイル自体、最後に残りのPOSTフィールドです。

Public Sub AddAttachmentToRT(ByVal url As String, ByVal fileName As String, ByVal filePath As String)

    Dim dataBoundary As String = "--xYzZY"
    Dim request As HttpWebRequest
    Dim fileType As String = "image/jpeg" 'Will want to extract this to make it more generic from the uploaded file.

    'Create a POST web request to the REST interface using the passed URL
    request = CType(WebRequest.Create(url), HttpWebRequest)
    request.ContentType = "multipart/form-data; boundary=xYzZY"
    request.Method = "POST"
    request.KeepAlive = True

    'Write the request to the requestStream
    Using requestStream As IO.Stream = request.GetRequestStream()

        'Create a variable "attachment_1" in the POST, specify the file name and file type
        Dim preAttachment As String = dataBoundary + vbCrLf _
        + "Content-Disposition: form-data; name=""attachment_1""; filename=""" + fileName + """" + vbCrLf _
        + "Content-Type: " + fileType + vbCrLf _
        + vbCrLf

        'Convert this preAttachment string to bytes
        Dim preAttachmentBytes As Byte() = System.Text.Encoding.UTF8.GetBytes(preAttachment)

        'Write this preAttachment string to the stream
        requestStream.Write(preAttachmentBytes, 0, preAttachmentBytes.Length)

        'Write the file as bytes to the stream by passing its exact location
        Using fileStream As New IO.FileStream(Server.MapPath(filePath + fileName), IO.FileMode.Open, IO.FileAccess.Read)

            Dim buffer(4096) As Byte
            Dim bytesRead As Int32 = fileStream.Read(buffer, 0, buffer.Length)

            Do While (bytesRead > 0)

                requestStream.Write(buffer, 0, bytesRead)
                bytesRead = fileStream.Read(buffer, 0, buffer.Length)

            Loop

        End Using

        'Create a variable named content in the POST, specify the attachment name and comment text
        Dim postAttachment As String = vbCrLf _
        + dataBoundary + vbCrLf _
        + "Content-Disposition: form-data; name=""content""" + vbCrLf _
        + vbCrLf _
        + "Action: comment" + vbLf _
        + "Attachment: " + fileName + vbCrLf _
        + "Text: Some description" + vbCrLf _
        + vbCrLf _
        + "--xYzZY--"

        'Convert postAttachment string to bytes
        Dim postAttachmentBytes As Byte() = System.Text.Encoding.UTF8.GetBytes(postAttachment)

        'Write the postAttachment string to the stream
        requestStream.Write(postAttachmentBytes, 0, postAttachmentBytes.Length)

    End Using

    Dim response As Net.WebResponse = Nothing

    'Get the response from our REST request to RT
    'Required to capture response, without this Try-Catch attaching will fail
    Try
        response = request.GetResponse()

        Using responseStream As IO.Stream = response.GetResponseStream()

            Using responseReader As New IO.StreamReader(responseStream)

                Dim responseText = responseReader.ReadToEnd()

            End Using

        End Using

    Catch exception As Net.WebException

        response = exception.Response

        If (response IsNot Nothing) Then

            Using reader As New IO.StreamReader(response.GetResponseStream())

                Dim responseText = reader.ReadToEnd()

            End Using

            response.Close()

        End If

    Finally

        request = Nothing

    End Try

End Sub
于 2011-06-06T20:02:37.477 に答える