9

SuperObjectライブラリを使用して、特定のオブジェクトのメソッドをその名前で呼び出し、この回答のようにSOInvokerメソッドを使用してそのパラメーターをjson文字列として指定できます。

作成したオブジェクトをパラメータとして送信する方法を知りたいのですが。私はそれを次のように送ろうとしました

LObjectList := TObjectList.Create;
LSuperRttiCtx := TSuperRttiContext.Create;
LSuperObjectParameter := LObjectList.ToJson(LSuperRttiCtx);

SOInvoke(MyInstantiatedObject, 'MyMethod', LSuperObjectParameter);

ただし、MyMethod内では、LObjectList参照は失われます。

私は何が間違っているのですか？

スーパーオブジェクトライブラリはここからダウンロードできます

4

1 に答える 1

8

オブジェクトリストの代わりにレコードの配列を使用する場合に機能します。それでもオブジェクトリストを使用したい場合は、このようなエンコーダーとデコーダーを作成する必要があります。TObjectList用のエンコーダー/デコーダーを作成しました。オブジェクトに対しても同じことを行い、クラス名をどこかに埋め込む必要があります。

ctx.SerialToJson.Add(TypeInfo(TObjectList), ObjectListToJSON);
ctx.SerialFromJson.Add(TypeInfo(TObjectList), JSONToObjectList);

function ObjectListToJSON(ctx: TSuperRttiContext; var value: TValue;
  const index: ISuperObject): ISuperObject;
var
  list: TObjectList;
  i: Integer;
begin
  list := TObjectList(value.AsObject);
  if list <> nil then
  begin
    Result := TSuperObject.Create(stArray);
    for i := 0 to list.Count - 1 do
      Result.AsArray.Add(encodeyourobject(list[i]));
  end else
    Result := nil;
end;

function JSONToObjectList(ctx: TSuperRttiContext; const obj: ISuperObject; var Value: TValue): Boolean;
var
  list: TObjectList;
  i: Integer;
begin
  list := nil;
  case ObjectGetType(obj) of
    stNull:
      begin
        Value := nil;
        Result := True;
      end;
    stArray:
      begin
        list := TObjectList.Create;
        for i := 0 to obj.AsArray.Length - 1 do
          list.Add(decodeyourobject(obj.AsArray[i]));
        Value := list;
        Result := True;
      end;
  else
      result := False;
  end;
end;
于 2012-01-06T15:12:04.650 に答える