20

私は、多くの RichTextBox コントロールを使用する WinForms SmartClient アプリケーションに取り組んでいます。いくつかのコントロールは、さまざまな理由で通常の TextBox の代わりに使用されます。残念ながら、RichTextBox は、XP または Vista スタイルのテーマの境界線ではなく、醜い Win95 3D 境界線を描画します。

テーマの境界線を RichTextBox に適用する方法を知っている人はいますか? この目的のためにそれらをサブクラス化してもかまいません。

ありがとう！

4

5 に答える 5

39

これは実際にはハックですが、できることの 1 つは、Panel コントロールをページにドロップすることです。FixedSingle の BorderStyle を指定します (デフォルトでは None になります)。

RichTextBox をパネルにドロップし、BorderStyle を none に設定します。次に、RichTextBox の Dock プロパティを Fill に設定します。

これにより、平らな境界線を持つ RichTextBox が得られます。

于 2009-09-23T19:27:03.850 に答える
2

当時、私はテキストボックスが内部のコンポーネントであり、DockPaddingが3または4ピクセルに設定されているパネルでこれを解決する必要がありました。次に、そのパネルを1つのピクセルにスタイル設定します。

私はいつもこれが本当に迷惑だと思っていました！

于 2009-03-31T08:03:16.763 に答える
1

これは VB.NET コードです。非クライアント領域を -1 で膨らませてから、非クライアント領域をケード ブルーで塗りつぶします。SharpDevelop 4.4 を使用して C# に変換できます。この記事からコードを導き出しました：

http://www.codeproject.com/Articles/13723/Themed-RichTextBox-A-RichTextBox-with-XP-styled-bo

Imports System.Runtime.InteropServices
Imports System.Windows.Forms
Imports System.Windows.Forms.VisualStyles
Imports System.Drawing
Imports System.Diagnostics

Public Class FlatRichTextBox
    Inherits RichTextBox

    Private BorderRect As RECT

    Sub New()
        If VisualStyleInformation.IsEnabledByUser Then
            BorderStyle = BorderStyle.None
        End If
    End Sub

    Protected Overrides Sub WndProc(ByRef m As Message)
        Const WM_NCPAINT = &H85
        Const WM_NCCALCSIZE = &H83
        Const WM_THEMECHANGED = &H31A

        Select Case m.Msg
            Case WM_NCPAINT
                WmNcpaint(m)
            Case WM_NCCALCSIZE
                WmNccalcsize(m)
            Case WM_THEMECHANGED
                UpdateStyles()
            Case Else
                MyBase.WndProc(m)
        End Select
    End Sub

    Private Sub WmNccalcsize(ByRef m As Message)
        MyBase.WndProc(m)

        If Not VisualStyleInformation.IsEnabledByUser Then Return

        Dim par As New NCCALCSIZE_PARAMS()
        Dim windowRect As RECT

        If m.WParam <> IntPtr.Zero Then
            par = CType(Marshal.PtrToStructure(m.LParam, GetType(NCCALCSIZE_PARAMS)), NCCALCSIZE_PARAMS)
            windowRect = par.rgrc0
        End If

        Dim clientRect = windowRect

        clientRect.Left += 1
        clientRect.Top += 1
        clientRect.Right -= 1
        clientRect.Bottom -= 1

        BorderRect = New RECT(clientRect.Left - windowRect.Left,
                              clientRect.Top - windowRect.Top,
                              windowRect.Right - clientRect.Right,
                              windowRect.Bottom - clientRect.Bottom)

        If m.WParam = IntPtr.Zero Then
            Marshal.StructureToPtr(clientRect, m.LParam, False)
        Else
            par.rgrc0 = clientRect
            Marshal.StructureToPtr(par, m.LParam, False)
        End If

        Const WVR_HREDRAW = &H100
        Const WVR_VREDRAW = &H200
        Const WVR_REDRAW = (WVR_HREDRAW Or WVR_VREDRAW)

        m.Result = New IntPtr(WVR_REDRAW)
    End Sub

    Private Sub WmNcpaint(ByRef m As Message)
        MyBase.WndProc(m)

        If Not VisualStyleInformation.IsEnabledByUser Then Return

        Dim r As RECT
        GetWindowRect(Handle, r)

        r.Right -= r.Left
        r.Bottom -= r.Top
        r.Top = 0
        r.Left = 0

        r.Left += BorderRect.Left
        r.Top += BorderRect.Top
        r.Right -= BorderRect.Right
        r.Bottom -= BorderRect.Bottom

        Dim hDC = GetWindowDC(Handle)
        ExcludeClipRect(hDC, r.Left, r.Top, r.Right, r.Bottom)

        Using g = Graphics.FromHdc(hDC)
            g.Clear(Color.CadetBlue)
        End Using

        ReleaseDC(Handle, hDC)
        m.Result = IntPtr.Zero
    End Sub

    <DllImport("user32.dll")>
    Public Shared Function GetWindowRect(hWnd As IntPtr, ByRef lpRect As RECT) As Boolean
    End Function

    <DllImport("user32.dll")>
    Public Shared Function GetWindowDC(hWnd As IntPtr) As IntPtr
    End Function

    <DllImport("user32.dll")>
    Public Shared Function ReleaseDC(hWnd As IntPtr, hDC As IntPtr) As Integer
    End Function

    <DllImport("gdi32.dll")>
    Public Shared Function ExcludeClipRect(hdc As IntPtr, nLeftRect As Integer, nTopRect As Integer, nRightRect As Integer, nBottomRect As Integer) As Integer
    End Function

    <StructLayout(LayoutKind.Sequential)>
    Public Structure NCCALCSIZE_PARAMS
        Public rgrc0, rgrc1, rgrc2 As RECT
        Public lppos As IntPtr
    End Structure

    <StructLayout(LayoutKind.Sequential)>
    Public Structure RECT
        Public Left As Integer
        Public Top As Integer
        Public Right As Integer
        Public Bottom As Integer

        Public Sub New(left As Integer, top As Integer, right As Integer, bottom As Integer)
            Me.Left = left
            Me.Top = top
            Me.Right = right
            Me.Bottom = bottom
        End Sub
    End Structure
End Class
于 2015-02-03T23:15:26.470 に答える
0

これは少し遅すぎると思いますが、それでもなお。

いつでも P/Invoke を使用して、RichEdit を UXTheme API でサブクラス化し、必要に応じて無効/有効にすることができます。

CodeProject には UXTheme/Visual Styles API を使用するリッチエディット コントロールがあったと思います

Windows 8 の展開に伴い、Visual Styles UXTheme API が廃止または非推奨になる可能性があります

于 2012-08-30T18:09:50.853 に答える