0

ロード時にオーディオを再生する単純な.swfファイルを作成しようとしています。これはコンパイルされますが、ブラウザに表示しても何も起こりません。スプライトベースのチュートリアルしか見つからなかったので、スプライトを拡張するのと同じ方法でサウンドを拡張できることを確認しました。最終バージョンはヘッドレスになり、イベントでオーディオを再生するためにJavaスクリプトと呼ばれます。

   package {
            import flash.media.Sound;
            import flash.net.URLRequest;

            public class typeRight extends Sound {
                    public function HelloWorld( ) {
                    load(new URLRequest('./sound.mp3'));
                    play();
                    }
            }
    }


私はFlashで作業していないので、GUIのアドバイスはしないでください。）。

4

1 に答える 1

2

Soundクラスをサブクラス化するのではなく、Soundクラスを含む次のようなドキュメントクラスを作成します。

package
{
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.media.Sound;
    import flash.media.SoundChannel;
    import flash.net.URLRequest;

    public class SoundPlayer extends Sprite
    {
        protected var _sound : Sound;
        protected var _channel : SoundChannel;

        public function SoundPlayer()
        {
            _sound = new Sound();
            _sound.addEventListener(Event.COMPLETE, soundLoadCompleteHandler);
            _sound.addEventListener(IOErrorEvent.IO_ERROR, loadError);
            _sound.load(new URLRequest("./sound.mp3"));
        }

        protected function soundLoadCompleteHandler(evt : Event) : void
        {
            // Use the _channel object to control sound properties such as pan and volume.
            _channel = _sound.play();
        }

        protected function loadError(evt : IOErrorEvent) : void
        {
            trace ("ERROR :: " + evt);
            // You could try recovering from the error here.
        }

    }
}
于 2011-05-31T23:18:51.040 に答える