ios - Delphi XE2でiOS加速度計にアクセスするにはどうすればよいですか？

Question

Delphi XE2を使用してiOSの加速度計にアクセスするにはどうすればよいですか？

IDEを調べてみましたが、コンポーネントが見つかりませんでした。

Answer 1

Delphi XE2は、Mac上のOSXへのデプロイをサポートしています。iPhoneへの展開は明らかに非常に簡単ですが、それでも最終的な展開ツールとしてXCodeを使用する必要があります。DelphiはiPhoneハードウェアへの展開を「公式に」サポートしていないため、Delphiに固有のコンポーネントが含まれているとは思えません。

免責事項：私は数時間前にXE2をダウンロードしたばかりで、これまでに1つのMacアプリケーションしかデプロイしていません（そしてそれは美しく機能しました）。だから私は専門家からはほど遠い。

編集：Anders Ohlssonは、XE2用の加速度計コンポーネントを作成したようです。試したことはありませんが、こちらです。

Answer 2

ジョセフは正しいです。Philip Hessは、Delphi iOSニュースグループ、およびその他の有用な情報に貢献してきました。

https://forums.embarcadero.com/message.jspa?messageID=390713&tstart=125

彼はまたこのページを持っています、ここに：

http://web.me.com/macpgmr/ObjP/Xcode4/ObjP_Intro.html

これはあなたに役立つかもしれません。私は現在、CoreLocationサービス（とりわけ）を使用するために、すべてを検討しています。それは確かに心の弱い人のためではありません。

Answer 3

Embarcaderoブログに加速度計を読み取るコンポーネントがあります：
http
：//edn.embarcadero.com/article/41748 コンポーネントのダウンロードリンクは次のとおりです：http：//cc.embarcadero.com/item/28609

Anders Ohlssonによるソースコードは次のとおりです
（これを使用してGPS /コンパスのコンポーネントを作成しました）。

unit Accelerometer;

{$IFDEF FPC}
{$mode objfpc}{$H+}
{$modeswitch objectivec1}
{$ENDIF}

interface

uses
  SysUtils, Classes, FMX_Types
{$IFDEF FPC}
  , iPhoneAll
{$ENDIF}
  ;

type
  TAccelerateEvent = procedure(x,y : Double) of object;

  TiOSAccelerometer = class(TFmxObject)
  private
    FOnAccelerate: TAccelerateEvent;
    { Private declarations }
  protected
    { Protected declarations }
  public
    { Public declarations }
    constructor Create(AOwner: TComponent); override;
  published
    { Published declarations }
    property OnAccelerate: TAccelerateEvent read FOnAccelerate write FOnAccelerate;
  end;

{$IFDEF FPC}
const
  kAccelerometerFrequency = 100.0; // Hz
{$ENDIF}

{$IFDEF FPC}
type
  UIAcceleration = objcclass external (NSObject)
  public
    function timestamp: NSTimeInterval; message 'timestamp';
    function x: UIAccelerationValue; message 'x';
    function y: UIAccelerationValue; message 'y';
    function z: UIAccelerationValue; message 'z';
  end;
{$ENDIF}

{$IFDEF FPC}
type
  AccDelegate = objcclass(NSObject)
    procedure accelerometer_didAccelerate(accelerometer: UIAccelerometer; acceleration: UIAcceleration); message 'accelerometer:didAccelerate:';
  end;
{$ENDIF}

{$IFDEF FPC}
var
  AccDelegatVar: AccDelegate;
{$ENDIF}

var
  MyAccelerometer: TiOSAccelerometer;

procedure Register;

implementation

{$IFDEF FPC}
procedure AccDelegate.accelerometer_didAccelerate(accelerometer: UIAccelerometer; acceleration: UIAcceleration);
begin
  if Assigned(MyAccelerometer) then
    if Assigned(MyAccelerometer.FOnAccelerate) then
      MyAccelerometer.FOnAccelerate(acceleration.x,acceleration.y);
end;
{$ENDIF}

constructor TiOSAccelerometer.Create(AOwner: TComponent);
begin
  inherited;
  {$IFDEF FPC}
  UIAccelerometer.sharedAccelerometer.setUpdateInterval(1.0 / kAccelerometerFrequency);
  AccDelegatVar := AccDelegate.alloc;
  UIAccelerometer.sharedAccelerometer.setDelegate(AccDelegatVar);
  {$ENDIF}
end;

procedure Register;
begin
  RegisterComponents('iOS', [TiOSAccelerometer]);
end;

end.