2

perlコードは次のようになります：問題は、subtweak_server{}内の$keyを読み取れないことです...。

my $key;
my %hash = ( flintstones => [ "C:/Users1/f1.xml", "C:/Users1/f2.xml" ], 
            jetsons => [ "C:/Users2/f1.xml" ], 
            simpsons =>    [ "C:/Users3/f1.xml", "C:/Users3/f1.xml", "C:/Users3/f1.xml" ], ); 

foreach $key (keys%hash){
if (scalar@{$hash{$key}}>1){
    foreach my $path (@{$hash{$key}}){
        my $filehandle;
        open($filehandle, "+<$path") or die "cannot open out file out_file:$!";
        my $roots = { TAG => 1 };
        my $handlers = { 'ROOT/TAG' => \&tweak_server,
                    };
        my $twig = new XML::Twig(TwigRoots => $roots,
                             TwigHandlers => $handlers,
                             twig_print_outside_roots => \*$filehandle);
        $twig->parsefile($path);
        say $key;#could read key
        sub tweak_server {
            my ($twig, $root) = @_;
            my $tag2=$root->first_child_text('TAG2'); 
            say $key;# could not read
            if ($tag2=~/$key/){
            #BLABLA
            }
            $twig->flush( $filehandle, pretty_print => 'indented');
        }
    }
}

}

私が述べているように、$ keyはサブの外側では読み取ることができますが、内側では読み取ることができません。エラーが表示されました：初期化されていない値$keyの使用

それから私は単純な状況を試しました

my $a="aaa";
open( $filehandle, "+<$path") or die "cannot open out file out_file:$!";
my $roots = { TAG => 1 };
my $handlers = { 'ROOT/TAG' => \&tweak_server,
            };
my $twig = new XML::Twig(TwigRoots => $roots,
                     TwigHandlers => $handlers,
                     twig_print_outside_roots => \*$filehandle
                     );
$twig->parsefile($path);
sub tweak_server {
    say $a;
    my ($twig, $root) = @_;
    my $tags=$root->first_child_text('TAG2');
    my $str="204B";
    if ($tag2=~m/$str/){
    foreach my $b(1...6){
                    say $a;             }
}
$twig->flush( $filehandle, pretty_print => 'indented');

}

このコードでは、$ aを読み取ることができます....私はこれに1日を費やしましたが、それでも修正できません...クレイジーになりました。よろしくお願いします。

4

2 に答える 2

4

ループ$keyの外側で宣言しています。for次に、forループ内で、で閉じるサブルーチンを定義します$key。

原則として、適用可能な最小のスコープで変数を宣言します。例えば：

for my $key (keys ...) {

また

open my $filehandle, '<', ...

なぜループsub tweak_serverの本体で定義しているのですか？for私には、あなたがしたいのは、反復ごとに新しい匿名のサブを定義することだと思います。

まず、観察しているものを複製する短い例：

use warnings; use strict;

my $key;
my %hash = qw(a b c d e f);

foreach $key (keys %hash) {
    somesub();
    sub somesub {
        print "$key\n";
    }
}

今、修正：

use warnings; use strict;

my %hash = qw(a b c d e f);

foreach my $key (keys %hash) {
    my $somesub = sub { print "$key\n" };
    $somesub->();
}

このようにして、反復ごとに新しい無名関数を定義し、新しいサブはループ変数の各値を閉じます。

コードに関しては、名前付きサブを次のように置き換える必要があります

my $tweak_server = sub {
    my ($twig, $root) = @_;
    my $tag2=$root->first_child_text('TAG2'); 
    say $key;# could not read
    if ($tag2=~/$key/){
        #BLABLA
    }
    $twig->flush( $filehandle, pretty_print => 'indented');
}

my $handlers = { 
    'ROOT/TAG' => $tweak_server,
};

または、@ mirodが観察するように、さらに良いことに、：に渡し$keyますtweak_server。

sub tweak_server { 
    my( $key, $twig, $root)= @_;
    ...
}

そして、ループの本体では、

my $handlers = { 
    'ROOT/TAG' => sub { tweak_server($key, @_) },
};
于 2011-10-20T17:24:16.113 に答える
4

短いバージョン：別のサブ内またはループ内に名前付きサブ宣言（sub foo { ... }）がある場合は、おそらく何か間違ったことをしているので、匿名のサブが必要になる可能性があります。これはここに当てはまります。

sub foo { ... }

基本的には

BEGIN { *foo = sub { ... }; }

subがそれ自体の外部の字句（my）変数を参照している場合、それらsubは実行時にキャプチャされます。これは、コンパイル時に名前付きsubを使用します。よくある間違いは

sub outer {
    my ($x) = @_;

    sub inner {
       ... $x ...
    }

   outer();
}

my $x複数の変数を作成するために複数回呼び出されるため、これは機能しませんinnerが、コンパイル時に存在したもののみをキャプチャします。（幸いなことに、それは警告します。）

一見すると、コードには、という名前$keyの変数が1つしかないため、コンパイル時に問題なくキャプチャできます。しかし、彼らはだましているように見えます。foreachのエイリアシング機能により、イテレータ変数はループの外側にあった変数ではありません。

$ perl -E'
   my $x; say "x: ", 0+\$x;   # Show address of variable.
   my $y; say "y: ", 0+\$y;
   my $z; say "z: ", 0+\$z;
   for $x ($y, $z) { say "i: ", 0+\$x; }
'
x: 155771632
y: 155771584
z: 155771744
i: 155771584
i: 155771744

あなたの場合、あなたは

$ perl -E'
   my $x; say "x: ", 0+\$x;
   my $y; say "y: ", 0+\$y;
   my $z; say "z: ", 0+\$z;
   for $x ($y, $z) {
      say "i: ", 0+\$x;
      sub f { say "f: ", 0+\$x; }
      f();
   }
'
x: 142992144
y: 142992096
z: 142992256
i: 142992096
f: 142992144
i: 142992256
f: 142992144

実行時$xにサブをキャプチャする必要があります。これは、匿名のサブを使用して行われます。

$ perl -E'
   my $x; say "x: ", 0+\$x;
   my $y; say "y: ", 0+\$y;
   my $z; say "z: ", 0+\$z;
   for $x ($y, $z) {
      say "i: ", 0+\$x;
      my $f = sub { say "f: ", 0+\$x; };
      $f->();
   }
'
x: 159675200
y: 159675152
z: 159675312
i: 159675152
f: 159675152
i: 159675312
f: 159675312

修理：

for my $key (keys %hash) {
   if (@{ $hash{$key} } > 1) {
      for my $path (@{ $hash{$key} }) {
         open(my $fh, "+<", $path)             # +< ???
            or die("Can't open \"$path\": $!\n");

         my $tweak_server = sub {
            my ($twig, $root) = @_;
            ...
         };

         my $twig = new XML::Twig->new(
            TwigRoots => { TAG => 1 },
            TwigHandlers => { 'ROOT/TAG' => $tweak_server },
            twig_print_outside_roots => $fh,   # No need for \*$fh
         );
         $twig->parsefile($path);
      }
   }
}

名前付きサブに引数として変数を渡す匿名ラッパーを使用することもできます。

sub tweak_server {
   my ($fh, $key, $twig, $root) = @_;
   ...
}

for my $key (keys %hash) {
   if (@{ $hash{$key} } > 1) {
      for my $path (@{ $hash{$key} }) {
         open(my $fh, "+<", $path)             # +< ???
            or die("Can't open \"$path\": $!\n");

         my $twig = new XML::Twig->new(
            TwigRoots => { TAG => 1 },
            TwigHandlers => {
               'ROOT/TAG' => sub { tweak_server($fh, $key, @_) },
            },
            twig_print_outside_roots => $fh,   # No need for \*$fh
         );
         $twig->parsefile($path);
      }
   }
}
于 2011-10-20T19:33:01.893 に答える