1

このページRsyntaxTextAreaでJava を使用して次のコードを実行し、このサイトで言及されているとおりにプログラムを実行しました。意図したとおりに出力を取得しています。しかし、私はこのJavaコードを次のようなGroovyコードに変更しようとしました:

import groovy.swing.SwingBuilder
import javax.swing.*
import java.awt.*
swing =  new SwingBuilder()
frame = swing.frame(title : "test", defaultCloseOperation:JFrame.EXIT_ON_CLOSE, pack:true, show : true, size :[100,100])
{
        panel
        {
             RSyntaxTextArea textArea = new RSyntaxTextArea();
             textArea.setSyntaxEditingStyle(SyntaxConstants.SYNTAX_STYLE_JAVA);
        }
}

そして、次のようにこのスクリプトを実行しようとすると:

groovyc -classpath rsyntaxtextarea.jar TextEditorDemo.groovy

次のようなエラーが表示されます。

groovy: 9: unable to resolve class RSyntaxTextArea 
 @ line 9, column 19.
        RSyntaxTextArea textArea = new RSyntaxTextArea();
                     ^

/home/anto/Groovy/Rsyntax/ST.groovy: 9: unable to resolve class RSyntaxTextArea 
 @ line 9, column 30.
        RSyntaxTextArea textArea = new RSyntaxTextArea();
                                ^

/home/anto/Groovy/Rsyntax/ST.groovy: 10: unable to resolve class RSyntaxTextArea 
 @ line 10, column 7.
         textArea.setSyntaxEditingStyle(SyntaxConstants.SYNTAX_STYLE_JAVA);

私はプログラムの実行に間違いを犯したと思います。この場合、クラスパスも定義してプログラムを実行するにはどうすればよいですか。

4

2 に答える 2

3

RSyntaxTextArea のパッケージをインポートしているようには見えません。次のインポートをプログラムに追加しようとしましたか?

import org.fife.ui.rtextarea.*;
import org.fife.ui.rsyntaxtextarea.*;
于 2011-06-14T04:43:27.913 に答える
1

このコードはあなたが望むことをするはずです...RSyntaxTextAreaビューに追加する必要がありました（widgetメソッドを使用して）

JScrollPaneいっぱいになったときにうまくスクロールできるように、 に追加する必要もありました。

import groovy.swing.SwingBuilder
import java.awt.BorderLayout as BL
import static javax.swing.JFrame.EXIT_ON_CLOSE
import org.fife.ui.rsyntaxtextarea.*

RSyntaxTextArea textArea = new RSyntaxTextArea()
textArea.syntaxEditingStyle = SyntaxConstants.SYNTAX_STYLE_JAVA

swing =  new SwingBuilder()
frame = swing.frame(title:"test", defaultCloseOperation:EXIT_ON_CLOSE, size:[600,400], show:true ) {
  borderLayout()
  panel( constraints:BL.CENTER ) {
    borderLayout()
    scrollPane( constraints:BL.CENTER ) {
      widget textArea
    }
  }
}

編集

ウィジェットを使用しない場合、コードは次のようになります。

import groovy.swing.SwingBuilder
import java.awt.BorderLayout as BL
import static javax.swing.JFrame.EXIT_ON_CLOSE
import org.fife.ui.rsyntaxtextarea.*

RSyntaxTextArea textArea = new RSyntaxTextArea()
textArea.syntaxEditingStyle = SyntaxConstants.SYNTAX_STYLE_JAVA

swing =  new SwingBuilder()
frame = swing.frame(title:"test", defaultCloseOperation:EXIT_ON_CLOSE, size:[600,400], show:true ) {
  borderLayout()
  panel( constraints:BL.CENTER ) {
    borderLayout()
    sp = scrollPane( constraints:BL.CENTER )
    sp.viewport.add textArea
  }
}
于 2011-06-14T07:59:04.243 に答える