0

これは、メイン クラスにインスタンス化しようとしているクラスです。

public class Character extends Sprite {

    [Embed(source='../lib/front1.svg')]
    private var front1Class:Class;
    private var crosshair:Sprite = new front1Class ();

    public function Character() {
        trace("started");
        Mouse.hide();

        crosshair.scaleX = 5;
        crosshair.scaleY = 5;
        this.addChild(crosshair);

        stage.addEventListener(Event.ENTER_FRAME, MrEveryFrame);
        stage.addEventListener(MouseEvent.CLICK, click);
    }


    private function click(evt:MouseEvent):void {
        trace("clicked @ " + evt.stageX + "," + evt.stageY);

    }
    public function MrEveryFrame(e:Event):void
    {
        crosshair.x = mouseX - 15;
        crosshair.y = mouseY - 15;


    }

}

ドキュメントクラスに設定すると、正常に動作します。

ただし...これをドキュメントクラスにして、そこから呼び出そうとすると:

public class Shell extends Sprite
{


    private var character:Sprite = new Character ();


    public function Shell() 
    {

        addChild(character);


    }


}

壊れて、スプライト オブジェクトが表示されなくなります (ただし、マウス ポインターは消去されます)。

ここでの取引は何ですか？カスタム スプライトまたはムービークリップ クラスを DisplayObject クラスにインスタンス化することはできませんか?

4

1 に答える 1

2

ステージはnullコンストラクタにあります。あなた自身が見つけたように、それはあなたのクラスがドキュメントクラスである場合にのみ機能します。したがって、コンストラクターを次のように変更します。

public function Character() {
    trace("started");
    Mouse.hide();

    crosshair.scaleX = 5;
    crosshair.scaleY = 5;
    this.addChild(crosshair);

    addEventListener(Event.ADDED_TO_STAGE, onAddedToStage);
}

private function onAddedToStage(event:Event):void
{

    stage.addEventListener(Event.ENTER_FRAME, MrEveryFrame);
    stage.addEventListener(MouseEvent.CLICK, click);
}

リスナーを追加すると、ステージが認識された後にのみステージにアクセスします。null

于 2011-09-26T20:45:40.823 に答える