2

次の XML に基づいて、XSL で英数字の並べ替えを実現する最善の方法は何ですか?

編集: 明確にするために、以下の XML は単純なサンプルにすぎず、実際の XML にはより多くのバリアント値が含まれます。

<colors>
  <item>
    <label>Yellow 100</label>
  </item>
  <item>
    <label>Blue 12</label>
  </item>
  <item>
    <label>Orange 3</label>
  </item>
  <item>
    <label>Yellow 10</label>
  </item>
  <item>
    <label>Orange 26</label>
  </item>
  <item>
    <label>Blue 117</label>
  </item>
</colors>

たとえば、次の順序で最終結果が必要です。

Blue 12, Blue 117, Orange 3, Orange 26, Yellow 10, Yellow 100

これは「効果的に」私が望むものです。

<xsl:apply-templates select="colors/item">
  <xsl:sort select="label" data-type="text" order="ascending"/><!--1st sort-->
  <xsl:sort select="label" data-type="number" order="ascending"/><!--2nd sort-->
</xsl:apply-templates>   

<xsl:template match="item">
  <xsl:value-of select="label"/>
  <xsl:if test="position() != last()">,</xsl:if>
</xsl:template>
4

1 に答える 1

6

あなたの例では、substring-beforeandを使用してラベルテキストをテキストと数字の部分に分割します（ただし、これは一般的なアプローチではありませんが、アイデアは得られます）：substring-after

<xsl:template match="/">
    <xsl:apply-templates select="colors/item">
      <xsl:sort select="substring-before(label, ' ')" data-type="text" order="ascending"/>
      <!--1st sort-->
      <xsl:sort select="substring-after(label, ' ')" data-type="number" order="ascending"/>
      <!--2nd sort-->
    </xsl:apply-templates>
  </xsl:template>

  <xsl:template match="item">
    <xsl:value-of select="label"/>
    <xsl:if test="position() != last()">, </xsl:if>
  </xsl:template>

これにより、次の出力が得られます。

Blue 12, Blue 117, Orange 3, Orange 26, Yellow 10, Yellow 100

アップデート

並べ替えの問題を解決するより一般的な方法selectは、要素の属性に、xls:sort期待する並べ替え規則に従って並べ替え可能な文字列を含めることです。たとえば、この文字列では、すべての数値に先頭の 0 を埋め込むことができるため、辞書順にソートするとdata-type="text"、正しい英数字の順序になります。

.NET の XSLT エンジンを使用している場合は、C# で単純な拡張関数を使用して、数字の先頭に 0 を埋め込むことができます。

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:myExt="urn:myExtension"
                xmlns:msxsl="urn:schemas-microsoft-com:xslt"
                exclude-result-prefixes="msxsl myExt">
  <xsl:output method="xml" indent="yes" />

  <msxsl:script language="C#" implements-prefix="myExt">

    <![CDATA[
        private static string PadMatch(Match match)
        {
            // pad numbers with zeros to a maximum length of the largest int value 
            int maxLength = int.MaxValue.ToString().Length;
            return match.Value.PadLeft(maxLength, '0');
        }

        public string padNumbers(string text)
        {
            return System.Text.RegularExpressions.Regex.Replace(text, "[0-9]+", new System.Text.RegularExpressions.MatchEvaluator(PadMatch));
        }
    ]]>

  </msxsl:script>
  <xsl:template match="/">
    <sorted>
      <xsl:apply-templates select="colors/item">
        <xsl:sort select="myExt:padNumbers(label)" data-type="text" order="ascending"/>
      </xsl:apply-templates>
    </sorted>
  </xsl:template>

  <xsl:template match="item">
    <xsl:value-of select="label"/>
    <xsl:if test="position() != last()">, </xsl:if>
  </xsl:template>

</xsl:stylesheet>
于 2009-04-22T16:04:56.933 に答える