0

HCL と Terraform は初めてで、セキュリティ グループとバックエンド アドレス プールをネットワーク インターフェイスに関連付ける際に問題があります。1 つのネットワーク インターフェイス ブロックに 2 つのネットワーク インターフェイスを作成しています。

#Create network interface for 2 VMs
resource "azurerm_network_interface" "FrontNetworkInterface" {
    count = 2
    name = "niFront${count.index}"
    location = azurerm_resource_group.PWSDevResourceGroup.location
    resource_group_name = azurerm_resource_group.PWSDevResourceGroup.name

    ip_configuration {
        name = "ipconfFrontVM"
        subnet_id = azurerm_subnet.PWSDevSubnet.id
        private_ip_address_allocation = "dynamic"
    }
}

さまざまな方法で関連付けを試みましたが、さまざまなエラーが発生しました。

試行 1:

#Connect security group to the network interface
resource "azurerm_network_interface_security_group_association" "PWSDevSecurityGroupAssoc" {
    network_interface_id = azurerm_network_interface.FrontNetworkInterface.id
    network_security_group_id = azurerm_network_security_group.PWSDevSecurityGroup.id
}

#Connect 2 backend ips to the load balancer
resource "azurerm_network_interface_backend_address_pool_association" "BackendIPAssoc" {
    network_interface_id = azurerm_network_interface.FrontNetworkInterface.id
    ip_configuration_name = "bipa"
    backend_address_pool_id = azurerm_lb_backend_address_pool.BackendIpPool.id
}

エラー:

エラー: リソース "azurerm_network_interface_security_group_association" "PWSDevSecurityGroupAssoc" の front.tf 行 85 にリソース インスタンス キーがありません: 85: network_interface_id = azurerm_network_interface.FrontNetworkInterface.id azurerm_network_interface.FrontNetworkInterface には "count" が設定されているため、その属性には特定のインスタンスでアクセスする必要があります。たとえば、参照リソースのインデックスと関連付けるには、azurerm_network_interface.FrontNetworkInterface[count.index] を使用します。

エラー: リソース "azurerm_network_interface_backend_address_pool_association" "BackendIPAssoc" の front.tf 行 91 にリソース インスタンス キーがありません: 91: network_interface_id = azurerm_network_interface.FrontNetworkInterface.id azurerm_network_interface.FrontNetworkInterface には "count" が設定されているため、その属性には特定のインスタンスでアクセスする必要があります。たとえば、参照リソースのインデックスと関連付けるには、azurerm_network_interface.FrontNetworkInterface[count.index] を使用します。

ATTEMPT 2/3/4 (前述の説明に従って、"[count.index]"、"[count.index].id"、または "[element(azurerm_network_interface.FrontNetworkInterface.*.id, count.index)]" を使用)エラー）：

#Connect security group to the network interface
resource "azurerm_network_interface_security_group_association" "PWSDevSecurityGroupAssoc" {
    network_interface_id = azurerm_network_interface.FrontNetworkInterface[count.index]
    network_security_group_id = azurerm_network_security_group.PWSDevSecurityGroup.id
}

#Connect 2 backend ips to the load balancer
resource "azurerm_network_interface_backend_address_pool_association" "BackendIPAssoc" {
    network_interface_id = azurerm_network_interface.FrontNetworkInterface[count.index]
    ip_configuration_name = "bipa"
    backend_address_pool_id = azurerm_lb_backend_address_pool.BackendIpPool.id
}

エラー ([count.index].id と [element(azurerm_network_interface.FrontNetworkInterface.*.id, count.index)] で同じ結果):

エラー: リソース "azurerm_network_interface_security_group_association" "PWSDevSecurityGroupAssoc" の front.tf 行 85 のカウントされないコンテキストでの "count" への参照: 85: network_interface_id = azurerm_network_interface.FrontNetworkInterface[count.index] "count" オブジェクトは、 「モジュール」、「リソース」、および「データ」ブロック、および「カウント」引数が設定されている場合のみ。

エラー: リソース "azurerm_network_interface_backend_address_pool_association" "BackendIPAssoc" の、カウントされないコンテキスト front.tf 行 91 の "count" への参照: network_interface_id = azurerm_network_interface.FrontNetworkInterface[count.index] "count" オブジェクトは "module" でのみ使用できます、「resource」、「data」ブロック、および「count」引数が設定されている場合のみ。

また、azurerm_virtual_machine ブロックで次のエラーが表示されます。

リソース "azurerm_virtual_machine" "FrontEndVirtualMachines" の 162 行目: 162: admin_ssh_key { タイプ "admin_ssh_key" のブロックはここでは想定されていません。

私はここに示されているものに従っています：

https://docs.microsoft.com/en-us/azure/developer/terraform/create-linux-virtual-machine-with-infrastructure

ご覧のとおり、admin_ssh_key ブロックが提供されています。スクリプトで使用されているバージョン 2.0 を使用してみました。しかし、私は同じ結果を経験しました。

ご協力いただきありがとうございます！！:)

4

2 に答える 2

0

count で作成されたリソースを参照するときは、引き続き .id を追加する必要があります。次の例を参照してください。詳細については、このリンクを参照してください。

provider "azurerm" {
  version = "~>2.23.0"
  features {}
}

resource "azurerm_resource_group" "example" {
  name     = "example-resources"
  location = "East US"
}

resource "azurerm_virtual_network" "example" {
  name                = "vnet"
  location            = azurerm_resource_group.example.location
  resource_group_name = azurerm_resource_group.example.name
  address_space       = ["10.0.0.0/16"]
  dns_servers         = ["10.0.0.4", "10.0.0.5"]
}

resource "azurerm_subnet" "example" {
  name                 = "example"
  resource_group_name  = azurerm_resource_group.example.name
  virtual_network_name = azurerm_virtual_network.example.name
  address_prefixes     = ["10.0.1.0/24"]
}

resource "azurerm_network_interface" "example" {
  count               = 2
  name                = format("int%s", count.index)
  location            = azurerm_resource_group.example.location
  resource_group_name = azurerm_resource_group.example.name

  ip_configuration {
    name                          = "ip"
    subnet_id                     = azurerm_subnet.example.id
    private_ip_address_allocation = "dynamic"
  }
}

resource "azurerm_network_security_group" "example" {
  name                = "acceptanceTestSecurityGroup1"
  location            = azurerm_resource_group.example.location
  resource_group_name = azurerm_resource_group.example.name

  security_rule {
    name                       = "test123"
    priority                   = 100
    direction                  = "Inbound"
    access                     = "Allow"
    protocol                   = "Tcp"
    source_port_range          = "*"
    destination_port_range     = "*"
    source_address_prefix      = "*"
    destination_address_prefix = "*"
  }
}

resource "azurerm_network_interface_security_group_association" "secgroup" {
  count                     = length(azurerm_network_interface.example)
  network_interface_id      = azurerm_network_interface.example[count.index].id
  network_security_group_id = azurerm_network_security_group.example.id
}
于 2020-09-17T11:31:50.667 に答える