10

画像 (mx) があり、クリックされたピクセルの uint を取得したいと考えています。

何か案は？

4

3 に答える 3

10

BitmapData LiveDoc ページで数分待つだけで、必要な場所に移動できます。画像を Bitmap 変数にロードしたら、その BitmapData プロパティにアクセスできます。マウス クリック イベントリスナーを画像に追加し、BitmapData::getPixelを使用します。getPixel の例は、uint 応答を RGB 16 進コードに変換する方法を示しています。

これは、私のために働いた BitmapData ページにある例の変更です (mxmlc - YMMV を使用):

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.net.URLRequest;

    public class BitmapDataExample extends Sprite {
        private var url:String = "santa-drunk1.jpg";
        private var size:uint = 200;
        private var image:Bitmap;

        public function BitmapDataExample() {
            configureAssets();
        }

        private function configureAssets():void {
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);

            var request:URLRequest = new URLRequest(url);
            loader.load(request);
            addChild(loader);
        }

        private function completeHandler(event:Event):void {
            var loader:Loader = Loader(event.target.loader);
            this.image = Bitmap(loader.content);

            this.addEventListener(MouseEvent.CLICK, this.clickListener);
        }

        private function clickListener(event:MouseEvent):void {
            var pixelValue:uint = this.image.bitmapData.getPixel(event.localX, event.localY)
            trace(pixelValue.toString(16));
        }
    }
}
于 2008-09-17T02:18:45.577 に答える
8

これはFlexまたはmx：Imageに固有のものではなく、任意のビットマップ描画可能オブジェクトからピクセルカラー値を取得できます（権限がある場合）。

private const bitmapData:BitmapData = new BitmapData(1, 1);
private const matrix:Matrix = new Matrix();
private const clipRect:Rectangle = new Rectangle(0, 0, 1, 1);

public function getColor(drawable:IBitmapDrawable, x:Number, y:Number):uint
{
    matrix.setTo(1, 0, 0, 1, -x, -y)
    bitmapData.draw(drawable, matrix, null, null, clipRect);
    return bitmapData.getPixel(0, 0);
}

ステージまたはmx：Imageインスタンスからピクセルを簡単に取得できます。ステージ全体（または描画可能なオブジェクト）を描画するよりもはるかに効率的であり、MouseEvent.MOUSE_MOVEに接続して即座に視覚的なフィードバックを得るのに十分な速度である必要があります。

于 2011-12-23T18:58:56.353 に答える
8

これはさらに単純な実装です。bitmapData のdraw()メソッドを使用してステージのスナップショットを取得し、マウスの下のピクセルでgetPixel()を使用するだけです。これの利点は、特定のビットマップだけでなく、ステージに描画されたあらゆるものをサンプリングできることです。

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.events.*;

stage.addEventListener(MouseEvent.CLICK, getColorSample);

function getColorSample(e:MouseEvent):void {
    var bd:BitmapData = new BitmapData(stage.width, stage.height);
    bd.draw(stage);
    var b:Bitmap = new Bitmap(bd);
    trace(b.bitmapData.getPixel(stage.mouseX,stage.mouseX));
}

これが役に立てば幸いです！

編集：

この編集されたバージョンは単一BitmapDataの を使用し、Bitmap. 色をサンプリングしている場合MOUSE_MOVE、これはメモリの問題を回避するために不可欠です。

注: カスタム カーソル スプライトを使用している場合は、'state' 以外のオブジェクトを使用する必要があります。そうしないと、カスタム スプライトの下にあるものではなく、カスタム スプライトの色をサンプリングすることになります。

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.events.*;

private var _stageBitmap:BitmapData;

stage.addEventListener(MouseEvent.CLICK, getColorSample);

function getColorSample(e:MouseEvent):void 
{
    if (_stageBitmap == null) {
        _stageBitmap = new BitmapData(stage.width, stage.height);
    }
    _stageBitmap.draw(stage);

    var rgb:uint = _stageBitmap.getPixel(stage.mouseX,stage.mouseY);

    var red:int =  (rgb >> 16 & 0xff);
    var green:int =  (rgb >> 8 & 0xff);
    var blue:int =  (rgb & 0xff);

    trace(red + "," + green + "," + blue);
}
于 2008-09-17T17:02:20.837 に答える