20

以下の例では、サブタイプごとに1 つのto_str()関数と 1 つのプロシージャを記述しています。関数と手順は、型を除いてほぼ同じです。set()pls_integer

subtype によって提供される制約を放棄することなく、さらに別のサブタイプto_str()や新しいサブタイプを作成する必要をなくすにはどうすればよいでしょうか?set()

varchar2好きに戻る

procedure set(list in varchar2, prefix in varchar2)

そしてそれを次のように呼び出します

set(to_str(list), 'foos:')

あまり素晴らしいアイデアとは思えませんが、それでもto_str()各サブタイプを提供する必要があります。

私はオラクルの初心者であり、新しいオラクルの機能にほぼ毎日驚かされるため、あらゆる種類のさまざまな提案を受け入れます。

私は11.2.0.1.0を実行しています。

create table so1table (
  id number,
  data varchar(20)
);

create or replace package so1 as
  subtype foo_t is pls_integer range 0 .. 4 not null;
  type foolist is table of foo_t;
  procedure set(id_ in number, list in foolist default foolist(1));

  subtype bar_t is pls_integer range 5 .. 10 not null;
  type barlist is table of bar_t;
  procedure set(id_ in number, list in barlist default barlist(5));
end;
/
show errors

create or replace package body so1 as
  /* Do I have always to implement these very similar functions/procedures for
  every single type ? */
  function to_str(list in foolist) return varchar2 as
    str varchar2(32767);
  begin
    for i in list.first .. list.last loop
      str := str || ' ' || list(i);
    end loop;
    return str;
  end;

  function to_str(list in barlist) return varchar2 as
    str varchar2(32767);
  begin
    for i in list.first .. list.last loop
      str := str || ' ' || list(i);
    end loop;
    return str;
  end;

  procedure set(id_ in number, list in foolist default foolist(1)) as
    values_ constant varchar2(32767) := 'foos:' || to_str(list);
  begin
    insert into so1table (id, data) values (id_, values_);
  end;

  procedure set(id_ in number, list in barlist default barlist(5)) as
    values_ constant varchar2(32767) := 'bars:' || to_str(list);
  begin
    insert into so1table (id, data) values (id_, values_);
  end;
end;
/
show errors

begin
  so1.set(1, so1.foolist(0, 3));
  so1.set(2, so1.barlist(5, 7, 10));
end;
/

SQLPLUS> select * from so1table;

        ID DATA
---------- --------------------
         1 foos: 0 3
         2 bars: 5 7 10
4

3 に答える 3

3 
create table so1table (
    id number,
    data varchar(20)
);


create or replace type parent_type as object
(
    v_number number,
    --Prefix probably belongs with a list, not an individual value.
    --For simplicity, I'm not adding another level to the objects.
    v_prefix varchar2(10)
) not instantiable not final;
/

create or replace type parentlist as table of parent_type;
/


create or replace type foo_type under parent_type
(
    constructor function foo_type(v_number number) return self as result
);
/

--The data must be stored as a NUMBER, since ADTs don't support
--PL/SQL specific data types.  The type safety is enforced by the
--conversion in the constructor.
create or replace type body foo_type is
    constructor function foo_type(v_number number) return self as result
    as
        subtype foo_subtype is pls_integer range 0 .. 4 not null;
        new_number foo_subtype := v_number;
    begin
        self.v_number := new_number;
        self.v_prefix := 'foos:';
        return;
    end;
end;
/

create or replace type foolist as table of foo_type;
/


create or replace type bar_type under parent_type
(
    constructor function bar_type(v_number number) return self as result
);
/

create or replace type body bar_type is
    constructor function bar_type(v_number number) return self as result
    as
        subtype bar_subtype is pls_integer range 5 .. 10 not null;
        new_number bar_subtype := v_number;
    begin
        self.v_number := new_number;
        self.v_prefix := 'bars:';
        return;
    end;
end;
/

create or replace type barlist as table of bar_type;
/



create or replace package so1 as
    procedure set(id_ in number, list in parentlist);
end;
/

create or replace package body so1 as

    function to_str(list in parentlist) return varchar2 as
        v_value VARCHAR2(32767);
    begin
        for i in list.first .. list.last loop
            if i = 1 then
                v_value := list(i).v_prefix;
            end if;
            v_value := v_value || ' ' || list(i).v_number;
        end loop;

        return v_value;
    end to_str;

    procedure set(id_ in number, list in parentlist) as
        values_ constant varchar2(32767) := to_str(list);
    begin
        insert into so1table (id, data) values (id_, values_);
    end set;
end so1;
/


begin
    --You probably don't want to mix foos and bars, but it is allowed. 
    so1.set(1, parentlist(foo_type(0), foo_type(3)));
    so1.set(2, parentlist(bar_type(5), bar_type(7), bar_type(10)));

    --These would generate "ORA-06502: PL/SQL: numeric or value error"
    --so1.set(1, parentlist(foo_type(5)));
    --so1.set(1, parentlist(bar_type(4)));

end;
/

select * from so1table;
于 2011-08-27T22:19:19.437 に答える
1

これはあなたの質問に答えないかもしれませんが、通常のテーブルにデータを入れてから、wm_concat集計関数を使用してそれらを連結してみませんか?

つまり、

> select * from myTable;

ID  Category  Value
--- --------- ------
1   foo       0
2   foo       3
3   bar       5
4   bar       7
5   bar       10

> select   Category||'s: '||replace(wm_concat(Value),',',' ') Data
  from     myTable
  group by Category;

Data
-------------
bars: 5 7 10
foos: 0 3

wm_concat型に依存しないため、関数をオーバーロードする必要はありません。さらに、使用できる方法は他にもあります。分析関数メソッドは良さそうですが、テストする 11g がありません!

（編集それ以外の場合は、 Oracleのオブジェクトモデル、特にポリモーフィズムを使用して、探しているものを達成できると思います。ただし、これは私を超えています...だから、他の誰かがチャイムを鳴らすことができます。）

于 2011-08-17T08:45:48.657 に答える
-1

次の回答は、実際にpostgresql（およびplpgsql）でどのように行うかについてのものであり、オラクルのサブタイプについても知りませんが、少なくともそれがあなたの答えにつながるほど十分に似ていると思います.

create function add (anynonarray,anynonarray) returning anynonarray
as 'begin return $1 + $2; end';

構文を間違えたことは知っていますが、とにかく、それで表示したいものを表示する必要があります。

アイデアは、「anynonarray」または代替のいずれかを呼び出しのパラメーターの型に置き換えるというものです。1 つの制限は、上記の例のすべての「anynonarray」が同じ型になることです。

ドキュメントでは、これをポリモーフィズムと呼んでいました。

于 2011-08-18T17:23:14.087 に答える