8

私は現在、ルートをリンクしてバーミンガム地域の基本的なGPSを作成する再帰的なPrologプログラムに取り組んでいます。現時点では、次のように出力を取得できます。

入力

routeplan(selly_oak, aston, P).

出力

P = [selly_oak, edgbaston, ... , aston]

私がやりたいのは、プログラムにある種のインターフェースを提供させることです。そのため、次のように入力するとします。

Route from selly_oak to aston

それは私に以下を提供します：

Go from selly_oak to edgbaston
Go from edgbaston to ...
Finally, Go from ... to aston.

Prologは強力な言語なので、これは簡単に可能だと思いますが、私が取り出した本の多くはこの部分をスキップしているようです。詳細はわかりませんが、私が知る限り、write（）とread（）の行に沿って何かを使用する必要があります。

ここにいる誰かが、いくつかの基本的な例や詳細情報へのリンクを持ったProlog初心者を出してくれませんか？

編集：これらの答えの多くは非常に複雑に見えます。解決策は約5〜10行のコードである必要があります。次の行に沿って何かを行うことができるので、値の読み取りは問題ではありません。

find:- 
    write('Where are you? '), 
    read(X), 
    nl, write('Where do you want to go? '),
    read(Y), 
    loopForRoute(X,Y).

write（）を使用して出力を書き出すことができれば、新しい行（nl）を使用して、上記の出力のように表示できるようにしたいと思います。

これが私の入力である場合、これらの入力で機能するように最上位のrouteplan（）をどのように調整しますか？また、これらのステーションのラインを追加のパラメータとして追加した場合、これはどのように実装されますか？すべてのリンクは、次のようにファイルの先頭で定義されます。

rlinks(selly_oak, edgbaston, uob_line).
rlinks(edgbaston, bham_new_street, main_line).

したがって、この情報があれば、そのように行を読み取ることができればよいでしょう。

Go from selly_oak to edgbaston using the uob_line
Go from edgbaston to ... using the ...
Finally, go from ... to aston using the astuni_line
4

4 に答える 4

5

そのようなことを詳細に論じている本は 、Michael A. Covington によるProlog Programmers のための自然言語処理です。

一般的に、あなたがする必要があるのは

  1. 入力をトークン化する
  2. トークンを (たとえば DCG で) 解析して、入力を取得します。routeplan/3
  3. 電話routeplan/3
  4. の出力に基づいて英語を生成します。routeplan/3

このようなもの (SWI-Prolog で動作):

% Usage example:
%
% ?- query_to_response('Route from selly_oak to aston', Response).
%
% Response = 'go from selly_oak to edgbaston then go from edgbaston
%         to aston then stop .'
%
query_to_response(Query, Response) :-
    concat_atom(QueryTokens, ' ', Query), % simple tokenizer
    query(path(From, To), QueryTokens, []),
    routeplan(From, To, Plan),
    response(Plan, EnglishTokens, []),
    concat_atom(EnglishTokens, ' ', Response).

% Query parser
query(path(From, To)) --> ['Route'], from(From), to(To).
from(From) --> [from], [From], { placename(From) }.
to(To) --> [to], [To], { placename(To) }.

% Response generator
response([_]) --> [stop], [.].
response([From, To | Tail]) -->
    goto(path(From, To)), [then], response([To | Tail]).
goto(path(From, To)) --> [go], from(From), to(To).

% Placenames
placename(selly_oak).
placename(aston).
placename(edgbaston).

% Mock routeplan/3
routeplan(selly_oak, aston, [selly_oak, edgbaston, aston]).
于 2009-03-24T11:45:15.427 に答える
4

うーん、私の理解が正しければ、印刷用にリストを適切にフォーマットしたいだけですよね?

SWI-Prolog では、次のように動作します。

output_string([A,B],StrIn,StrOut) :-
 concat_atom([StrIn, 'Finally, Go from ', A, ' to ', B, '.'],StrOut),
 write(StrOut).

output_string([A,B|Rest],StrIn,StrOut) :-
 concat_atom([StrIn,'Go from ', A, ' to ', B, '.\n'],StrAB),
 output_string([B|Rest],StrAB,StrOut).

次に、で呼び出します

output_string(P,'',_).

おそらくあまり効率的ではありませんが、仕事はします。:)

于 2009-03-24T10:47:46.207 に答える
2

このようなことのために、私は通常、シェル述語を作成します。だからあなたの場合...

guided:-
    print('Enter your start point'),nl,
    read(Start),
    print('Enter your destination'),nl,
    read(Dest),
    routeplan(Start, Dest, Route),
    print_route(Route).

また、print_route/1 は次のような再帰的なものになる可能性があります。

print_route([]).

print_route([[A,B,Method]|Tail]):-
    print_route(Tail),
    print('Go from '), print(A),
    print(' to '), print(B),
    print(' by '), print(Method), nl.

routeplan/3 述語の 3 番目の変数はリストのリストであると仮定しました。また、テールに追加して構築されていることも。そうでない場合は、かなり簡単に適応できるはずです。コメントで質問してください。

于 2009-04-02T18:14:07.943 に答える
0

ファイル/ストリームから Prolog 文字列に行を読み取るためのいくつかの述語を次に示します。

%%% get_line(S, CL): CL is the string read up to the end of the line from S.
%%% If reading past end of file, returns 'end_of_file' in CL first, raises
%%% an exception second time.
%%% :- pred get_string(+stream, -list(int)).
get_line(S, CL) :-
    peek_code(S, C),
    (   C = -1
    ->  get_code(S, _),
        CL = end_of_file
    ;   get_line(S, C, CL)).

get_line(_, -1, CL) :- !, CL = [].  % leave end of file mark on stream
get_line(S, 0'\n, CL) :- !,
    get_code(S, _),
    CL = [].
get_line(S, C, [C|CL]) :-
    get_code(S, _),
    peek_code(S, NC),
    get_line(S, NC, CL).

%% read_lines(L): reads lines from current input to L.  L is a list of list
%% of character codes, newline characters are not included.
%% :- pred read_lines(-list(list(char))).
read_lines(L) :-
    current_input(In),
    get_line(In, L0),
    read_lines(In, L0, L).

%% read_lines(F, L): reads lines from F to L.  L is a list of list of character
%% codes, newline characters are not included.
%% :- pred read_lines(+atom, -list(list(char))).
read_lines(F, L) :-
    fail_on_error(open(F, read, S)),
    call_cleanup((get_line(S, L0),
              read_lines(S, L0, L)),
             close(S)).

read_lines(_, end_of_file, L) :- !, L = [].
read_lines(S, H, [H|T]) :-
    get_line(S, NH),
    read_lines(S, NH, T).

次に、文字列を解析する方法についてDCGを参照してください。

于 2009-03-24T10:28:11.587 に答える