1

Perl では、ファイル パスが与えられた場合、最初に存在する祖先をどのように見つけますか?

例えば：

  • 指定されたパス/opt/var/DOES/NOT/EXIST/wtv/blarg.txtとディレクトリ/opt/var/DOES/は存在しないが、ディレクトリ/opt/var/は存在する場合、結果は になります/opt/var/。
  • パス/home/leguri/images/nsfw/lena-full.jpgとディレクトリ/home/leguri/images/nsfw/が存在しないが、ディレクトリが存在する場合/home/leguri/images/、結果は になります/home/leguri/images/。

これを行うモジュールまたは関数はありますか、それともパスを分割し/て存在をテストするだけの問題ですか?

4

2 に答える 2

5

私が知っている最も近いのはPath::Classです。これは、まさにあなたが望むことを行うわけではありませんが、パスを分割する際にいくつかの手順を節約できます。

use Path::Class 'dir';

sub get_existing_dir {
    my ( $path ) = @_;

    my $dir = dir( $path );
    while (!-d $dir) {
        $dir = $dir->parent;
    }
    return $dir->stringify;
}

my $file = '/opt/var/DOES/NOT/EXIST/wtv/blarg.txt';
my $dir = get_existing_dir( $file );
print $dir;
于 2011-09-17T03:10:51.617 に答える
0

モンキーパッチ

#!/usr/bin/perl --
use strict;
use warnings;
use Path::Class ;

my @paths = map dir($_) , 
    map join( '/', $_, 1..6 ),
    grep defined,
    @ENV{qw/ WINDIR PROGRAMFILES TEMP HOME /},
    'Q:/bogus/drive/and/path', 
    'QQ:/bogus/drive/bogusly/treated/as/file',
    ;
push @paths, dir('bogus/relative/path/becomes/dot');
push @paths, dir('bogus/relative/path/becomes/relative/to/cwd')->absolute;

for my $path ( @paths ) {
    print $path, "\n\t=> ", $path->real_parent, "\n\n";
}

sub Path::Class::Entity::real_parent {
    package Path::Class::Entity;
    my( $dir ) = @_;
    while( !-d $dir ){
        my $parent = $dir->parent;
        last if  $parent eq $dir ; # no infinite loop on bogus drive
        $dir = $parent;
    }
    return $dir if -d $dir;
    return;
}
__END__
C:\WINDOWS\1\2\3\4\5\6
    => C:\WINDOWS

C:\PROGRA~1\1\2\3\4\5\6
    => C:\PROGRA~1

C:\DOCUME~1\bogey\LOCALS~1\Temp\1\2\3\4\5\6
    => C:\DOCUME~1\bogey\LOCALS~1\Temp

C:\DOCUME~1\bogey\1\2\3\4\5\6
    => C:\DOCUME~1\bogey

Q:\bogus\drive\and\path\1\2\3\4\5\6
    => 

QQ:\bogus\drive\bogusly\treated\as\file\1\2\3\4\5\6
    => .

bogus\relative\path\becomes\dot
    => .

C:\temp\bogus\relative\path\becomes\relative\to\cwd
    => C:\temp
于 2011-09-17T13:38:33.667 に答える