25

sshを介していくつかのルーターに接続するexpectスクリプトがあります。これらのルーターはすべて同じパスワードを持っており（私は知っていますが、それは間違っています）、ルーターに接続できるようにするには、スクリプトがそのパスワードを知っている必要があります。現在、パスワードはコマンドラインの引数としてスクリプトに渡されますが、これは、実行中のプロセスだけでなく、.bash_historyファイルにもそのパスワードの痕跡があることを意味します。その代わりに、可能であればサイレントに、ユーザーにパスワードの入力を求めてもらいたいと思います。

ユーザーにexpectでパスワードの入力を求めることができるかどうか知っていますか？

ありがとうございました。

編集：ルーターの代わりにサーバーに接続している場合は、パスワードの代わりにsshキーを使用する可能性があります。しかし、私が使用しているルーターはパスワードをサポートしているだけです。

4

3 に答える 3

45

次のようにexpectのsttyコマンドを使用します。

# grab the password
stty -echo
send_user -- "Password for $user@$host: "
expect_user -re "(.*)\n"
send_user "\n"
stty echo
set pass $expect_out(1,string)

#... later
send -- "$pass\r"

stty -echo 呼び出す前に呼び出すことが重要であることに注意してくださいsend_user。正確な理由はわかりません。タイミングの問題だと思います。

プログラマーを期待するすべての本を読む必要があります: Don Libes によるExploring Expect

于 2009-03-25T20:50:14.750 に答える
8

OK、上（または下または現在の場所）の2つの回答をマージします。

#!/usr/bin/expect
log_user 0
set timeout 10
set userid  "XXXXX"
set pass    "XXXXXX"

### Get two arguments - (1) Host (2) Command to be executed
set host    [lindex $argv 0] 
set command [lindex $argv 1]

# grab the password
stty -echo
send_user -- "Password for $userid@$host: "
expect_user -re "(.*)\n"
send_user "\n"
stty echo
set pass $expect_out(1,string)

spawn /usr/bin/ssh -l $userid $host
match_max [expr 32 * 1024]

expect {
    -re "RSA key fingerprint" {send "yes\r"}
    timeout {puts "Host is known"}
}

expect {
     -re "username: " {send "$userid\r"} 
     -re "(P|p)assword: " {send "$pass\r"}
     -re "Warning:" {send "$pass\r"}
     -re "Connection refused" {puts "Host error -> $expect_out(buffer)";exit}
     -re "Connection closed"  {puts "Host error -> $expect_out(buffer)";exit}
     -re "no address.*" {puts "Host error -> $expect_out(buffer)";exit}

     timeout {puts "Timeout error. Is host down or unreachable?? ssh_expect";exit}
}

expect {
   -re "\[#>]$" {send "term len 0\r"}
   timeout {puts "Error reading prompt -> $expect_out(buffer)";exit}
}


expect {
   -re "\[#>]$" {send "$command\r"}

   timeout {puts "Error reading prompt -> $expect_out(buffer)";exit}
}

expect -re "\[#>]$"
set output $expect_out(buffer)
send "exit\r"
puts "$output\r\n"

他の答えと一致するように、$password変数を$passに変更したことに注意してください。

于 2011-01-24T19:19:11.573 に答える
0

または、SSH_ASKPASS 環境変数を使用して、X11 経由で ssh にパスワードを収集させることもできます。

マニュアルページから：

> SSH_ASKPASS
>     If ssh needs a passphrase, it will read the passphrase from the
>     current terminal if it was run from a terminal.  If ssh does not
>     have a terminal associated with it but DISPLAY and SSH_ASKPASS
>     are set, it will execute the program specified by SSH_ASKPASS
>     and open an X11 window to read the passphrase.  This is particularly
>     useful when calling ssh from a .xsession or related script.
>     (Note that on some machines it may be necessary to redirect the
>     input from /dev/null to make this work.)
于 2011-02-11T18:45:43.710 に答える