9

私はErlangを学び始めているので、「Hello、world！」を書こうとしています。並行プログラミングのIRCボット。

私はすでに、OTPの優れた機能（スーパーバイザー、アプリケーションなどの動作）なしでErlangを使用して作成しました。OTPの原則を使用して書き直そうとしていますが、残念ながら、OTPを使用してソケットプログラミングを行う「正しい」方法を理解できません。

別のプロセスを手動で作成してスーパーバイザーにリンクするのが唯一の合理的な方法のようですが、確かに誰かが以前にこれを行ったことがあるでしょう。

4

3 に答える 3

4

これがあなたが探しているものだと思います：http： //www.trapexit.org/Building_a_Non-blocking_TCP_server_using_OTP_principles これは、OTPを使用して非ブロッキングTCPサーバーを構築する方法についての完全なチュートリアルです（もちろん、完全に文書化され、説明されています） 。

于 2011-05-30T07:03:11.043 に答える
4

Erlang/OTP を学び始めてよかったです!

次のリソースは非常に役立ちます。

  • OTP設計原則。まだ読んでいない場合は、これを注意深く読んでください。OTP はオブジェクト指向 (OO) であるという一般的な誤解に注意してください。そうではありません! 「継承」についてのすべてを忘れてください。標準モジュールを「拡張」するだけでは、完全なシステムを構築することはできません。
  • メッセージングシステム :

    これらの関数は、プロセスのシステム メッセージの使用を実装するために使用する必要があります。

  • 特別なプロセス。特別なプロセスは、スーパーバイザーとうまく統合できる OTP 準拠のプロセスです。

これは私のプロジェクトにあるコードです。私も Erlang の学習者なので、コードをあまり信用しないでください。

-module(gen_tcpserver).

%% Public API
-export([start_link/2]).

%% start_link reference
-export([init/2]).

%% System internal API
-export([system_continue/3, system_terminate/4, system_code_change/4]).

-define(ACCEPT_TIMEOUT, 250).

-record(server_state, {socket=undefined,
                       args,
                       func}).

%% ListenArgs are given to gen_tcp:listen
%% AcceptFun(Socket) -> ok, blocks the TCP accept loop
start_link(ListenArgs, AcceptFun) ->
    State = #server_state{args=ListenArgs,func=AcceptFun},
    proc_lib:start_link(?MODULE, init, [self(), State]).

init(Parent, State) ->
    {Port, Options} = State#server_state.args,
    {ok, ListenSocket} = gen_tcp:listen(Port, Options),
    NewState = State#server_state{socket=ListenSocket},
    Debug = sys:debug_options([]),
    proc_lib:init_ack(Parent, {ok, self()}),
    loop(Parent, Debug, NewState).

loop(Parent, Debug, State) ->
    case gen_tcp:accept(State#server_state.socket, ?ACCEPT_TIMEOUT) of
        {ok, Socket} when Debug =:= [] -> ok = (State#server_state.func)(Socket);
        {ok, Socket} ->
            sys:handle_debug(Debug, fun print_event/3, undefined, {accepted, Socket}),
            ok = (State#server_state.func)(Socket);
        {error, timeout} -> ok;
        {error, closed} when Debug =:= [] ->
            sys:handle_debug(Debug, fun print_event/3, undefined, {closed}),
            exit(normal);
        {error, closed} -> exit(normal)
    end,
    flush(Parent, Debug, State).

flush(Parent, Debug, State) ->
    receive
        {system, From, Msg} ->
            sys:handle_system_msg(Msg, From, Parent, ?MODULE, Debug, State)
        after 0 ->
            loop(Parent, Debug, State)
    end.

print_event(Device, Event, _Extra) ->
    io:format(Device, "*DBG* TCP event = ~p~n", [Event]).

system_continue(Parent, Debug, State) ->
    loop(Parent, Debug, State).

system_terminate(Reason, _Parent, _Debug, State) ->
    gen_tcp:close(State#server_state.socket),
    exit(Reason).

system_code_change(State, _Module, _OldVsn, _Extra) ->
    {ok, State}.

これは準拠した OTP プロセスであることに注意してください (スーパーバイザーが管理できます)。AcceptFun新しいワーカーの子を生成 (=高速化) するために使用する必要があります。私はまだそれを徹底的にテストしていません。

1> {ok, A} = gen_tcpserver:start_link({8080,[]},fun(Socket)->gen_tcp:close(Socket) end).
{ok,<0.93.0>}
2> sys:trace(A, true).
ok
*DBG* TCP event = {accepted,#Port<0.2102>}
*DBG* TCP event = {accepted,#Port<0.2103>}
3>

(2>の後ok、Google Chrome ブラウザーをポート 8080 に向けました。これは TCP の優れたテストです!)

于 2011-06-28T22:38:54.883 に答える
2

非同期 TCP リスナーを実装する別の方法は、supervisor_bridge.

これを示すために私が書いたコードを次に示します（テストされていません）：

-module(connection_bridge).

-behaviour(supervisor_bridge).

% supervisor_bridge export
-export([init/1, terminate/2]).

% internal proc_lib:start_link
-export([accept_init/3]).

%% Port: see gen_tcp:listen(Port, _).
%% Options: see gen_tcp:listen(_, Options).
%% ConnectionHandler: Module:Function(Arguments)->pid() or fun/0->pid()
%% ConnectionHandler: return pid that will receive TCP messages
init({Port, Options, ConnectionHandler}) ->
    case gen_tcp:listen(Port, Options) of
        {ok, ListenSocket} ->
            {ok, ServerPid} = proc_lib:start_link(?MODULE, accept_init,
                [self(), ListenSocket, ConnectionHandler], 1000),
            {ok, ServerPid, ListenSocket};
        OtherResult -> OtherResult
    end.

terminate(_Reason, ListenSocket) ->
    gen_tcp:close(ListenSocket).

accept_init(ParentPid, ListenSocket, ConnectionHandler) ->
    proc_lib:init_ack(ParentPid, {ok, self()}),
    accept_loop(ListenSocket, ConnectionHandler).

accept_loop(ListenSocket, ConnectionHandler) ->
    case gen_tcp:accept(ListenSocket) of
        {ok, ClientSocket} ->
            Pid = case ConnectionHandler of
                {Module, Function, Arguments} ->
                    apply(Module, Function, Arguments);
                Function when is_function(Function, 0) ->
                    Function()
            end,
            ok = gen_tcp:controlling_process(ClientSocket, Pid),
            accept_loop(ListenSocket, ConnectionHandler);
        {error, closed} ->
            error({shutdown, tcp_closed});
        {error, Reason} ->
            error(Reason)
    end.

私の他の答えよりもはるかに理解しやすいです。UDP と SCTP もサポートするconnection_bridgeように拡張できます。

于 2011-06-30T19:08:24.673 に答える