1

私は10以上のSProcで使用され、アイロンがけされるとおそらく成長する関数に取り組んでいます。

私が遭遇している問題は、データ型ごとに関数を開発したくないということです。そのため、SQL_VARIANTデータ型はアクションに非常に便利に見えます。データ型をチェックできることはわかっていますがISNULL、渡された値が有効な数値であるかどうかもチェックしたいのですが、ISNUMERIC関数が機能せず、関数についてよくわかりませSQL_VARIANTんSQL_VARIANT_PROPERTY。

これまでのコード：

CREATE FUNCTION dbo.mpt_Format_Number
(
    @value SQL_VARIANT
    , @money BIT
)
RETURNS VARCHAR
AS
BEGIN
    --Check for NULL value
    IF ISNULL(@value) BEGIN
        -- Value IS NULL, return NULL
        RETURN NULL
    END ELSE BEGIN
        -- Value is NOT NULL
        DECLARE @TMP VARCHAR
    END 
END
4

2 に答える 2

4 
CREATE FUNCTION dbo.mpt_Format_Number 
( 
    @value SQL_VARIANT 
    , @money BIT 
) 
RETURNS VARCHAR 
AS 
BEGIN 
--Check for NULL value 
IF @value is null  
          -- Value IS NULL, return NULL 
    RETURN NULL 
ELSE 
BEGIN 
    -- Value is NOT NULL 
    if isnumeric(convert(varchar(max), @value)) = 1 RETURN 'Y' -- is valid number
    --DECLARE @TMP VARCHAR 

END  
return 'N' --is not valid number 
END

この構文を使用すると、いつでもプロパティタイプをテストできます。あなたの機能に協力しにくいはずです。

declare @t SQL_VARIANT
set @t = '3'
select SQL_VARIANT_PROPERTY(@t, 'basetype')

結果：

varchar
于 2011-09-01T15:29:59.040 に答える
0

最後の実装として、ここでは使用されたとおりの完全な関数があります。

ALTER FUNCTION [dbo].[_mpt_Format_Number]
(
    @value SQL_VARIANT
    , @money BIT = 0
)
RETURNS VARCHAR(max)
AS
BEGIN
    DECLARE @ret VARCHAR(MAX)
    --Check for NULL value
    IF @value IS NULL BEGIN
        -- Value IS NULL, return NULL
        SET @ret = 'NULL'
    END ELSE BEGIN
        -- Value is NOT NULL

        --Check for Numeric Value
        IF ISNUMERIC(CONVERT(VARCHAR, @value)) = 0 BEGIN
            --Value is NOT a Number, return NULL
            SET @ret =  'NULL'
        END ELSE BEGIN
            --Value IS a Number
            declare @isNeg BIT
            declare @tmp varchar(max)
            set @tmp = convert(varchar(max), round(cast(@value as money), 0), 1)

            --Check if value is negative
            if @value < 0 begin
                --Value is Negative
                set @isNeg = 1
                --Remove the negative sign
                set @tmp = replace(@tmp, '-', '')
            end 

            --Remove the decimal plus any digits to the right of the decimal
            set @tmp = left(@tmp ,len(@tmp) - 3)

            --Is money set to True
            if @money = 1 begin
                --Pre-pend the dollar sign to value
                set @tmp = '$' + @tmp
            end

            --Is isNeg set to True
            if @isNeg = 1 begin
                --Encapsulate the value with parenthesis
                set @tmp = '(' + @tmp + ')'
            end

            SET @ret =  @tmp
        END 
    END 

    RETURN @ret
END
于 2011-09-05T14:41:39.200 に答える