5

DSPACKコンポーネントライブラリを使用して、システムの優先オーディオ入力デバイスからSkypeにオーディオを送信するDelphi6Proアプリがあります。TSampleGrabberコンポーネントを使用して、フィルターグラフチェーンを利用し、オーディオバッファーをSkypeに送信しています。問題は、オーディオが1秒に1回しか取得されないことです。つまり、TSampleGrabberインスタンスのOnBuffer（）イベントは、1秒に1回だけ発生し、Bufferパラメーターに1秒分のデータが含まれます。フィルタグラフチェーンを変更して、1秒に1回よりも速い間隔で入力デバイスからデータを取得する方法を知る必要があります。可能であれば、50ミリ秒ごとまたは少なくとも100ミリ秒ごとに実行したいと思います。

私のフィルターグラフチェーンは、上部にあるシステムの優先オーディオ入力デバイスにマップされているTFilterで構成されています。そのフィルターの出力ピンを、TFilterが割り当てられた「WAVDest」の入力ピンに接続して、PCMWAV形式でサンプルを取得できるようにします。次に、「WAV Dest」フィルターの出力ピンを、TSampleGrabberインスタンスの入力ピンに接続します。TSampleGrabber OnBuffer（）イベントをより速い間隔で発生させるには、何を変更する必要がありますか？

更新：Roman Rの回答に基づいて、以下に示すソリューションを実装することができました。1つのメモ。彼のリンクから、ソリューションに役立つ次のブログ投稿にアクセスできました。

http://sid6581.wordpress.com/2006/10/09/minimizing-audio-capture-latency-in-directshow/

// Variable declaration for output pin to manipulate.
var
    intfCapturePin: IPin;

...............


    // Put this code after you have initialized your audio capture device
    //  TFilter instance *and* set it's wave audio format.  My variable for
    //  this is FFiltAudCap.  I believe you need to set the buffer size before
    //  connecting up the pins of the Filters.  The media type was
    //  retrieved earlier (theMediaType) when I initialized the audio
    //  input device Filter so you will need to do similarly.

    // Get a reference to the desired output pin for the audio capture device.
    with FFiltAudCap as IBaseFilter do
        CheckDSError(findPin(StringToOleStr('Capture'), intfCapturePin));

    if not Assigned(intfCapturePin) then
        raise Exception.Create('Unable to find the audio input device''s Capture output pin.');

    // Set the capture device buffer to 50 ms worth of audio data to
    //  reduce latency.  NOTE: This will fail if the device does not
    //  support the latency you desire so make sure you watch out for that.
    setBufferLatency(intfCapturePin as IAMBufferNegotiation, 50, theMediaType);

..................

// The setBufferLatency() procedure.
procedure setBufferLatency(
                // A buffer negotiation interface pointer.
                intfBufNegotiate: IAMBufferNegotiation;
                // The desired latency in milliseconds.
                bufLatencyMS: WORD;
                // The media type the audio stream is set to.
                theMediaType: TMediaType);
var
    allocProp: _AllocatorProperties;
    wfex: TWaveFormatEx;
begin
    if not Assigned(intfBufNegotiate) then
        raise Exception.Create('The buffer negotiation interface object is unassigned.');

    // Calculate the number of bytes per second using the wave
    // format belonging to the given Media Type.
    wfex := getWaveFormat(theMediaType);

    if wfex.nAvgBytesPerSec = 0 then
        raise Exception.Create('The average bytes per second value for the given Media Type is 0.');

    allocProp.cbAlign := -1;  // -1 means "no preference".
    // Calculate the size of the buffer needed to get the desired
    //  latency in milliseconds given the average bytes per second
    //  of the Media Type's audio format.
    allocProp.cbBuffer := Trunc(wfex.nAvgBytesPerSec * (bufLatencyMS / 1000));
    allocProp.cbPrefix := -1;
    allocProp.cBuffers := -1;

    // Try to set the buffer size to the desired.
    CheckDSError(intfBufNegotiate.SuggestAllocatorProperties(allocProp));
end;
4

1 に答える 1

6

オーディオキャプチャフィルターを微調整して、必要なサイズのバッファーにキャプチャする必要があると思います。つまり、全体的なレイテンシーを小さくするのに十分な長さです。

オーディオキャプチャフィルタIAMBufferNegotiationは、出力ピンのインターフェイスを公開しSuggestAllocatorProperties、バッファ設定を指定できるようにします。

詳細については、「遅延を減らすためのWindows Media AudioEncoderDMOの構成」を参照してください。

于 2011-10-24T20:53:45.690 に答える