4

開発サーバーと運用サーバーの間でファイルを転送するために使用する ColdFusion アプリケーションがあります。実際にファイルを送信するコードは次のとおりです。

ftp = new Ftp();
ftp.setUsername(username);
ftp.setPassword(password);
ftp.setServer(server);
ftp.setTimeout(1800);
ftp.setConnection('dev');
ftp.open();
ftp.putFile(transferMode="binary",localFile=localpath,remoteFile=remotepath);
ftp.close(connection='dev');

上記のコードを使用してファイルを送信する場合、100KB/秒未満で上限を設定します (受信サーバーの FileZilla を介して監視)。Windows コマンドライン FTP ツールを使用してまったく同じファイルを送信すると、速度は 1000KB/s を超えます。

上記のコードだけでまったく新しいファイルを作成しましたが、それは転送速度に影響を与えないため、元のアプリケーションの周囲のコードとは何の関係もないことがわかります.

では、これらの異常に遅い速度の原因は何でしょうか?

編集:すべてのテストは、実稼働サーバーから開発サーバーにファイルを転送して行われています。<cfftp>cfscript の代わりにタグを使用してみましたが、同じ結果が得られました。

編集＃2：cfexecuteコードは次のとおりです。

私のFTPスクリプトから：

public function sendFiles(required string localpath, required string remotepath) {
    this.writeFtpInstructions(localpath);
    exe = "C:\Windows\system32\ftp.exe";
    params = "-s:" & request.localapproot & "/" & "upload.txt";
    outputfile = request.localapproot & '/ftp.log';
    timeout = 120;
    Request.cliExec(exe,params,outputfile,timeout);
}

public function writeFtpInstructions(required string localpath) {
    instructions = request.localapproot & "/" & "upload.txt";
    crlf = chr(13) & chr(10);
    data = "";
    data &= "open " & this.server & crlf;
    data &= this.username & crlf;
    data &= this.password & crlf;
    data &= "cd " & request.remoteapproot & crlf;
    data &= "put " & localpath & crlf;
    data &= "quit";
    FileWrite(instructions, data);
}

cliExec()関数（cfscriptに相当するものがないため、ラッパーを作成する必要があります）cfexecute：

<cffunction name="cliExec">
    <cfargument name="name">
    <cfargument name="arguments">
    <cfargument name="outputfile">
    <cfargument name="timeout">
    <cfexecute
        name="#name#"
        arguments="#arguments#"
        outputFile="#outputfile#"
        timeout="#timeout#" />
</cffunction>
4

2 に答える 2

3

CF9 で cfftp を使用した経験では、より大きなファイルを転送することは不可能でした。FTP サーバー側でアクティブな転送を表示すると、転送は最高速度で開始されますが、送信されるデータが増えるにつれて速度が低下し続けることがわかります。100 MB が転送された後、削減は非常に劇的になり始め、最終的には 1 桁のクロールに達しました。最終的に転送がタイムアウトし、失敗しました。330 MB のファイルを処理しようとしましたが、cfftp を使用して転送できないことがわかりました。SFTPをサポートしていないように見えるため、標準のWindows ftp.exeを使用する場合、cfexecuteはオプションではありませんでした。

私は、coldfusion で使用する外部 Java クラスを探し、JSch (http://www.jcraft.com/jsch/) に落ち着きました。皮肉なことに、CF9 は CFFTP にこのクラスのバリエーション (jsch-0.1.41m.jar) を使用しているように見えますが、この最新のダウンロード バージョン (jsch-0.1.45.jar) を使用すると、結果は大きく異なります。

概念実証のためにまとめたコードは次のとおりです。

<cfscript>
    stAppPrefs = {
        stISOFtp = {
             server = 'sftp.server.com',
             port = '22',
             username = 'youser',
             password = 'pa$$w0rd'
        }
    };

    /* Side-Load JSch Java Class (http://www.jcraft.com/jsch/) */
    try {
        // Load Class Using Mark Mandel's JavaLoader (http://www.compoundtheory.com/?action=javaloader.index)
        /* 
        Add Mark's LoaderClass To The ColdFusion Class Path Under CF Admin:
        Java and JVM : ColdFusion Class Path : C:\inetpub\wwwroot\javaloader\lib\classloader-20100119110136.jar
        Then Restart The Coldfusion Application Service
        */
        loader = CreateObject("component", "javaloader.JavaLoader").init([expandPath("jsch-0.1.45.jar")]);
        // Initiate Instance
        jsch = loader.create("com.jcraft.jsch.JSch").init();
    }
    catch(any excpt) {          
        WriteOutput("Error loading ""jsch-0.1.45.jar"" java class: " & excpt.Message & "<br>");
        abort;
    }

    /* SFTP Session & Channel */
    try {
        // Create SFTP Session
        session = jsch.getSession(stAppPrefs.stISOFtp.username, stAppPrefs.stISOFtp.server, stAppPrefs.stISOFtp.port);
        // Turn Off & Use Username/Password
        session.setConfig("StrictHostKeyChecking", "no");
        session.setPassword(stAppPrefs.stISOFtp.password);
        session.connect();
        // Create Channel To Transfer File(s) On
        channel = session.openChannel("sftp");
        channel.connect();
    }
    catch(any excpt) { 
        WriteOutput("Error connecting to FTP server: " & excpt.Message & "<br>");
        abort;
    } 

    // Returns Array Of Java Objects, One For Each Zip Compressed File Listed In Root DIR
    // WriteDump(channel.ls('*.zip'));      
    // Get First Zip File Listed For Transfer From SFTP To CF Server
    serverFile = channel.ls('*.zip')[1].getFilename();

    /* Debug */
    startTime = Now();
    WriteOutput("Transfer Started: " & TimeFormat(startTime, 'hh:mm:ss') & "<br>");
    /* // Debug */

    /* Transfer File From SFTP Server To CF Server */
    try {
        // Create File On Server To Write Byte Stream To
        transferFile = CreateObject("java", "java.io.File").init(expandPath(serverFile));
        channel.get(serverFile, CreateObject("java", "java.io.FileOutputStream").init(transferFile));
        // Close The File Output Stream
        transferFile = '';
    }
    catch(any excpt) { 
        WriteOutput("Error transfering file """ & expandPath(serverFile) & """: " & excpt.Message & "<br>");
        abort;
    }

    /* Debug */
    finishTime = Now();
    WriteOutput("Transfer Finished: " & TimeFormat(finishTime, 'hh:mm:ss') & "<br>");
    expiredTime = (finishTime - startTime);
    WriteOutput("Duration: " & TimeFormat(expiredTime, 'HH:MM:SS') & "<br>");
    WriteOutput("File Size: " & NumberFormat(Evaluate(GetFileInfo(ExpandPath(serverFile)).size / 1024), '_,___._') & " KB<br>");
    WriteOutput("Transfer Rate: " & NumberFormat(Evaluate(Evaluate(GetFileInfo(ExpandPath(serverFile)).size / 1024) / Evaluate(((TimeFormat(expiredTime, 'H') * 60 * 60) + (TimeFormat(expiredTime, 'M') * 60) + TimeFormat(expiredTime, 'S')))), '_,___._') & " KB/Sec <br>");
    /* // Debug */

    channel.disconnect();
    session.disconnect();
    </cfscript>

結果：

Transfer Started: 09:37:57
Transfer Finished: 09:42:01
Duration: 00:04:04
File Size: 331,770.8 KB
Transfer Rate: 1,359.7 KB/Sec

達成された転送速度は、FileZilla FTP クライアントを使用して手動でダウンロードしたものと同等です。この方法は、cfftp の不十分さに対する実行可能な解決策であることがわかりました。

于 2012-01-10T03:07:20.763 に答える
2

私は探していましたが、なぜ遅いのかについて答えがありません。ただし、理論的には、Windows コマンド ラインから cfexecute を使用してこれを実行できるはずです。バッチ ファイルを作成して、1 回の呼び出しで実行することもできます。

于 2011-05-27T17:36:08.640 に答える