3

選択した日の iso_week を返す datepart iso_week があります。

SELECT DATEPART(iso_week, getdate())

これは、現在の週のヨーロッパ標準を返します。必ずしも週と同じではありません。

ここにトリッキーな部分があります：

SELECT DATEPART(iso_week, '2011-01-01')

戻り値

52

年と iso_week でグループ化するには、iso_week が同じ年のものではないことを考慮する必要があります。

Iso_week は月曜日から始まり、ほとんどの日が重なる年に属します。したがって、2010 年の 4 日と 2011 年の 3 日は、週が 52 で、すべての日が 2010 年の iso_year に属します。ただし、TSQL には detepart iso_year がありません。

declare @t table(col1 datetime)

insert @t 
ALL SELECT '2010-12-28'
UNION ALL SELECT '2010-12-29'
UNION ALL SELECT '2010-12-30'
UNION ALL SELECT '2010-12-31'
UNION ALL SELECT '2011-01-01'
UNION ALL SELECT '2011-01-02'
--UNION ALL SELECT '2011-01-03' Stackexchange is bugged and can't handle this line showing 53
UNION ALL SELECT '2011-01-04'

次のようなものが必要です (iso_year は存在しません):

SELECT DATEPART(ISO_WEEK, col1) WEEK, DATEPART(iso_YEAR, col1) YEAR, COUNT(*) COUNT 
FROM @t
GROUP BY DATEPART(ISO_WEEK, col1), DATEPART(iso_YEAR, col1)
ORDER BY  2,1

期待される結果

WEEK  YEAR          COUNT
52    2010           6
1     2011           2
4

4 に答える 4

3

同じ ISO 週の木曜日は、明確に正しい年を提供します。そして、この答えは、指定された日付から適切な木曜日を取得する方法のアイデアを提供できます。

SELECT
  Week  = DATEPART(ISOWK, TheThursday),
  Year  = DATEPART(YEAR, TheThursday),
  Count = COUNT(*)
FROM (
  SELECT
    TheThursday = DATEADD(
      DAY,
      3 - (DATEPART(DW, col1) + @@DATEFIRST - 2) % 7,
      col1
    )
  FROM @t
) s
GROUP BY
  TheThursday
于 2011-07-20T23:41:36.357 に答える
1

年を 1 で減算する必要があるかどうかを確認して把握することができdayofyearます。iso_week

select datepart(iso_week, col1) as [week], 
       case when datepart(dayofyear, col1) < 7 and
                 datepart(iso_week, col1) > 51
            then year(col1) - 1
            else year(col1)
       end as [year], 
       count(*) as [count]
from @t
group by datepart(iso_week, col1),
         case when datepart(dayofyear, col1) < 7 and
                   datepart(iso_week, col1) > 51
              then year(col1) - 1
              else year(col1)
         end
order by [year], [week]
于 2011-07-20T19:55:37.100 に答える
1

このソリューションは、週が前年から始まる年も処理します。

SELECT DATEPART(ISO_WEEK, col1) WEEK, 
DATEPART(year , col1 - CAST(col1-.5 as int)%7 + 3) YEAR, 
COUNT(*) COUNT 
FROM @t
GROUP BY DATEPART(ISO_WEEK, col1), 
DATEPART(year , col1 - CAST(col1-.5 as int)%7 + 3)
ORDER BY 2,1
于 2011-07-20T21:35:19.710 に答える
1

編集済み...

SELECT 
  IsoWeek  = DATEPART(ISO_WEEK, TheDate), 
  IsoYear  = CASE 
    WHEN 
      MONTH(TheDate) = 1 AND DATEPART(ISO_WEEK, TheDate) > 51 
      THEN YEAR(TheDate) - 1 
      ELSE YEAR(TheDate) 
    END, 
  DayCount = COUNT(*)
FROM 
  @t
GROUP BY 
  DATEPART(ISO_WEEK, TheDate), 
  CASE 
    WHEN MONTH(TheDate) = 1 AND DATEPART(ISO_WEEK, TheDate) > 51 
    THEN YEAR(TheDate) - 1 
    ELSE YEAR(TheDate) 
  END 
ORDER BY  
  IsoYear,
  IsoWeek

--IsoWeek  IsoYear  DayCount
--     52     2010         6
--      1     2011         2
于 2011-07-20T21:12:01.577 に答える