6

簡単な質問は、ユーザーが共有オブジェクトへのデータの書き込みをブロックしているかどうかを actionscript で検出するにはどうすればよいですか?

sharedObj = SharedObject.getLocal("rememberme");

これは常に共有オブジェクトを返しますが、共有オブジェクトをブロックしてもサイズは0です。

データを共有オブジェクトに保存してフラッシュしようとすると、書き込みがブロックされているため、エラーがスローされます。では、共有オブジェクトへの書き込みが無効になっているかどうかを確認する正しい方法は何でしょうか?

Error: Error #2130: Unable to flush SharedObject.
4

1 に答える 1

10 
var my_so:SharedObject = SharedObject.getLocal("mySpace");
var flushStatus:String = null;
try {
    flushStatus = my_so.flush();
} catch (error:Error) {
    trace("Error...Could not write SharedObject to disk\n");
}
if (flushStatus != null) {
    switch (flushStatus) {
        case SharedObjectFlushStatus.PENDING :
            trace("Requesting permission to save object...\n");
            my_so.addEventListener(NetStatusEvent.NET_STATUS, onFlushStatus);
            break;
        case SharedObjectFlushStatus.FLUSHED :
            trace("Value flushed to disk.\n");
            break;
    }
}
function onFlushStatus(event:NetStatusEvent):void {
    trace("User closed permission dialog...\n");
    switch (event.info.code) {
        case "SharedObject.Flush.Success" :
            trace("User granted permission -- value saved.\n");
            break;
        case "SharedObject.Flush.Failed" :
            trace("User denied permission -- value not saved.\n");
            break;
    }
my_so.removeEventListener(NetStatusEvent.NET_STATUS, onFlushStatus);
}

共有オブジェクトがブロックされている場合はcatch、エラーを報告できます。それ以外の場合は 0 になりSharedObjectFlushStatus.PENDINGます。

ソース

于 2011-08-31T08:18:16.977 に答える