0

特定の Delphi バージョンからプロジェクト MRU リストを取得しようとしています。

function GetDelphiMRUList(const verstr: string; var MRUList: TStringList): Boolean;
var
  Reg: TRegistry;
begin
  Result := False;
  MRUList.Text := '';
  Reg := TRegistry.Create;
  try
    Reg.RootKey := HKEY_CURRENT_USER;
    Reg.OpenKeyReadOnly('SOFTWARE\Embarcadero\BDS\' + verstr);
    Result := Reg.KeyExists('Closed Projects');
    Reg.CloseKey;
    if Result then
    begin
      // How to get the MRUList?

    end;
  finally
    Reg.Free;
  end;
end;

使用法：

procedure TForm1.FormCreate(Sender: TObject);
begin
  var MRUList: TStringList;
  MRUList := TStringList.Create;
  try
    if GetDelphiMRUList('22.0', MRUList) then
      CodeSite.Send('TForm1.FormCreate: MRUList', MRUList);
  finally
    MRUList.Free;
  end;
end;

クローズされたプロジェクトのリストを取得するのに行き詰まっています。

4

1 に答える 1

2

少なくとも私のシステムでは、レジストリ値には 、 などの名前が付けられてFile_0いるFile_1ため、このリストを取得するのは簡単です。

function GetDelphiMRUList(const verstr: string; MRUList: TStringList): Boolean;
begin
  var Reg := TRegistry.Create;
  try
    Reg.RootKey := HKEY_CURRENT_USER;
    Result := Reg.OpenKey('SOFTWARE\Embarcadero\BDS\' + verstr + '\Closed Projects', False);
    if Result then
    begin
      MRUList.Clear;
      var i := 0;
      while Reg.ValueExists('File_' + i.ToString) do
      begin
        MRUList.Add(Reg.ReadString('File_' + i.ToString));
        Inc(i);
      end;
    end;
  finally
    Reg.Free;
  end;
end;

( をパラメータにする意味がないことに注意してくださいMRUList。var)

使用法：

procedure TForm1.FormCreate(Sender: TObject);
begin
  var List := TStringList.Create;
  try
    if GetDelphiMRUList('21.0', List) then
      Memo1.Lines.Assign(List)
    else
      Memo1.Text := 'Couldn''t get MRU list.';
  finally
    List.Free;
  end;
end;
于 2022-01-01T19:13:00.690 に答える