18

マルチキャストgen_udpを行うためにErlangでどのように使用しますか? 私はそれがコードにあることを知っていますが、その背後にあるドキュメントはありません。データの送信は明白で簡単です。メンバーシップを追加する方法について疑問に思っていました。起動時にメンバーシップを追加するだけでなく、実行中にメンバーシップを追加することも役立ちます。

4

4 に答える 4

15

Here is example code on how to listen in on Bonjour / Zeroconf traffic.

-module(zcclient).

-export([open/2,start/0]).
-export([stop/1,receiver/0]).

open(Addr,Port) ->
   {ok,S} = gen_udp:open(Port,[{reuseaddr,true}, {ip,Addr}, {multicast_ttl,4}, {multicast_loop,false}, binary]),
   inet:setopts(S,[{add_membership,{Addr,{0,0,0,0}}}]),
   S.

close(S) -> gen_udp:close(S).

start() ->
   S=open({224,0,0,251},5353),
   Pid=spawn(?MODULE,receiver,[]),
   gen_udp:controlling_process(S,Pid),
   {S,Pid}.

stop({S,Pid}) ->
   close(S),
   Pid ! stop.

receiver() ->
   receive
       {udp, _Socket, IP, InPortNo, Packet} ->
           io:format("~n~nFrom: ~p~nPort: ~p~nData: ~p~n",[IP,InPortNo,inet_dns:decode(Packet)]),
           receiver();
       stop -> true;
       AnythingElse -> io:format("RECEIVED: ~p~n",[AnythingElse]),
           receiver()
   end.
于 2009-11-16T04:36:03.823 に答える
11

マルチキャスト送信が応答されました。受信にはマルチキャスト グループへの加入が必要です。

(まだ) 文書化されていないようですが、以前に erlang-questions メーリング リストでカバーされていました。http://www.erlang.org/pipermail/erlang-questions/2003-March/008071.html

    {ok, Socket} = gen_udp:open(Port, [binary, {active, false},
                                       {reuseaddr, true},{ip, Addr}, 
                                       {add_membership, {Addr, LAddr}}]).

ここで、Addrはマルチキャスト グループで、LAddrはローカル インターフェイスです。(コードは mog の厚意による)

上記で使用したのと同じオプションを include に渡して、グループのリッスンを停止できinet:setoptsます{drop_membership, {Addr, LAddr}}。

于 2008-09-17T08:32:44.710 に答える
4

この例を自分の PC で実行しようとしています。受信ソケットを開くと常に {error,eaddrnotavail} というメッセージが表示される場合はどうなりますか?

例 1: これは動作します:

{ok, Socket} = gen_udp:open(?PORT, [{reuseaddr,true}, {ip,?SERVER_IP},
               {multicast_ttl,4}, {multicast_loop,false}, binary]),

例 2: 実行時エラーの取得:

{ok, Socket} = gen_udp:open(?PORT, [{reuseaddr,true}, {ip,?MULTICAST_IP},
               {multicast_ttl,4}, {multicast_loop,false}, binary]),

% --> {エラー,eaddrnotavail}

-define(SERVER_IP, {10,31,123,123}). % The IP of the current computer
-define(PORT, 5353).
-define(MULTICAST_IP, {224,0,0,251}).
于 2009-12-10T10:49:23.413 に答える
0

マルチキャストはIPアドレスで指定

これは、すべての言語と同様に erlang でも同じです。IP アドレス 224.0.0.0 から 239.255.255.255 はマルチキャスト アドレスです。

その範囲内のアドレスを選択し、既に割り当てられているアドレスと重複していないことを確認してください。

http://www.iana.org/assignments/multicast-addresses

于 2008-09-17T01:18:29.450 に答える