4

cabbage-goat-wolfパズルの（動作中の！）ソリューションをScalaからHaskellに変換しようとしましたが、ソリューションリストが空であるため、呼び出し時にコードがスローされてエラーが発生するheadためfindSolutions、問題はループのどこかにあるようです。findMovesうまくいくようです。

import Data.Maybe(fromMaybe)

data Item = Farmer | Cabbage | Goat | Wolf deriving (Eq, Show)

type Position = ([Item], [Item]) 

validPos :: Position -> Bool
validPos p = valid (fst p) && valid (snd p) where   
   valid list = elem Farmer list || notElem Goat list || 
                (notElem Cabbage list && notElem Wolf list) 

findMoves :: Position -> [Position]
findMoves (left,right) = filter validPos moves where
    moves | elem Farmer left = map (\item -> (delItem item left, addItem item right)) left 
          | otherwise = map (\item -> (addItem item left, delItem item right)) right
    delItem item = filter (\i ->  notElem i [item, Farmer]) 
    addItem Farmer list = Farmer:list      
    addItem item list = Farmer:item:list      

findSolution :: Position -> Position -> [Position]
findSolution from to = head $ loop [[from]] where
    loop pps = do
          (p:ps) <- pps
          let moves = filter (\x -> notElem x (p:ps)) $ findMoves p
          if elem to moves then return $ reverse (to:p:ps)
                           else loop $ map (:p:ps) moves  

solve :: [Position]
solve = let all = [Farmer, Cabbage, Goat, Wolf]
        in findSolution (all,[]) ([],all)

もちろん、実際のエラーとは関係のない改善に関するヒントもいただければ幸いです。

[アップデート]

念のため、私は。を使用するという提案に従いましたSet。動作するコードは次のとおりです。

import Data.Set

data Item = Farmer | Cabbage | Goat | Wolf deriving (Eq, Ord, Show)

type Position = (Set Item, Set Item)

validPos :: Position -> Bool
validPos p = valid (fst p) && valid (snd p) where
   valid set = or [Farmer `member` set, Goat `notMember` set, 
                   Cabbage `notMember` set && Wolf `notMember` set]

findMoves :: Position -> [Position]
findMoves (left,right) = elems $ Data.Set.filter validPos moves where
    moves | Farmer `member` left = Data.Set.map (move delItem addItem) left
          | otherwise = Data.Set.map (move addItem delItem) right
    move f1 f2 item = (f1 item left, f2 item right)
    delItem item = delete Farmer . delete item 
    addItem item = insert Farmer . insert item 

findSolution :: Position -> Position -> [Position]
findSolution from to = head $ loop [[from]] where
    loop pps = do
          ps <- pps
          let moves = Prelude.filter (\x -> notElem x ps) $ findMoves $ head ps
          if to `elem` moves then return $ reverse $ to:ps
                             else loop $ fmap (:ps) moves

solve :: [Position]
solve = let all = fromList [Farmer, Cabbage, Goat, Wolf]
        in findSolution (all, empty) (empty, all)

headinの呼び出しfindSolutionはより安全になり、ソリューションを印刷するためのより良い方法を使用する必要がありますが、それを除けば、私は非常に満足しています。

【アップデート2】

以前の立場の表現は、この種の問題には最適ではなかったと思います。次のデータモデルに切り替えました。これにより、移動などが少し冗長になりましたが、はるかに読みやすくなりました。

data Place = Here | There deriving (Eq, Show)

data Pos = Pos { cabbage :: Place
               , goat :: Place
               , wolf :: Place
               , farmer :: Place 
               } deriving (Eq, Show)
4

1 に答える 1

4

問題はそれ[Farmer,Goat,Cabbage,Wolf]が同じではなく、使用時に[Farmer,Cabbage,Goat,Wolf]チェックしないことです。1つの解決策は、常に要素のリストを並べ替えることです。たとえば、使用できる関数では次のようになります。elemnotElemfindMoves

import Data.List(ord)
import Control.Arrow((***))

data Item = Farmer | Cabbage | Goat | Wolf deriving (Eq, Show, Ord)

findMoves (left,right) = map (sort***sort) $ filter validPos moves where
-- ....

solve = let all = sort [Farmer, Cabbage, Goat, Wolf]
-- ....

または、アイテムのリストの代わりにアイテムのセットを使用できます。

于 2011-07-05T11:57:43.203 に答える