delphi - odt Open Officeドキュメントで検索して置換する方法は？

Question

私のDelphiアプリケーションでは、現在、Office OLEオートメーションを使用して、ドキュメントおよびdocxワードドキュメントをプログラムで検索および置換しています。OpenOfficeで同じことをするコード（doc、docs、odt）を持っている人はいますか？

また、PDFへの保存についても関連する質問をしました。

Answer 1

XReplaceableインターフェースに焦点を当てる必要があります。これが例です。エラー処理はありませんのでご注意ください。LibreOffice writerでテストしましたが、問題なく動作します。

uses
  ComObj;

procedure OpenOfficeReplace(const AFileURL: string; ASearch: string; const AReplace: string);
var
  StarOffice: Variant;
  StarDesktop: Variant;
  StarDocument: Variant;
  FileReplace: Variant;
  FileParams: Variant;
  FileProperty: Variant;

begin
  StarOffice := CreateOleObject('com.sun.star.ServiceManager');
  StarDesktop := StarOffice.CreateInstance('com.sun.star.frame.Desktop');

  FileParams := VarArrayCreate([0, 0], varVariant);
  FileProperty := StarOffice.Bridge_GetStruct('com.sun.star.beans.PropertyValue');
  FileProperty.Name := 'Hidden';
  FileProperty.Value := False;
  FileParams[0] := FileProperty;

  StarDocument := StarDesktop.LoadComponentFromURL(AFileURL, '_blank', 0, FileParams);

  FileReplace := StarDocument.CreateReplaceDescriptor;
  FileReplace.SearchCaseSensitive := False;
  FileReplace.SetSearchString(ASearch);
  FileReplace.SetReplaceString(AReplace);

  StarDocument.ReplaceAll(FileReplace);

  ShowMessage('Replace has been finished');

  StarDocument.Close(True);
  StarDesktop.Terminate;
  StarOffice := Unassigned;
end;

そして、例の使用法

procedure TForm1.Button1Click(Sender: TObject);
begin
  OpenOfficeReplace('file:///C:/File.odt', 'Search', 'Replace');
end;

SearchDescriptorにはいくつかの検索/置換オプションもあります。