delphi - ボタンのクリック時にTScrollBoxにコンポーネントを動的に追加する方法は?

Question

TScrollBox を 1 つ作成しました。ボタンのクリック時にラベルと編集ボックスを動的に追加しました。コンポーネントの位置を設定するために、コンポーネントの高さ、幅、左、上プロパティを使用しました。しかし、5 つのコンポーネントを追加した後にスクロール バーが画面に表示されると、次のコンポーネントの場所が乱れます。次のコンポーネントは ScrollBox に同期的に配置されません。

Answer 1

ScrollBox に配置されたコントロールのTop座標は、既に行われた「スクロール」の量を考慮する必要があります。コントロールを一度に追加しても、ScrollBox は「スクロール」する機会がないため、これは問題ではありません。

"スクロール" する機会を得た後でScrollBox にコントロールを追加する場合は、発生した垂直方向の "スクロール" の量を考慮する必要があります。にラベルを追加するサンプル コードを次に示しScrollBox1ます。垂直スクロールを考慮して、コントロールが互いに重ならないようにします。ここでは、フォームの "Tag" プロパティを使用しTopて、追加された次のコントロールを保持しています。またTag、ラベルの一意の名前を生成するためにも使用しています (したがって、それらが正しい座標で ScrollBox に入っていることがわかります)。 .

procedure TForm31.Button1Click(Sender: TObject);
var L: TLabel;
begin
  L := TLabel.Create(Self);
  L.Caption := 'Test: ' + IntToStr(Tag);
  L.Parent := ScrollBox1;
  L.Top := Tag + ScrollBox1.VertScrollBar.Size - ScrollBox1.VertScrollBar.Position;
  Tag := Tag + L.Height;
end;

私が時々使用する別のアプローチは、最後に追加されたコントロールを追跡し、最後に追加されたコントロールの座標に基づいて新しいコントロールの座標を作成することです。

var LastControl: TControl;

procedure TForm31.Button1Click(Sender: TObject);
var L: TLabel;
begin
  L := TLabel.Create(Self);
  L.Caption := 'Test: ' + IntToStr(Tag);
  L.Parent := ScrollBox1;
  if Assigned(LastControl) then
    L.Top := LastControl.Top + LastControl.Height
  else
    L.Top := 0;
  Tag := Tag + L.Height;

  LastControl := L;
end;

さらに別のアプローチは、最も低いコントロールを見つけて、その座標に基づいてコントロールを追加することです。

procedure TForm31.Button1Click(Sender: TObject);
var L: TLabel;
    Bottom, TestBottom: Integer;
    i: Integer;
begin
  // Find "Bottom"
  Bottom := 0;
  for i:=0 to ScrollBox1.ControlCount-1 do
    with ScrollBox1.Controls[i] do
    begin
      TestBottom := Top + Height;
      if TestBottom > Bottom then
        Bottom := TestBottom;
    end;
  L := TLabel.Create(Self);
  L.Caption := 'Test: ' + IntToStr(Tag);
  L.Parent := ScrollBox1;
  L.Top := Bottom;
  Tag := Tag + L.Height;
end;