10

SL4A に基本的な GUI 機能はありますか? Android で Python プログラムを実行したいのですが、リストボックスと簡単なダイアログ (情報を表示して入力を取得する) が必要です。

簡単なダイアログがあるようですが、リストボックスは見つかりませんでした。リストボックスがない場合、テキストを書き、画面の指定された部分に四角形を強調表示し、ユーザーが画面に触れたり入力したりすることに反応する機能があれば、リストボックスを作成できるはずです (ユーザーが触れた場所や場所を知ることを含む)カーソルは）です。

4

3 に答える 3

11

基本的に、実行できることは3つあります。

  1. ユーザーの入力（ユーザー名とパスワードなど）の取得や選択オプションのリストの表示など、単純なAndroidリストと入力が必要な場合は、http ：//code.google.comにいくつかのチュートリアルがあります。 / p / android-scripting / wiki / UiExamples

  2. 情報を表示したい場合（つまり、ユーザーに選択させたくない場合）、WebViewにHTMLを表示して、イベントを介して応答することができます：http ://code.google.com/p/android-scripting/wiki/UsingWebView

    droid.eventPost(eventName,eventData);これを行うと、JavaScriptおよびdroid.eventWaitFor(eventName).resultPythonで使用することにより、イベントを介して機能が制限されます。その後、受信したデータを使ってやりたいことができます。

  3. 勇気がある場合は、最新の非公式リリースに完全なAndroidレイアウト（ネイティブAndroidアプリにあるようなXMLで作成されたもの）のサポートが含まれています。そのためのガイドはここにあります：http ：//code.google.com/p/android-scripting/wiki/FullScreenUI

于 2011-10-13T05:21:50.930 に答える
10

Android / iOS / Linux / Windows /MacでPythonGUIソリューションが必要な場合は、kivyを使用できます...それは素晴らしいです！ kivy.org

于 2012-07-06T08:42:14.520 に答える
3

高速で強力なオプションは、REBOL 3 を使用することです。SL4a の機能を使用できますが、次のことは必要ありません。

http://business-programming.com/business_programming.html#section-18

以下は、GUI を備えた 10 個の完全に機能するデモ プログラムです。これらは Android とデスクトップ OS で実行され、まったく同じコードを使用し、変更はありません。非常に小さなスクリプトで、非常に簡単に作成できます。それのようなものは他にありません：

REBOL []
load-gui
view [text "Hello World!"]


REBOL [title: "Tiny Note Editor"]
do %r3-gui.r3  ; download this file manually or just use load-gui as above
view [
    a1: area
    button "Save" on-action [write %notes.txt get-face a1]
    button "Load" on-action [set-face a1 to-string read %notes.txt]
]


REBOL [title: "Data Entry to CSV File"]
do %r3-gui.r3
view [
    text "First Name:"
    f1: field
    text "Last Name:"
    f2: field
    button "Submit" on-action [
        write/append %cntcts.txt rejoin [
            mold get-face f1 " " mold get-face f2 newline
        ]
        request "" "Saved"
    ]
    a1: area
    button "Load" on-action [set-face a1 to-string read %cntcts.txt]
]


REBOL [title: "Text File Reader (How to use a text list file selector)"]
do %r3-gui.r3
view [
    a1: area
    button "Load" on-action [
        files: read %./
        view/modal [
            text "File Name:"
            t2: text-list files on-action [
                set-face a1 to-string read(to-file pick files get-face t2)
                unview
            ]
        ]
    ]
]


REBOL [title: "List-View (Grid) Example"]
do %r3-gui.r3
view [
    text-table ["1" 200 "2" 100 "3"][
        ["asdf" "a" "4"]
        ["sdfg" "b" "3"]
        ["dfgh" "c" "2"]
        ["fghj" "d" "1"]
    ] 
]


REBOL [title: "Calculator"]
do %r3-gui.r3
stylize [
    btn: button [
        facets: [init-size: 50x50]
        actors: [on-action:[set-face f join get-face f get-face face]]
    ]
]
view [
    hgroup [
        f: field return
        btn "1"  btn "2"  btn "3"  btn " + "  return
        btn "4"  btn "5"  btn "6"  btn " - "  return
        btn "7"  btn "8"  btn "9"  btn " * "  return
        btn "0"  btn "."  btn " / "   btn "=" on-action [
            attempt [set-face f form do get-face f]
        ]
    ]
]


REBOL [title: "Sliding Tile Puzzle"]
do %r3-gui.r3
stylize [
    p: button [
        facets: [init-size: 60x60  max-size: 60x60]
        actors: [
            on-action: [
                t: face/gob/offset
                face/gob/offset: x/gob/offset
                x/gob/offset: t
            ]
        ]
    ]
]
view/options [
    hgroup [ 
        p "8"   p "7"   p "6"   return
        p "5"   p "4"   p "3"   return
        p "2"   p "1"   x: box 60x60 white
    ]
] [bg-color: white]


REBOL [title: "Math Test"]
do %r3-gui.r3
random/seed now
x: does [rejoin [random 10 " + " random 20]]
view [
    f1: field (x)
    text "Answer:"
    f2: field on-action [
        either (get-face f2) = (form do get-face f1) [
            request "Yes!" "Yes!"][request "No!" "No!"
        ]
        set-face f1 x
        set-face f2 ""
        focus f2
    ]
]


REBOL [title: "Minimal Cash Register"]
do %r3-gui.r3
stylize [fld: field [init-size: 80]]   
view [
    hgroup [
        text "Cashier:"   cashier: fld 
        text "Item:"      item: fld 
        text "Price:"     price: fld on-action [
            if error? try [to-money get-face price] [
                request "Error" "Price error" 
                return none
            ]
            set-face a rejoin [
                get-face a mold get-face item tab get-face price newline
            ]
            set-face item copy "" set-face price copy ""
            sum: 0
            foreach [item price] load get-face a [
                sum: sum + to-money price
            ]
            set-face subtotal form sum
            set-face tax form sum * .06
            set-face total form sum * 1.06 
            focus item
        ]
        return
        a: area 600x300
        return
        text "Subtotal:"   subtotal: fld 
        text "Tax:"        tax: fld 
        text "Total:"      total: fld
        button "Save" on-action [
            items: replace/all (mold load get-face a) newline " "
            write/append %sales.txt rejoin [
                items newline get-face cashier newline now/date newline
            ]
            set-face item copy "" set-face price copy "" 
            set-face a copy ""    set-face subtotal copy ""
            set-face tax copy "" set-face total copy ""
        ]
    ]
]


REBOL [title: "Requestors"]
do %r3-gui.r3
x: request/ask "Question" "Do you like this?."
either x = false [print "No!"] [print "Yes!"]
x: request/custom "" "Do you like this?" ["Yay" "Boo"]
either x = false [print "Boo!"] [print "Yay!"]
view [button "Click me" on-action[request "Ok" "You clicked the button."]]

SL4a から REBOL への機能を使用または追加する場合は、https: //raw.github.com/gchiu/Rebol3/master/protocols/prot-sl4a.r3 でコードを実行するだけです

于 2013-09-02T13:59:21.427 に答える