5

ここで MD5 の Javascript 実装をテストします。http://www.webtoolkit.info/javascript-md5.htmlは、次の出力を提供します。

MD5("ムザヤ") = "00e081abefbbbf72b2d5258196a9b6d0"

私のアーラン シェルに行き、同じ値の MD5 を計算すると、次のようになります。

Eshell V5.8.4 (^G で中止)
1> erlang:md5("ムザアヤ").
<<0,224,129,171,239,187,191,114,178,213,37,129,150,169,
  182,208>>
2>

2つを比較するにはどうすればよいですか？JavaScript フロントエンド アプリからの MD5 の結果が Erlang バックエンドに届いた場合、2 つのダイジェストを比較できるようにしたいと考えています。JavaScript MD5 ダイジェストを Erlang のダイジェストと一致させるにはどうすればよいですか?

4

5 に答える 5

17

MD5 ハッシュは、本質的に 128 ビットの数値です。

Erlang では MD5 値を 16 バイト (16 * 8 = 128 ビット) のバイナリとして受け取ります。そのバイナリの各バイトは、JavaScript の MD5 出力 (1 バイトあたり 2 文字の 16 進文字列) と比較できるように、16 進表現に変換する必要があります。

2> lists:flatten([io_lib:format("~2.16.0b", [B]) || <<B>> <= MD5]).
"00e081abefbbbf72b2d5258196a9b6d0"

まず、バイナリから各バイトを取得し、io_libモジュールを使用してそれを 16 進文字列にフォーマットします。次に flatten 関数を使用して、読み取り可能な文字列として表示します (ただし、値をファイルまたはソケットに書き込む場合は、深い io リスト、ネストされた文字のリスト、またはバイナリ)。

使用されるフォーマット文字列は、基数を使用し~2.16.0bて整数 ( b) をフォーマットし、パディング文字を使用16して幅にパディングすることを意味します (完全なガイドについては、を参照してください)。20io:format/3

バイナリが必要な場合は、代わりに次のバイナリ内包表記を使用できます。

3> << << (list_to_binary(io_lib:format("~2.16.0b", [C])))/binary >>
     || <<C>> <= MD5 >>.
<<"00e081abefbbbf72b2d5258196a9b6d0">>

（代わりにio_lib:format/2もありますがhttp_util:integer_to_hexlist/1、速いかどうかはわかりません）

于 2011-07-25T15:39:12.233 に答える
4

さらに別のより高速なバージョン:

hstr(B) when is_binary(B) ->
  << <<(hex(A)), (hex(B))>> || <<A:4,B:4>> <= B >>.

-compile({inline, [hex/1]}).

hex(0)  -> $0;
hex(1)  -> $1;
hex(2)  -> $2;
hex(3)  -> $3;
hex(4)  -> $4;
hex(5)  -> $5;
hex(6)  -> $6;
hex(7)  -> $7;
hex(8)  -> $8;
hex(9)  -> $9;
hex(10) -> $a;
hex(11) -> $b;
hex(12) -> $c;
hex(13) -> $d;
hex(14) -> $e;
hex(15) -> $f.

しかし、最速のバージョンは

md5_hex(L) ->
  << A1:4, A2:4,  A3:4,  A4:4,  A5:4,  A6:4,  A7:4,  A8:4,
    A9:4,  A10:4, A11:4, A12:4, A13:4, A14:4, A15:4, A16:4,
    A17:4, A18:4, A19:4, A20:4, A21:4, A22:4, A23:4, A24:4,
    A25:4, A26:4, A27:4, A28:4, A29:4, A30:4, A31:4, A32:4
    >> = erlang:md5(L),
  << (hex(A1)), (hex(A2)),  (hex(A3)),  (hex(A4)),
    (hex(A5)),  (hex(A6)),  (hex(A7)),  (hex(A8)),
    (hex(A9)),  (hex(A10)), (hex(A11)), (hex(A12)),
    (hex(A13)), (hex(A14)), (hex(A15)), (hex(A16)),
    (hex(A17)), (hex(A18)), (hex(A19)), (hex(A20)),
    (hex(A21)), (hex(A22)), (hex(A23)), (hex(A24)),
    (hex(A25)), (hex(A26)), (hex(A27)), (hex(A28)),
    (hex(A29)), (hex(A30)), (hex(A31)), (hex(A32)) >>.

ただし、この最適化を行う必要はありません。

編集:のこのバージョンhex/1はさらに高速です:

hex(X) ->
  element(X+1, {$0, $1, $2, $3, $4, $5, $6, $7, $8, $9, $a, $b, $c, $d, $e, $f}).

EDIT2:さらに別のアプローチ:

md5_hex(L) ->
    <<X:128>> = erlang:md5(L),
    B = integer_to_binary(X,16),
    list_to_binary([lists:duplicate(32-byte_size(B),$0)|B]).
于 2011-09-07T13:22:54.017 に答える
3

ワンライナーが必要な場合は、次のようになります。

1> B = erlang:md5("muzaaya").
<<0,224,129,171,239,187,191,114,178,213,37,129,150,169,
  182,208>>
2> lists:flatten([io_lib:format("~2.16.0b", [C]) || <<C>> <= B]).
"00e081abefbbbf72b2d5258196a9b6d0"
于 2011-07-25T15:37:53.440 に答える
3

これはおそらく最速で最もメモリ効率の良いビット文字列内包バージョンです:

hstr(B) when is_binary(B) ->
    T = {$0,$1,$2,$3,$4,$5,$6,$7,$8,$9,$a,$b,$c,$d,$e,$f},
    << <<(element(X bsr 4 + 1, T)), (element(X band 16#0F + 1, T))>>
    || <<X:8>> <= B >>.

3> M:hstr(erlang:md5("muzaaya"))。

4> <<"00e081abefbbbf72b2d5258196a9b6d0">>

于 2011-07-25T18:05:24.990 に答える
2

JavaScript側で実行したい場合は、これを使用できます

function md5HexToArray ( hexStr ) {  
  var i, arr = [], arraylength = hexStr.length/2;

  for( i = 0; i < arraylength ; i++ ) {
     arr[i] = parseInt( hexStr.substr(i*2,2), 16) ;
  }

  return arr;
};

しかし、@Wrikkenのコメントはうまくいくはずです。

于 2011-07-25T15:37:55.690 に答える