19

ノードが存在するかどうかに応じて設定された後、変数のリテラル文字列値を出力しようとしています。条件チェックのロジックは正しいと思います。しかし、それは値を出力していません...

<xsl:variable name="subexists"/>

<xsl:template match="class">
<xsl:copy><xsl:apply-templates select="@*|node()"/></xsl:copy>
<xsl:choose>
    <xsl:when test="joined-subclass">
        <xsl:variable name="subexists" select="'true'"/>
    </xsl:when>
    <xsl:otherwise>
        <xsl:variable name="subexists" select="'false'"/>
    </xsl:otherwise>
</xsl:choose>
subexists:  <xsl:value-of select="$subexists" />

「true」か「false」のリテラル文字列を出力してほしい。しかし、それは何も出力していません。助けてください！ありがとうございました！！！

4

3 に答える 3

22

この場合、変数を設定するための条件は必要ありません。

このワンライナー XPath 式:

boolean(joined-subclass)

true()指定された現在のノードの子が存在する場合にのみ存在joined-subclassし、それ以外の場合は存在しませんfalse()。

完全なスタイルシートは次のとおりです。

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes"/>

 <xsl:template match="class">
   <xsl:variable name="subexists"
        select="boolean(joined-subclass)"
   />

   subexists:  <xsl:text/>
   <xsl:value-of select="$subexists" />
 </xsl:template>
</xsl:stylesheet>

この式での XPath 関数の使用はboolean()、ノード (またはその不在) をブール値true()またはのいずれかに変換することであることに注意してくださいfalse()。

于 2009-04-13T13:24:31.997 に答える
7

主な問題は、テンプレートの外部で宣言した変数が、chooseステートメント内で「設定」されているのと同じ変数であると考えることです。これはXSLTの動作方法ではなく、変数を再割り当てすることはできません。これはあなたが望むものにもっと似ています：

<xsl:template match="class">
  <xsl:copy><xsl:apply-templates select="@*|node()"/></xsl:copy>
  <xsl:variable name="subexists">
    <xsl:choose>
      <xsl:when test="joined-subclass">true</xsl:when>
      <xsl:otherwise>false</xsl:otherwise>
    </xsl:choose>
  </xsl:variable>
  subexists:      <xsl:value-of select="$subexists" />
</xsl:template>

また、変数に「グローバル」スコープが必要な場合は、テンプレートの外部で宣言します。

<xsl:variable name="subexists">
  <xsl:choose>
     <xsl:when test="/path/to/node/joined-subclass">true</xsl:when>
     <xsl:otherwise>false</xsl:otherwise>
  </xsl:choose>
</xsl:variable>

<xsl:template match="class">
   subexists:      <xsl:value-of select="$subexists" />
</xsl:template>
于 2009-04-13T01:57:49.387 に答える
6

XSLTでは、同じ<xsl:variable>ものを1回だけ宣言でき、宣言時にのみ値を指定できます。複数の変数が同時に宣言されている場合、それらは実際には異なる変数であり、異なるスコープを持っています。

したがって、変数の必要な条件付き設定を実現し、その値を生成する方法は次のとおりです。

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes"/>

    <xsl:template match="class">
    <xsl:variable name="subexists">
            <xsl:choose>
                <xsl:when test="joined-subclass">true</xsl:when>
                <xsl:otherwise>false</xsl:otherwise>
            </xsl:choose>
        </xsl:variable>
        subexists:  <xsl:text/>    
        <xsl:value-of select="$subexists" />
    </xsl:template>
</xsl:stylesheet>

上記の変換が次のXMLドキュメントに適用される場合：

<class>
 <joined-subclass/>
</class>

必要な結果が生成されます：

    subexists:  true
于 2009-04-13T02:08:16.227 に答える