0

iTextSharp を使用しているときに PDF に変換したい html 文字列を解析しようとすると、TextReader で少し問題が発生します。

Function ViewDeliveryNote(ByVal id As Integer) As FileStreamResult
        'Memory buffer
        Dim ms As MemoryStream = New MemoryStream()

        'the document
        Dim document As Document = New Document(PageSize.A4)

        'the pdf writer
        PdfWriter.GetInstance(document, ms)

        Dim wc As WebClient = New WebClient
        Dim htmlText As String = wc.DownloadString("http://localhost:59800/Warehouse/DeliveryNote/" & id) 'Change to live URL
        Dim worker As html.simpleparser.HTMLWorker = New html.simpleparser.HTMLWorker(document)
        Dim reader As TextReader = New StringReader(htmlText)

        document.Open()

        worker.Open()
        worker.StartDocument()
        worker.Parse(reader)
        worker.EndDocument()
        worker.Close()

        document.Close()

        'ready the file stream
        Response.ContentType = "application/pdf"
        Response.AddHeader("content-disposition", "attachment;filename=DeliveryNote.pdf")
        Response.Buffer = True
        Response.Clear()
        Response.OutputStream.Write(ms.GetBuffer(), 0, ms.GetBuffer.Length)
        Response.OutputStream.Flush()
        Response.End()

        Return New FileStreamResult(Response.OutputStream, "application/pdf")
 End Function

HTMLページを正常に読み取ったにもかかわらず、停止した行にworker.Parse(reader)エラーがあります。Object reference not set to an instance of an objectStringReader(htmlText)

現時点で何が間違っているのか、何が欠けているのかわからないので、何か助けていただければ幸いです。

更新Dim reader As New StringReader(htmlText)代わりに試してみましたが、役に立ちませんでした。htmlText には確かに値が含まれていますが、オブジェクトは値が含まれていないと認識しています。

4

1 に答える 1

0

コントローラーの汚染を避けるために、これに対するカスタム アクションの結果を必ず作成します。また、コード内の未処理の使い捨てリソースもすべて処理する必要があります。

Public Class PdfResult
    Inherits ActionResult

    Private ReadOnly _id As Integer

    Public Sub New(ByVal id As Integer)
        _id = id
    End Sub

    Public Overrides Sub ExecuteResult(context As ControllerContext)
        If context Is Nothing Then
            Throw New ArgumentNullException("context")
        End If

        Dim response = context.HttpContext.Response
        response.Buffer = True
        response.ContentType = "application/pdf"
        response.AddHeader("Content-Disposition", "attachment; filename=DeliveryNote.pdf")

        Using client = New WebClient()
            Dim htmlText As String = client.DownloadString("http://localhost:59800/Warehouse/DeliveryNote/" & _id) 'Change to live URL
            Dim doc = New Document(PageSize.A4)
            PdfWriter.GetInstance(doc, response.OutputStream)
            Dim worker = New HTMLWorker(doc)
            doc.Open()
            worker.Open()
            Using reader = New StringReader(htmlText)
                worker.Parse(reader)
            End Using
            doc.Close()
        End Using
    End Sub
End Class

そして簡単に：

Function ViewDeliveryNote(ByVal id As Integer) As ActionResult
    Return New PdfResult(id)
End Function

サーバーが目的の URL にアクセスできることも確認する必要があります。彼の要求はネットワーク アカウントのコンテキストで実行されることを忘れないでください。ネットワーク アカウントは、通常のアカウントと同じ権限を持っていない可能性があります。

于 2011-09-05T15:23:26.653 に答える