wolfram-mathematica - listPlotの複数のディレクティブ

Question

daList={{0.059, 0.298, 0.726, 0.735, 1.461, 2.311, 3.315}, 
        {0.05, 0.404,0.664, 0.782, 1.376, 2.328, 3.432}, 
        {0.087, 0.628, 0.986, 1.187,1.914, 3.481, 4.993}, 
        {0.073, 0.594, 0.975, 1.147, 2.019, 3.417,5.037}, 
        {0.143, 0.821, 1.442, 1.595, 2.983, 4.98, 7.604}, 
        {0.107,0.871, 1.431, 1.684, 2.964, 5.015, 7.394}}


ListPlot[daList,
         Joined -> True,
         PlotRange -> {{1, 7}, {0, 7}}, 
         PlotStyle -> {{Thick, Lighter[Red, .5]}, 
                       {Dashed, Black}, 
                       {Thick,Lighter[Red, .3]}, 
                       {Dashed, Black}, 
                       {Thick,Lighter[Red, .1]}, 
                       {Dashed, Black}},
         Prolog ->{GrayLevel[0.5], EdgeForm[Thickness[.005]], 
                   Rectangle[{1.01, 0.01}, {6.99, 6.99}]}]

ご覧のとおり、各行に異なるディレクティブを割り当てる必要があります。

破線の黒い線をポイントにします（Joined-> False）。

サブリストのディレクティブをグループ化する方法がまだわかりません。

ご清聴ありがとうございました。

Answer 1

他のすべてのプロットを結合したい場合は、単に設定できますJoined->{True, False}。

ListPlot[daList, Joined -> {True, False}, 
 PlotRange -> {{1, 7}, {0, 7}}, 
 PlotStyle -> {{Thick, Lighter[Red, .5]}, {Dashed, Black}, {Thick, 
    Lighter[Red, .3]}, {Dashed, Black}, {Thick, 
    Lighter[Red, .1]}, {Dashed, Black}}, 
 Prolog -> {GrayLevel[0.5], EdgeForm[Thickness[.005]], 
   Rectangle[{1.01, 0.01}, {6.99, 6.99}]}]

生産する

編集

あなたのコメントに関しては、いつでも偶数セットと奇数セットのポイントを別々にプロットし、それらをショーと組み合わせることができると思います。あなたの例では：

joinedStyle = {Thick, Lighter[Red, #]} & /@ {.5, .3, .1};
pointStyle = Black;

plot1 = ListPlot[daList[[1 ;; ;; 2]], Joined -> True, PlotStyle -> joinedStyle,
  PlotRange -> {{1,7},{0,7}}];
plot2 = ListPlot[daList[[2 ;; ;; 2]], Joined -> False, PlotStyle -> pointStyle];
Show[plot1, plot2, PlotRange -> {{1, 7}, {0, 7}}, 
  Prolog -> {GrayLevel[0.5], EdgeForm[Thickness[.005]], 
    Rectangle[{1.01, 0.01}, {6.99, 6.99}]}]

Answer 2

プロットを個別に構築し、Show. 以下は、うまくいけば的外れではない例です。

{d1, d2} = Partition[daList, 2]\[Transpose];
lambda = {541, 550, 560, 570, 580, 590, 600};
colors = {Thick, Red~Lighter~#} & /@ {0.5, 0.3, 0.1};

g1 = ListPlot[d1, Joined -> True, PlotStyle -> colors];
g2 = ListPlot[d2, PlotStyle -> {{Black, AbsolutePointSize[5]}}];

Show[{g1, g2}, PlotRange -> {{1, 7}, {0, 7}}, 
 AspectRatio -> 1/GoldenRatio, Frame -> True, FrameStyle -> 20, 
 FrameTicks -> {{Automatic, 
    None}, {MapIndexed[{#2[[1]], #} &, lambda], Automatic}}, 
 Prolog -> {GrayLevel[0.5], EdgeForm[Thickness[.005]], 
   Rectangle[Scaled[{0, 0}], Scaled[{1, 1}]]}, ImageSize -> 600]

ここはほぼ平家を真似していると思いますが、意図的ではありません。うまくいけば、両方の答えが何かを追加します。

https://stackoverflow.com/questions/6303500/mathematica-matlab-like-figure-plotScaledには、ImageScaledこのまさにアプリケーションの使用のより完全な例があります。

Answer 3

の代わりにListPlot、あなたは考えることができますGraphics

tdata = MapIndexed[{#2[[1]], #1} &, #] & /@ daList;

と

Graphics[
 { GrayLevel[0.7], EdgeForm[AbsoluteThickness[2]], 
  Rectangle[{1.02, 0.05}, {7.2, 7.75}],
  (*lines*)
  AbsoluteThickness[2], 
  Transpose[{Lighter[Red, #] & /@ {0.5, 0.3, 0.1}, 
    Line@tdata[[#]] & /@ {1, 3, 5}}],
  (*points*)
  Black, PointSize[0.016],
  Point@tdata[[#]] & /@ {2, 4, 6}
  }, Axes -> True, PlotRange -> {{1, 7.2}, {0, 7.8}},
 AspectRatio -> 1/GoldenRatio]

与える

または、次のプロットのように、各データ セットに異なる記号を指定します。

コード：

Graphics[
 { GrayLevel[.7], EdgeForm[AbsoluteThickness[2]], 
  Rectangle[{1.02, 0.05}, {7.2, 7.75}],

  (*lines*)
  AbsoluteThickness[2], 
  Transpose[{Lighter[Red, #] & /@ {0.5, 0.3, 0.1}, 
    Line@tdata[[#]] & /@ {1, 3, 5}}],

  (*points*)

  Inset[Graphics[{EdgeForm[Black], White, Rectangle[]}, 
      ImageSize -> 8], #] & /@ tdata[[2]],
  Inset[Graphics[{EdgeForm[Black], White, 
       Polygon[{{1, 0}, {0, Sqrt[3]}, {-1, 0}}]}, 
      ImageSize -> 10], #] & /@ tdata[[4]],
  Inset[Graphics[{ EdgeForm[Black], White, Disk[]}, 
      ImageSize -> 9], #] & /@ tdata[[6]]

  }, Axes -> True, PlotRange -> {{1, 7.2}, {0, 7.8}},
 AspectRatio -> 1/GoldenRatio]