0

私はOpenVMSでのスクリプト作成に非常に苦労しています。test.txtというファイルに特定の出力があります。例：

[WWEWE@http-lx-as code]$ cat test.txt
** Configuration for file "MULTINET:NETWORK_DEVICES.CONFIGURATION" **

Device                           Adapter   CSR Address  Flags/Vector

------                           -------   -----------  ------------

se0  (Shared VAX/VMS Ethernet)   -NONE-    -NONE-       -NONE-

s10  (Serial Line IP)            -NONE-    -NONE-       -NONE-

dn0  (IP over DECNet link)       -NONE-    -NONE-       -NONE-

Linuxでスクリプトを作成しました。このスクリプトは、デバイス列の下にあるすべての情報（この場合はse0、s10、dn0）を取得するのに役立ちます。OPENVMSでも同様のことができますか

Linuxスクリプトは次のとおりです。スクリプト：

for i in `cat test.txt 2>/dev/null |egrep '^[a-z]' |grep -v '\*\*' | awk '{print $1}'`
> do
>     echo Begin-interface: $i
> done

出力：

Begin-interface: se0
Begin-interface: s10
Begin-interface: dn0

達成できるかどうか教えてください、よろしくお願いします

4

2 に答える 2

2

「-」で始まる行の下の最初の列に何かが必要であると仮定すると、コマンドファイルで次のことを試すことができます。

$    IF P1 .EQS. "" THEN GOTO nothing_specified
$    IF F$SEARCH( P1 ) .EQS. "" THEN GOTO file_not_found
$    parse_line = 0
$    OPEN/READ/ERROR=file_open_error infile 'P1'
$read_loop:
$    READ/ERROR=file_read_error/END_OF_FILE=end_of_file infile inline
$    IF F$LENGTH( F$EDIT( inline, "TRIM" ) ) .EQ. 0 THEN GOTO read_loop
$    IF parse_line .EQ. 1
$    THEN
$        interface = F$ELEMENT( 0, " ", F$EDIT( inline, "TRIM,COMPRESS" ) )
$        WRITE SYS$OUTPUT F$FAO( "Begin-interface: !AS", interface )
$    ELSE
$        parse_line = ( F$EXTRACT( 0,1,inline ) .EQS. "-" )
$    ENDIF
$    GOTO read_loop
$nothing_specified:
$    WRITE SYS$OUTPUT "No file specified"
$    GOTO finished
$file_not_found:
$    WRITE SYS$OUTPUT F$FAO( "File !AS not found", P1 )
$    GOTO finished
$file_open_error:
$    WRITE SYS$OUTPUT F$FAO( "Error opening file !AS", P1 )
$    GOTO finished
$file_read_error:
$    WRITE SYS$OUTPUT F$FAO( "Error reading from file !AS", P1 )
$    GOTO close_file
$end_of_file:
$close_file:
$    IF F$TRNLNM("infile").NES."" THEN CLOSE infile
$finished:
$    EXIT

次を使用してこのスクリプトを実行します。

$ @extract_if test.txt

出力は指定どおりである必要があります。

AWK に精通しているようです。OpenVMS 用の GAWK をインストールすることもできます。

于 2011-10-18T14:03:49.500 に答える
1

2年遅れ……。

$ gawk/comm="/^[a-z]/{print ""Begin-interface:"",$1}" test.tmp
Begin-interface: se0
Begin-interface: s10
Begin-interface: dn0

4 つまたは 5 つのパイプされたコマンドと適切なツールが必要で、1 つのステップですべてを実行する必要があると考えている Unix スクリプトの弱虫を理解することは決してできないと思います。

「cat」出力を awk または perl にパイプすることは、無知であることの最も明白で不快な兆候です。うーん…続き！ハイン。

于 2013-07-17T03:26:48.147 に答える