0

Grails 監査ロギング プラグインが正常に機能するようになりました。onChange メソッド内から監査可能なドメイン オブジェクトへの参照を取得する方法がわかりません。以下は、プラグインの例の Person クラスのコードで、私が達成しようとしていることのいくつかの行が追加されています。

class Person {

   static auditable = true 
   Long id 
   Long version

   String firstName 
   String middleName 
   String lastName

   String email

   static hasMany = [emailRecords : EmailRecord]    
   static constraints = { 
      firstName(nullable:true,size:0..60) 
      middleName(nullable:true,size:0..60) 
      lastName(nullable:false,size:1..60) 
      email(email:true) 
   }

   def onSave = { 
      println "new person inserted" // may optionally refer to newState map 
   } 

   def onDelete = { 
      println "person was deleted" // may optionally refer to oldState map 
   } 

   def onChange = { 
     oldMap,newMap -> 
        println "Person was changed ..." 
        oldMap.each({ key, oldVal -> 
           if(oldVal != newMap[key]) { 
              println " * $key changed from $oldVal to " + newMap[key] 
              // how can achieve something like this?
              if(key == "email"){
                 def personInstance = this // this didn't work, I'm not sure how I can get such a reference to the owning domain object
                 personInstance.addToEmailRecords(
                    new EmailRecord(
                       email:newMap[key],
                       date: new Date()
                    ).save()
                 )
              }
           } 
        }) 
     }
   }
4

1 に答える 1

2

このユースケースでは、少なくともisDirty()とgetPersistentValue()を使用して標準の GORM イベントを使用して、更新を行いたいだけです。特に、監査ログ プラグインのドキュメントに記載されているように、エンティティがデータ ストアにコミットされた後にエンティティで動作するように設計されています (したがって、たとえば、オブジェクト ID が割り当てられることが保証されます)。

次のようなことを試してください。

class Person {
    // blah, blah, blah
    def beforeInsert = {
        if (email) {
            addToEmailRecords(new EmailRecord(email: email, date: new Date()))
        }
    }

    def beforeUpdate = {
        if (isDirty("email")) {
            addToEmailRecords(new EmailRecord(email: email, date: new Date()))
        }
    }
}

そうすれば、オブジェクトの変更がコミットされた後にオブジェクトを変更することで、ファンキーにぶつかることはありません。

于 2011-09-16T22:01:37.043 に答える