1

管理者特権レベルが必要な場合は、フォルダーを検出したい (を使用Delphi)。出来ますか？

私はこのコードを書きました。これはまさに私が欲しいものです。しかし、Windows標準機能を使用してこれを行いたいです。

// Check if You need Administrator-level access to create a folder
try
  mkdir(SDirectory + '\~TEST');
except
  on E: exception do
  begin
    if E.message = 'File access denied' then
    begin
      MessageBox(self.Handle,
        'You need Administrator-level access to create this folder', '', MB_ICONERROR);
      exit;
    end;
  end;
end;
RmDir(SDirectory + '\~TEST');
4

2 に答える 2

7

次の例は、この記事から翻訳されたものです。ファイルまたはディレクトリがすべてのユーザーに対してその記事で通知されているアクセス権を持っているかどうかを判断するために使用できるため、FILE_ALL_ACCESS を要求すると、すべてのユーザーが目的のファイルまたはディレクトリに完全にアクセスできることを意味します。次のコードには例外処理がなく、前回いつ VB を使用したか覚えていないため、間違っている可能性があることに注意してください。これを参考にして、この投稿を自由に変更してください。

const
  FILE_READ_DATA = $0001;
  FILE_WRITE_DATA = $0002;
  FILE_APPEND_DATA = $0004;
  FILE_READ_EA = $0008;
  FILE_WRITE_EA = $0010;
  FILE_EXECUTE = $0020;
  FILE_READ_ATTRIBUTES = $0080;
  FILE_WRITE_ATTRIBUTES = $0100;
  FILE_GENERIC_READ = (STANDARD_RIGHTS_READ or FILE_READ_DATA or
    FILE_READ_ATTRIBUTES or FILE_READ_EA or SYNCHRONIZE);
  FILE_GENERIC_WRITE = (STANDARD_RIGHTS_WRITE or FILE_WRITE_DATA or
    FILE_WRITE_ATTRIBUTES or FILE_WRITE_EA or FILE_APPEND_DATA or SYNCHRONIZE);
  FILE_GENERIC_EXECUTE = (STANDARD_RIGHTS_EXECUTE or FILE_READ_ATTRIBUTES or
    FILE_EXECUTE or SYNCHRONIZE);
  FILE_ALL_ACCESS = STANDARD_RIGHTS_REQUIRED or SYNCHRONIZE or $1FF;

function CheckFileAccess(const FileName: string; const CheckedAccess: Cardinal): Cardinal;
var Token: Cardinal;
    Status: LongBool;
    Access: Cardinal;
    SecDescSize: Cardinal;
    PrivSetSize: Cardinal;
    PrivSet: PRIVILEGE_SET;
    Mapping: GENERIC_MAPPING;
    SecDesc: PSECURITY_DESCRIPTOR;
begin
  Result := 0;
  GetFileSecurity(PChar(Filename), OWNER_SECURITY_INFORMATION or GROUP_SECURITY_INFORMATION or DACL_SECURITY_INFORMATION, nil, 0, SecDescSize);
  SecDesc := GetMemory(SecDescSize);

  if GetFileSecurity(PChar(Filename), OWNER_SECURITY_INFORMATION or GROUP_SECURITY_INFORMATION or DACL_SECURITY_INFORMATION, SecDesc, SecDescSize, SecDescSize) then
  begin
    ImpersonateSelf(SecurityImpersonation);
    OpenThreadToken(GetCurrentThread, TOKEN_QUERY, False, Token);
    if Token <> 0 then
    begin
      Mapping.GenericRead := FILE_GENERIC_READ;
      Mapping.GenericWrite := FILE_GENERIC_WRITE;
      Mapping.GenericExecute := FILE_GENERIC_EXECUTE;
      Mapping.GenericAll := FILE_ALL_ACCESS;

      MapGenericMask(Access, Mapping);
      PrivSetSize := SizeOf(PrivSet);
      AccessCheck(SecDesc, Token, CheckedAccess, Mapping, PrivSet, PrivSetSize, Access, Status);
      CloseHandle(Token);
      if Status then
        Result := Access;
    end;
  end;

  FreeMem(SecDesc, SecDescSize);
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  if CheckFileAccess('C:\Windows', FILE_ALL_ACCESS) = FILE_ALL_ACCESS then
    ShowMessage('C:\Windows has full access for everyone')
  else
    ShowMessage('Someone has no full access to C:\Windows');
end;

ここに画像の説明を入力
64 ビット Windows 7 Enterprise SP 1 上の Delphi 2007 で

とにかく、 JEDI Windows Security Code Libraryをダウンロードして、このような例に従う方がはるかに簡単です（ディレクトリでも機能することを願っていますが、うまくいくと確信しています）。

于 2011-08-02T10:52:38.660 に答える
3

Delphi XE2 以降に移行した場合は、上記の例を少し変更します (Token は Cardinal では機能しなくなり、THandle にする必要があります)。

function getFileAccess(...):Cardinal;
var
    Token: THandle;//No longer Cardinal
begin
    { ... code ...}
    if GetFileSecurity({...params...}) then
    begin
        //... more stuff
        OpenThreadToken(GetCurrentThread,TOKEN_QUERY,false,Token);
        if Token<>0 then
        begin
            //... more stuff
            AccessCheck(SecDesc,Token,CheckedAccess,Mapping,PrivSet,PrivSetSize,Access,Status);
            CloseHandle(Token);
            //... more stuff
        end;
    end;
    //....more stuff
end;
于 2013-06-05T19:09:33.923 に答える